diag_mod Module Reference

Functions/Subroutines
subroutine, public	diag (ng, tile)
subroutine	diag_tile (ng, tile, lbi, ubi, lbj, ubj, imins, imaxs, jmins, jmaxs, nstp, krhs, h, pm, pn, omn, hz, z_r, z_w, rho, u, v, wvel, ubar, vbar, zeta)

Function/Subroutine Documentation

diag()

subroutine, public diag_mod::diag	(	integer, intent(in)	ng,
		integer, intent(in)	tile )

Definition at line 23 of file diag.F.

!***********************************************************************
!
      USE mod_param
      USE mod_grid
      USE mod_ocean
      USE mod_stepping
!
#ifdef ANA_DIAG
      USE analytical_mod, ONLY : ana_diag
#endif
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile
!
!  Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
#include "tile.h"
!
#ifdef PROFILE
      CALL wclock_on (ng, inlm, 7, __line__, myfile)
#endif
      CALL diag_tile (ng, tile,                                         &
     &                lbi, ubi, lbj, ubj,                               &
     &                imins, imaxs, jmins, jmaxs,                       &
#ifdef STEP2D_FB_LF_AM3
     &                nstp(ng), kstp(ng),                               &
#else
     &                nstp(ng), krhs(ng),                               &
#endif
     &                grid(ng) % h,                                     &
     &                grid(ng) % pm,                                    &
     &                grid(ng) % pn,                                    &
     &                grid(ng) % omn,                                   &
#ifdef SOLVE3D
     &                grid(ng) % Hz,                                    &
     &                grid(ng) % z_r,                                   &
     &                grid(ng) % z_w,                                   &
     &                ocean(ng) % rho,                                  &
     &                ocean(ng) % u,                                    &
     &                ocean(ng) % v,                                    &
     &                ocean(ng) % wvel,                                 &
#endif
     &                ocean(ng) % ubar,                                 &
     &                ocean(ng) % vbar,                                 &
     &                ocean(ng) % zeta)
#ifdef ANA_DIAG
      CALL ana_diag (ng, tile, inlm)
#endif
#ifdef PROFILE
      CALL wclock_off (ng, inlm, 7, __line__, myfile)
#endif
!
      RETURN

References analytical_mod::ana_diag(), diag_tile(), mod_grid::grid, mod_param::inlm, mod_stepping::krhs, mod_stepping::kstp, mod_stepping::nstp, mod_ocean::ocean, wclock_off(), and wclock_on().

Referenced by main3d().

Here is the call graph for this function:

Here is the caller graph for this function:

diag_tile()

subroutine diag_mod::diag_tile ( integer, intent(in) ng, integer, intent(in) tile, integer, intent(in) lbi, integer, intent(in) ubi, integer, intent(in) lbj, integer, intent(in) ubj, integer, intent(in) imins, integer, intent(in) imaxs, integer, intent(in) jmins, integer, intent(in) jmaxs, integer, intent(in) nstp, integer, intent(in) krhs, real(r8), dimension(lbi:,lbj:), intent(in) h, real(r8), dimension(lbi:,lbj:), intent(in) pm, real(r8), dimension(lbi:,lbj:), intent(in) pn, real(r8), dimension(lbi:,lbj:), intent(in) omn, real(r8), dimension(lbi:,lbj:,:), intent(in) hz, real(r8), dimension(lbi:,lbj:,:), intent(in) z_r, real(r8), dimension(lbi:,lbj:,0:), intent(in) z_w, real(r8), dimension(lbi:,lbj:,:), intent(in) rho, real(r8), dimension(lbi:,lbj:,:,:), intent(in) u, real(r8), dimension(lbi:,lbj:,:,:), intent(in) v, real(r8), dimension(lbi:,lbj:,0:), intent(in) wvel, real(r8), dimension(lbi:,lbj:,:), intent(in) ubar, real(r8), dimension(lbi:,lbj:,:), intent(in) vbar, real(r8), dimension(lbi:,lbj:,:), intent(in) zeta )

private

Definition at line 84 of file diag.F.

!***********************************************************************
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_scalars
 
