ana_diag.h

Go to the documentation of this file.

!!
      SUBROUTINE ana_diag (ng, tile, model)
!
!! git $Id$
!!======================================================================
!! Copyright (c) 2002-2025 The ROMS Group                              !
!!   Licensed under a MIT/X style license                              !
!!   See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine is provided so the USER can compute any specialized    !
!  diagnostics.  If activated, this routine is call at end of every    !
!  3D-equations timestep.                                              !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_ncparam
      USE mod_ocean
!
! Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
!
! Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
#include "tile.h"
!
      CALL ana_diag_tile (ng, tile, model,                              &
     &                    lbi, ubi, lbj, ubj,                           &
     &                    imins, imaxs, jmins, jmaxs,                   &
#ifdef SOLVE3D
     &                    ocean(ng) % u,                                &
     &                    ocean(ng) % v,                                &
#endif
     &                    ocean(ng) % ubar,                             &
     &                    ocean(ng) % vbar)
!
! Set analytical header file name used.
!
#ifdef DISTRIBUTE
      IF (lanafile) THEN
#else
      IF (lanafile.and.(tile.eq.0)) THEN
#endif
        ananame( 5)=myfile
      END IF
!
      RETURN
      END SUBROUTINE ana_diag
!
!***********************************************************************
      SUBROUTINE ana_diag_tile (ng, tile, model,                        &
     &                          LBi, UBi, LBj, UBj,                     &
     &                          IminS, ImaxS, JminS, JmaxS,             &
#ifdef SOLVE3D
     &                          u, v,                                   &
#endif
     &                          ubar, vbar)
!***********************************************************************
!
      USE mod_param
      USE mod_iounits
      USE mod_scalars
#ifdef SEAMOUNT
      USE mod_stepping
#endif
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
!
#ifdef ASSUMED_SHAPE
# ifdef SOLVE3D
      real(r8), intent(in) :: u(LBi:,LBj:,:,:)
      real(r8), intent(in) :: v(LBi:,LBj:,:,:)
# endif
      real(r8), intent(in) :: ubar(LBi:,LBj:,:)
      real(r8), intent(in) :: vbar(LBi:,LBj:,:)
#else
# ifdef SOLVE3D
      real(r8), intent(in) :: u(LBi:UBi,LBj:UBj,N(ng),2)
      real(r8), intent(in) :: v(LBi:UBi,LBj:UBj,N(ng),2)
# endif
      real(r8), intent(in) :: ubar(LBi:UBi,LBj:UBj,:)
      real(r8), intent(in) :: vbar(LBi:UBi,LBj:UBj,:)
#endif
!
!  Local variable declarations.
!
      integer :: i, io_error, j, k
!
      real(r8) :: umax, ubarmax, vmax, vbarmax
!
      character (len=256) :: io_errmsg
 
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Compute user diagnostics.
!-----------------------------------------------------------------------
!
#ifdef SEAMOUNT
 
!  Open USER file.
!
      IF (iic(ng).eq.ntstart(ng)) THEN
        OPEN (usrout,file=usrname,form='formatted',status='unknown',    &
     &        iostat=io_err, iomsg=io_errmsg)
        IF (io_err.ne.0) THEN
          WRITE (stdout,10) usrname, trim(io_errmsg)
          exit_flag=5
          RETURN
  10      FORMAT (' ANA_DIAG - unable to open output file: ',a,         &
                  /12x,'ERROR: ',a)
        END IF
      END IF
!
!  Write out maximum values of velocity.
!
      umax=0.0_r8
      vmax=0.0_r8
      ubarmax=0.0_r8
      vbarmax=0.0_r8
      DO k=1,n(ng)
        DO j=0,mm(ng)+1
          DO i=1,lm(ng)+1
            umax=max(umax,u(i,j,k,nnew(ng)))
          END DO
        END DO
        DO j=1,mm(ng)+1
          DO i=0,lm(ng)+1
            vmax=max(vmax,v(i,j,k,nnew(ng)))
          END DO
        END DO
      END DO
      DO j=0,mm(ng)+1
        DO i=1,lm(ng)+1
          ubarmax=max(ubarmax,ubar(i,j,knew(ng)))
        END DO
      END DO
      DO j=1,mm(ng)+1
        DO i=0,lm(ng)+1
          vbarmax=max(vbarmax,vbar(i,j,knew(ng)))
        END DO
      END DO
!
!  Write out maximum values on velocity.
!
      WRITE (usrout,20) tdays(ng), ubarmax, vbarmax, umax, vmax
  20  FORMAT (2x,f13.6,2x,1pe13.6,2x,1pe13.6,2x,1pe13.6,2x,1pe13.6)
#endif
!
      RETURN
      END SUBROUTINE ana_diag_tile