#ifdef DISTRIBUTE
!
      USE distribute_mod, ONLY : mp_reduce
      USE distribute_mod, ONLY : mp_reduce2
#endif
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
      integer, intent(in) :: nstp, krhs
 
#ifdef ASSUMED_SHAPE
      real(r8), intent(in) :: h(LBi:,LBj:)
      real(r8), intent(in) :: pm(LBi:,LBj:)
      real(r8), intent(in) :: pn(LBi:,LBj:)
      real(r8), intent(in) :: omn(LBi:,LBj:)
# ifdef SOLVE3D
      real(r8), intent(in) :: Hz(LBi:,LBj:,:)
      real(r8), intent(in) :: z_r(LBi:,LBj:,:)
      real(r8), intent(in) :: z_w(LBi:,LBj:,0:)
      real(r8), intent(in) :: rho(LBi:,LBj:,:)
      real(r8), intent(in) :: u(LBi:,LBj:,:,:)
      real(r8), intent(in) :: v(LBi:,LBj:,:,:)
      real(r8), intent(in) :: wvel(LBi:,LBj:,0:)
# endif
      real(r8), intent(in) :: ubar(LBi:,LBj:,:)
      real(r8), intent(in) :: vbar(LBi:,LBj:,:)
      real(r8), intent(in) :: zeta(LBi:,LBj:,:)
#else
      real(r8), intent(in) :: h(LBi:UBi,LBj:UBj)
      real(r8), intent(in) :: pm(LBi:UBi,LBj:UBj)
      real(r8), intent(in) :: pn(LBi:UBi,LBj:UBj)
      real(r8), intent(in) :: omn(LBi:UBi,LBj:UBj)
# ifdef SOLVE3D
      real(r8), intent(in) :: Hz(LBi:UBi,LBj:UBj,N(ng))
      real(r8), intent(in) :: z_r(LBi:UBi,LBj:UBj,N(ng))
      real(r8), intent(in) :: z_w(LBi:UBi,LBj:UBj,0:N(ng))
      real(r8), intent(in) :: rho(LBi:UBi,LBj:UBj,N(ng))
      real(r8), intent(in) :: u(LBi:UBi,LBj:UBj,N(ng),2)
      real(r8), intent(in) :: v(LBi:UBi,LBj:UBj,N(ng),2)
      real(r8), intent(in) :: wvel(LBi:UBi,LBj:UBj,0:N(ng))
# endif
      real(r8), intent(in) :: ubar(LBi:UBi,LBj:UBj,:)
      real(r8), intent(in) :: vbar(LBi:UBi,LBj:UBj,:)
      real(r8), intent(in) :: zeta(LBi:UBi,LBj:UBj,:)
#endif
!
!  Local variable declarations.
!
      integer :: NSUB, i, ispace, j, k, trd
      integer :: idia, istep
      integer :: my_max_Ci, my_max_Cj, my_max_Ck
#ifdef DISTRIBUTE
# ifdef SOLVE3D
      integer, parameter :: Nreduce = 5
      integer, parameter :: Ncourant = 7
# else
      integer, parameter :: Nreduce = 4
      integer, parameter :: Ncourant = 5
# endif
      real(r8), dimension(Nreduce) :: rbuffer
      real(r8), dimension(Ncourant) :: Courant
      character (len=3), dimension(Nreduce) :: op_handle
      character (len=6), dimension(Nreduce) :: C_handle
#else
      integer :: my_threadnum
#endif
!
      real(r8) :: cff, my_avgke, my_avgpe, my_volume
      real(r8) :: my_C , my_max_C
      real(r8) :: my_Cu, my_max_Cu
      real(r8) :: my_Cv, my_max_Cv
#ifdef SOLVE3D
      real(r8) :: my_Cw, my_max_Cw
#endif
      real(r8) :: my_maxspeed, u2v2
#ifdef SOLVE3D
      real(r8) :: my_maxrho
#endif
      real(r8), dimension(IminS:ImaxS,JminS:JmaxS) :: ke2d
      real(r8), dimension(IminS:ImaxS,JminS:JmaxS) :: pe2d
!
      character (len=8 ) :: kechar, pechar, maxvalchar
      character (len=22) :: DateTime
      character (len=60) :: frmt
 
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Compute and report out volume averaged kinetic, potential
!  total energy, volume, Courant numbers.
!-----------------------------------------------------------------------
!
!  Set time timestep counter and time level indices to process. Restart
!  counter after 10 billion steps.
!
      istep=int(mod(real(iic(ng)-1,r8),1.0e+10_r8))
#ifdef SOLVE3D
      idia=nstp
#else
      idia=krhs
#endif
      datetime=time_code(ng)
!
! Compute kinetic and potential energy.
!
      IF (mod(iic(ng)-1,ninfo(ng)).eq.0) THEN
        my_max_c =0.0_r8
        my_max_cu=0.0_r8
        my_max_cv=0.0_r8
#ifdef SOLVE3D
        my_max_cw=0.0_r8
#endif
        my_max_ci=0
        my_max_cj=0
        my_max_ck=0
        my_maxspeed=0.0_r8
#ifdef SOLVE3D
        my_maxrho=-spval
#endif
        DO j=jstr,jend
#ifdef SOLVE3D
          DO i=istr,iend
            ke2d(i,j)=0.0_r8
            pe2d(i,j)=0.5_r8*g*z_w(i,j,n(ng))*z_w(i,j,n(ng))
          END DO
          cff=g/rho0
          DO k=n(ng),1,-1
            DO i=istr,iend
              u2v2=u(i  ,j,k,idia)*u(i  ,j,k,idia)+                     &
     &             u(i+1,j,k,idia)*u(i+1,j,k,idia)+                     &
     &             v(i,j  ,k,idia)*v(i,j  ,k,idia)+                     &
     &             v(i,j+1,k,idia)*v(i,j+1,k,idia)
              ke2d(i,j)=ke2d(i,j)+                                      &
     &                  hz(i,j,k)*0.25_r8*u2v2
              pe2d(i,j)=pe2d(i,j)+                                      &
     &                  cff*hz(i,j,k)*(rho(i,j,k)+1000.0_r8)*           &
     &                  (z_r(i,j,k)-z_w(i,j,0))
              my_cu=0.5_r8*abs(u(i,j,k,idia)+u(i+1,j,k,idia))*          &
     &              dt(ng)*pm(i,j)
              my_cv=0.5_r8*abs(v(i,j,k,idia)+v(i,j+1,k,idia))*          &
     &              dt(ng)*pn(i,j)
              my_cw=0.5_r8*abs(wvel(i,j,k-1)+wvel(i,j,k))*              &
     &              dt(ng)/hz(i,j,k)
              my_c=my_cu+my_cv+my_cw
              IF (my_c.gt.my_max_c) THEN
                my_max_c =my_c
                my_max_cu=my_cu
                my_max_cv=my_cv
                my_max_cw=my_cw
                my_max_ci=i
                my_max_cj=j
                my_max_ck=k
              END IF
              my_maxspeed=max(my_maxspeed,sqrt(0.5_r8*u2v2))
              my_maxrho=max(my_maxrho,rho(i,j,k))
            END DO
          END DO
#else
          cff=0.5_r8*g
          DO i=istr,iend
            u2v2=ubar(i  ,j,idia)*ubar(i  ,j,idia)+                     &
     &           ubar(i+1,j,idia)*ubar(i+1,j,idia)+                     &
     &           vbar(i,j  ,idia)*vbar(i,j  ,idia)+                     &
     &           vbar(i,j+1,idia)*vbar(i,j+1,idia)
            ke2d(i,j)=(zeta(i,j,idia)+h(i,j))*0.25_r8*u2v2
            pe2d(i,j)=cff*zeta(i,j,idia)*zeta(i,j,idia)
            my_cu=0.5_r8*abs(ubar(i,j,idia)+ubar(i+1,j,idia))*          &
     &            dt(ng)*pn(i,j)
            my_cv=0.5_r8*abs(vbar(i,j,idia)+vbar(i,j+1,idia))*          &
     &            dt(ng)*pn(i,j)
            my_c=my_cu+my_cv
            IF (my_c.gt.my_max_c) THEN
              my_max_c =my_c
              my_max_cu=my_cu
              my_max_cv=my_cv
              my_max_ci=i
              my_max_cj=j
            END IF
            my_maxspeed=max(my_maxspeed,sqrt(0.5_r8*u2v2))
          END DO
#endif
        END DO
!
!  Integrate horizontally within one tile. In order to reduce the
!  round-off errors, the summation is performed in two stages. First,
!  the index j is collapsed and then the accumulation is carried out
!  along index i. In this order, the partial sums consist on much
!  fewer number of terms than in a straightforward two-dimensional
!  summation. Thus, adding numbers which are orders of magnitude
!  apart is avoided.
!
        DO i=istr,iend
          pe2d(i,jend+1)=0.0_r8
          pe2d(i,jstr-1)=0.0_r8
          ke2d(i,jstr-1)=0.0_r8
        END DO
        DO j=jstr,jend
          DO i=istr,iend
#ifdef SOLVE3D
            pe2d(i,jend+1)=pe2d(i,jend+1)+                              &
     &                     omn(i,j)*(z_w(i,j,n(ng))-z_w(i,j,0))
#else
            pe2d(i,jend+1)=pe2d(i,jend+1)+                              &
     &                     omn(i,j)*(zeta(i,j,idia)+h(i,j))
#endif
            pe2d(i,jstr-1)=pe2d(i,jstr-1)+omn(i,j)*pe2d(i,j)
            ke2d(i,jstr-1)=ke2d(i,jstr-1)+omn(i,j)*ke2d(i,j)
          END DO
        END DO
        my_volume=0.0_r8
        my_avgpe=0.0_r8
        my_avgke=0.0_r8
        DO i=istr,iend
          my_volume=my_volume+pe2d(i,jend+1)
          my_avgpe =my_avgpe +pe2d(i,jstr-1)
          my_avgke =my_avgke +ke2d(i,jstr-1)
        END DO
!
!  Perform global summation: whoever gets first to the critical region
!  resets global sums before global summation starts; after the global
!  summation is completed, thread, which is the last one to enter the
!  critical region, finalizes the computation of diagnostics and prints
!  them out.
!
#ifdef DISTRIBUTE
        nsub=1                           ! distributed-memory
#else
        IF (domain(ng)%SouthWest_Corner(tile).and.                      &
     &      domain(ng)%NorthEast_Corner(tile)) THEN
          nsub=1                         ! non-tiled application
        ELSE
          nsub=ntilex(ng)*ntilee(ng)     ! tiled application
        END IF
#endif
!$OMP CRITICAL (NL_DIAGNOSTICS)
!!      IF (tile_count.eq.0) THEN
!!        volume=0.0_r8
!!        avgke=0.0_r8
!!        avgpe=0.0_r8
!!        maxspeed(ng)=0.0_r8
#ifdef SOLVE3D
!!        maxrho(ng)=-spval
#endif
!!        max_C =0.0_r8
!!        max_Cu=0.0_r8
!!        max_Cv=0.0_r8
#ifdef SOLVE3D
!!        max_Cw=0.0_r8
#endif
!!        max_Ci=0
!!        max_Cj=0
#ifdef SOLVE3D
!!        max_Ck=0
#endif
!!      END IF
        volume=volume+my_volume
        avgke=avgke+my_avgke
        avgpe=avgpe+my_avgpe
        maxspeed(ng)=max(maxspeed(ng),my_maxspeed)
#ifdef SOLVE3D
        maxrho(ng)=max(maxrho(ng),my_maxrho)
#endif
        IF (my_max_c.eq.max_c) THEN
          max_ci=min(max_ci,my_max_ci)
          max_cj=min(max_cj,my_max_cj)
#ifdef SOLVE3D
          max_ck=min(max_ck,my_max_ck)
#endif
        ELSE IF (my_max_c.gt.max_c) THEN
          max_c =my_max_c
          max_cu=my_max_cu
          max_cv=my_max_cv
#ifdef SOLVE3D
          max_cw=my_max_cw
#endif
          max_ci=my_max_ci
          max_cj=my_max_cj
#ifdef SOLVE3D
          max_ck=my_max_ck
#endif
        END IF
        tile_count=tile_count+1
        IF (tile_count.eq.nsub) THEN
          tile_count=0
#ifdef DISTRIBUTE
          rbuffer(1)=volume
          rbuffer(2)=avgke
          rbuffer(3)=avgpe
          rbuffer(4)=maxspeed(ng)
# ifdef SOLVE3D
          rbuffer(5)=maxrho(ng)
# endif
          op_handle(1)='SUM'
          op_handle(2)='SUM'
          op_handle(3)='SUM'
          op_handle(4)='MAX'
# ifdef SOLVE3D
          op_handle(5)='MAX'
# endif
          CALL mp_reduce (ng, inlm, nreduce, rbuffer, op_handle)
          volume=rbuffer(1)
          avgke=rbuffer(2)
          avgpe=rbuffer(3)
          maxspeed(ng)=rbuffer(4)
# ifdef SOLVE3D
          maxrho(ng)=rbuffer(5)
# endif
!
          courant(1)=max_c
          courant(2)=max_cu
          courant(3)=max_cv
          courant(4)=real(max_ci,r8)
          courant(5)=real(max_cj,r8)
# ifdef SOLVE3D
          courant(6)=max_cw
          courant(7)=real(max_ck,r8)
# endif
          c_handle(1)='MAXLOC'
          CALL mp_reduce2 (ng, inlm, ncourant, 1, courant, c_handle)
          max_c =courant(1)
          max_cu=courant(2)
          max_cv=courant(3)
          max_ci=int(courant(4))
          max_cj=int(courant(5))
# ifdef SOLVE3D
          max_cw=courant(6)
          max_ck=int(courant(7))
# endif
!
          trd=mymaster
#else
          trd=my_threadnum()
#endif
          avgke=avgke/volume
          avgpe=avgpe/volume
          avgkp=avgke+avgpe
!
! Report global run diagnotics values for the nonlinear kernel.
!
          IF (first_time(ng).eq.0) THEN
            first_time(ng)=1
            IF (master.and.(ng.eq.1)) THEN
              WRITE (stdout,10) 'TIME-STEP', 'YYYY-MM-DD hh:mm:ss.ss',  &
     &                          'KINETIC_ENRG', 'POTEN_ENRG',           &
#ifdef NESTING
     &                          'TOTAL_ENRG', 'NET_VOLUME', 'Grid'
#else
     &                          'TOTAL_ENRG', 'NET_VOLUME'
#endif
#ifdef SOLVE3D
              WRITE (stdout,20) 'C => (i,j,k)', 'Cu', 'Cv',             &
     &                          '  Cw  ', 'Max Speed'
#else
              WRITE (stdout,20) '  C => (i,j)', 'Cu', 'Cv',             &
     &                          ' C Max', 'Max Speed'
#endif
#ifdef NESTING
 10           FORMAT (/,1x,a,1x,a,2x,a,3x,a,4x,a,4x,a,2x,a)
#else
 10           FORMAT (/,1x,a,1x,a,2x,a,3x,a,4x,a,4x,a)
#endif
 20           FORMAT (21x,a,7x,a,12x,a,10x,a,7x,a,/)
            END IF
          END IF
!
          IF (master) THEN
            WRITE (stdout,30) istep, datetime,                          &
#ifdef NESTING
     &                        avgke, avgpe, avgkp, volume, ng
#else
     &                        avgke, avgpe, avgkp, volume
#endif
#ifdef SOLVE3D
            ispace=35-(6+idigits(ng)+jdigits(ng)+kdigits(ng))
            WRITE (frmt,40) ispace,                                     &
     &                      '"("', idigits(ng), idigits(ng),            &
     &                      '","', jdigits(ng), jdigits(ng),            &
     &                      '","', kdigits(ng), kdigits(ng), '")"'
            WRITE (stdout,frmt) max_ci, max_cj,                         &
     &                          max_ck, max_cu, max_cv, max_cw,         &
     &                          maxspeed(ng)
#else
            ispace=35-(5+idigits(ng)+jdigits(ng))
            WRITE (frmt,40) ispace,                                     &
     &                      '"("', idigits(ng), idigits(ng),            &
     &                      '","', jdigits(ng), jdigits(ng), '")"'
            WRITE (stdout,frmt) max_ci, max_cj,                         &
     &                          max_cu, max_cv, max_c,                  &
     &                          maxspeed(ng)
#endif
            FLUSH (stdout)
#ifdef NESTING
 30         FORMAT (i10,1x,a,4(1pe14.6),2x,i2.2)
#else
 30         FORMAT (i10,1x,a,4(1pe14.6))
#endif
 40         FORMAT ('(',i2.2,'x,',a,',i',i1,'.',i1,',',                 &
     &                            a,',i',i1,'.',i1,',',                 &
#ifdef SOLVE3D
     &                            a,',i',i1,'.',i1,',',                 &
#endif
     &                            a,',t35,4(1pe13.6,1x))')
          END IF
!
!  If blowing-up, set exit_flag to stop computations.
!
          WRITE (kechar,'(1pe8.1)') avgke
          WRITE (pechar,'(1pe8.1)') avgpe
          DO i=1,8
            IF ((kechar(i:i).eq.'N').or.(pechar(i:i).eq.'N').or.        &
     &          (kechar(i:i).eq.'n').or.(pechar(i:i).eq.'n').or.        &
     &          (kechar(i:i).eq.'*').or.(pechar(i:i).eq.'*')) THEN
              exit_flag=1
              blowup_string='KEchar = '//kechar//', PEchar = '//pechar
            END IF
          END DO
!
!  Stop computations if exceeding maximum speed allowed.  This will be
!  useful during debugging to avoid NaNs in output NetCDF files.
!
          IF (maxspeed(ng).gt.max_speed) THEN
            exit_flag=1
            WRITE (maxvalchar,'(1pe8.1)') maxspeed(ng)
            blowup_string='MaxSpeed = '//maxvalchar
          END IF
#ifdef SOLVE3D
!
!  Stop computation if exceeding maximum density anomaly allowed.
!  Recall that  density is computed from potential temperature and
!  salinity.  This is a good way to screen for very bad values which
!  indicates that the model is blowing-up.
!
          IF (maxrho(ng).gt.max_rho) THEN
            exit_flag=1
            WRITE (maxvalchar,'(1pe8.1)') maxrho(ng)
            blowup_string='MaxDensity = '//maxvalchar
          END IF
#endif
!
!  Reset global reduction variables for the next call.
!
          volume=0.0_r8
          avgke=0.0_r8
          avgpe=0.0_r8
          maxspeed(ng)=-large
#ifdef SOLVE3D
          maxrho(ng)=-large
#endif
          max_c =0.0_r8
          max_cu=0.0_r8
          max_cv=0.0_r8
#ifdef SOLVE3D
          max_cw=0.0_r8
#endif
          max_ci=0
          max_cj=0
#ifdef SOLVE3D
          max_ck=0
#endif
        END IF
!$OMP END CRITICAL (NL_DIAGNOSTICS)
      END IF
!
      RETURN

References mod_scalars::avgke, mod_scalars::avgkp, mod_scalars::avgpe, mod_scalars::blowup_string, mod_param::domain, mod_scalars::dt, mod_scalars::exit_flag, mod_scalars::first_time, mod_scalars::g, mod_scalars::idigits, mod_scalars::iic, mod_param::inlm, mod_scalars::jdigits, mod_scalars::kdigits, mod_scalars::large, mod_parallel::master, mod_scalars::max_c, mod_scalars::max_ci, mod_scalars::max_cj, mod_scalars::max_ck, mod_scalars::max_cu, mod_scalars::max_cv, mod_scalars::max_cw, mod_scalars::max_rho, mod_scalars::max_speed, mod_scalars::maxrho, mod_scalars::maxspeed, distribute_mod::mp_reduce2(), mod_parallel::mymaster, mod_scalars::ninfo, mod_param::ntilee, mod_param::ntilex, mod_scalars::rho0, mod_scalars::spval, mod_iounits::stdout, mod_parallel::tile_count, mod_scalars::time_code, and mod_scalars::volume.

Referenced by diag().

Here is the call graph for this function:

Here is the caller graph for this function: