main2d.F

Go to the documentation of this file.

#include "cppdefs.h"
#if defined NONLINEAR && !defined SOLVE3D
      SUBROUTINE main2d (RunInterval)
!
!git $Id$
!=======================================================================
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                            Hernan G. Arango   !
!========================================== Alexander F. Shchepetkin ===
!                                                                      !
!  This routine is the main driver for ROMS nonlinear model (NLM)      !
!  when configured as a 2D barotropic shallow water ocean model. It    !
!  advances forward the NLM for all nested grids, if any, by the       !
!  specified time interval (seconds), RunInterval.                     !
!                                                                      !
# if defined STEP2D_FB_LF_AM3
!  Numerical 2D time-stepping kernel: FB AB3-AM4                       !
# elif defined STEP2D_FB_LF_AM3
!  Numerical 2D time-stepping kernel: FB LF-AM3                        !
# else
!  Numerical 2D time-stepping kernel: LF-AM3 (Legacy scheme)           !
# endif
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
# if defined MODEL_COUPLING && defined MCT_LIB
      USE mod_coupler
# endif
      USE mod_iounits
# ifdef NESTING
      USE mod_nesting
# endif
      USE mod_scalars
      USE mod_stepping
!
      USE dateclock_mod,        ONLY : time_string
      USE diag_mod,             ONLY : diag
# ifdef TLM_CHECK
      USE dotproduct_mod,       ONLY : nl_dotproduct
# endif
# ifdef TIDE_GENERATING_FORCES
      USE equilibrium_tide_mod, ONLY : equilibrium_tide
# endif
# if defined NLM_OUTER                || \
     defined rbl4dvar                 || \
     defined rbl4dvar_ana_sensitivity || \
     defined rbl4dvar_fct_sensitivity || \
     defined sp4dvar
      USE forcing_mod,          ONLY : forcing
# endif
# ifdef ADJUST_WSTRESS
      USE frc_adjust_mod,       ONLY : frc_adjust, load_frc
# endif
      USE ini_fields_mod,       ONLY : ini_fields, ini_zeta
# if defined ATM_COUPLING && defined MCT_LIB
      USE mct_coupler_mod,      ONLY : ocn2atm_coupling
# endif
# if defined WAV_COUPLING && defined MCT_LIB
      USE mct_coupler_mod,      ONLY : ocn2wav_coupling
# endif
# ifdef NESTING
      USE nesting_mod,          ONLY : nesting
#  ifndef ONE_WAY
      USE nesting_mod,          ONLY : do_twoway
#  endif
# endif
# if defined ADJUST_BOUNDARY
      USE obc_adjust_mod,       ONLY : obc_adjust, load_obc
# endif
# ifdef AVERAGES
      USE set_avg_mod,          ONLY : set_avg
# endif
# if defined SSH_TIDES || defined UV_TIDES
      USE set_tides_mod,        ONLY : set_tides
# endif
      USE set_vbc_mod,          ONLY : set_vbc
      USE step2d_mod,           ONLY : step2d
# ifdef FLOATS
      USE step_floats_mod,      ONLY : step_floats
# endif
      USE strings_mod,          ONLY : founderror
!
      implicit none
!
!  Imported variable declarations.
!
      real(dp), intent(in) :: RunInterval
!
!  Local variable declarations.
!
      logical :: DoNestLayer, Time_Step
!
      integer :: Nsteps, Rsteps
      integer :: ig, il, istep, ng, nl, tile
      integer :: next_indx1
# ifdef FLOATS
      integer :: Lend, Lstr, chunk_size
# endif
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
!=======================================================================
!  Time-step nonlinear vertically integrated equations.
!=======================================================================
!
!  Time-step the 3D kernel for the specified time interval (seconds),
!  RunInterval.
!
      time_step=.true.
      donestlayer=.true.
!
      kernel_loop : DO WHILE (time_step)
!
!  In nesting applications, the number of nesting layers (NestLayers) is
!  used to facilitate refinement grids and composite/refinament grids
!  combinations. Otherwise, the solution it is looped once for a single
!  grid application (NestLayers = 1).
!
        nl=0
# ifdef NESTING
        twowayinterval(1:ngrids)=0.0_r8
# endif
!
        nest_layer : DO WHILE (donestlayer)
!
!  Determine number of time steps to compute in each nested grid layer
!  based on the specified time interval (seconds), RunInterval. Non
!  nesting applications have NestLayers=1. Notice that RunInterval is
!  set in the calling driver. Its value may span the full period of the
!  simulation, a multi-model coupling interval (RunInterval > ifac*dt),
!  or just a single step (RunInterval=0).
!
          CALL ntimesteps (inlm, runinterval, nl, nsteps, rsteps)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          IF ((nl.le.0).or.(nl.gt.nestlayers)) EXIT
!
!  Time-step governing equations for Nsteps.
!
          step_loop : DO istep=1,nsteps
!
!  Set time indices and time clock.
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              tdays(ng)=time(ng)*sec2day
              IF (step_counter(ng).eq.rsteps) time_step=.false.
            END DO
!
!-----------------------------------------------------------------------
!  Read in required data, if any, from input NetCDF files.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
!$OMP MASTER
              CALL get_data (ng)
!$OMP END MASTER
!$OMP BARRIER
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END DO
!
!-----------------------------------------------------------------------
!  If applicable, process input data: time interpolate between data
!  snapshots.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              DO tile=first_tile(ng),last_tile(ng),+1
                CALL set_data (ng, tile)
              END DO
!$OMP BARRIER
            END DO
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
 
# if defined NLM_OUTER                || \
     defined rbl4dvar                 || \
     defined rbl4dvar_ana_sensitivity || \
     defined rbl4dvar_fct_sensitivity
!
!-----------------------------------------------------------------------
!  If appropriate, add convolved adjoint solution impulse forcing to
!  the nonlinear model solution. Notice that the forcing is only needed
!  after finishing all the inner loops. The forcing is continuous.
!  That is, it is time interpolated at every time-step from available
!  snapshots (FrequentImpulse=TRUE).
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
#  if defined WEAK_NOINTERP
              IF ((iic(ng).gt.1).and.(iic(ng).ne.ntend(ng)+1).and.      &
     &            (mod(iic(ng)-1,nadj(ng)).eq.0)) THEN
                IF (master) THEN
                  WRITE (stdout,*) ' FORCING NLM at iic = ',iic(ng)
                END IF
#  endif
                IF (frequentimpulse(ng)) THEN
                  DO tile=first_tile(ng),last_tile(ng),+1
                    CALL forcing (ng, tile, kstp(ng), nstp(ng))
                  END DO
!$OMP BARRIER
                END IF
#   ifdef WEAK_NOINTERP
              END IF
#  endif
            END DO
# endif
!
!-----------------------------------------------------------------------
!  Initialize all time levels and compute other initial fields.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (iic(ng).eq.ntstart(ng)) THEN
!
!  Initialize free-surface.
!
                DO tile=first_tile(ng),last_tile(ng),+1
                  CALL ini_zeta (ng, tile, inlm)
                END DO
!$OMP BARRIER
!
!  Initialize other state variables.
!
                DO tile=last_tile(ng),first_tile(ng),-1
                  CALL ini_fields (ng, tile, inlm)
                END DO
!$OMP BARRIER
 
# ifdef NESTING
!
!  Extract donor grid initial data at contact points and store it in
!  REFINED structure so it can be used for the space-time interpolation.
!
                IF (refinedgrid(ng)) THEN
                  CALL nesting (ng, inlm, ngetd)
                END IF
# endif
              END IF
            END DO
!
!-----------------------------------------------------------------------
!  Compute and report diagnostics. If appropriate, accumulate time-
!  averaged output data which needs a irreversible loop in shared-memory
!  jobs.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              DO tile=first_tile(ng),last_tile(ng),+1     ! irreversible
# ifdef AVERAGES
                CALL set_avg (ng, tile)
# endif
# ifdef DIAGNOSTICS
                CALL set_diags (ng, tile)
# endif
# ifdef TIDE_GENERATING_FORCES
                CALL equilibrium_tide (ng, tile, inlm)
# endif
                CALL diag (ng, tile)
# ifdef TLM_CHECK
                CALL nl_dotproduct (ng, tile, lnew(ng))
# endif
              END DO
!$OMP BARRIER
            END DO
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
# if defined ATM_COUPLING && defined MCT_LIB
!
!-----------------------------------------------------------------------
!  Couple ocean to atmosphere model every "CoupleSteps(Iatmos)"
!  timesteps: get air/sea fluxes.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF ((iic(ng).ne.ntstart(ng)).and.                         &
     &            mod(iic(ng),couplesteps(iatmos,ng)).eq.0) THEN
                DO tile=last_tile(ng),first_tile(ng),-1
                  CALL ocn2atm_coupling (ng, tile)
                END DO
!$OMP BARRIER
              END IF
            END DO
# endif
 
# ifdef ADJUST_BOUNDARY
!
!-----------------------------------------------------------------------
!  Interpolate open boundary increments and adjust open boundary.
!  Load open boundary into storage arrays. Skip the last output
!  timestep.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (iic(ng).lt.(ntend(ng)+1)) THEN
                DO tile=first_tile(ng),last_tile(ng),+1
                  CALL obc_adjust (ng, tile, lbinp(ng))
                  CALL load_obc (ng, tile, lbout(ng))
                END DO
!$OMP BARRIER
              END IF
            END DO
# endif
 
# ifdef ADJUST_WSTRESS
!
!-----------------------------------------------------------------------
!  Interpolate surface forcing increments and adjust surface forcing.
!  Load surface forcing to storage arrays.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (iic(ng).lt.(ntend(ng)+1)) THEN
                DO tile=first_tile(ng),last_tile(ng),+1
                  CALL frc_adjust (ng, tile, lfinp(ng))
                  CALL load_frc (ng, tile, lfout(ng))
                END DO
!$OMP BARRIER
              END IF
            END DO
# endif
 
# if defined WAV_COUPLING && defined MCT_LIB
!
!-----------------------------------------------------------------------
!  Couple ocean to waves model every "CoupleSteps(Iwaves)"
!  timesteps: get waves/sea fluxes.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF ((iic(ng).ne.ntstart(ng)).and.                         &
     &            mod(iic(ng)-1,couplesteps(iwaves,ng)).eq.0) THEN
                DO tile=first_tile(ng),last_tile(ng),+1
                  CALL ocn2wav_coupling (ng, tile)
                END DO
!$OMP BARRIER
              END IF
            END DO
# endif
 
!
!-----------------------------------------------------------------------
!  Set vertical boundary conditions. Process tidal forcing.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              DO tile=first_tile(ng),last_tile(ng),+1
                CALL set_vbc (ng, tile)
# if defined SSH_TIDES || defined UV_TIDES
                CALL set_tides (ng, tile)
# endif
              END DO
!$OMP BARRIER
            END DO
 
# ifdef NESTING
!
!  If composite or mosaic grids, process additional points in the
!  contact zone between connected grids for bottom stress variables.
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (any(compositegrid(:,ng))) THEN
                CALL nesting (ng, inlm, nbstr)
              END IF
            END DO
# endif
!
!-----------------------------------------------------------------------
!  If appropriate, write out fields into output NetCDF files.  Notice
!  that IO data is written in delayed and serial mode.  Exit if last
!  time step.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
!$OMP MASTER
              CALL output (ng)
!$OMP END MASTER
!$OMP BARRIER
              IF ((founderror(exit_flag, noerror, __line__, myfile)).or.&
     &            ((iic(ng).eq.(ntend(ng)+1)).and.(ng.eq.ngrids))) THEN
                RETURN
              END IF
            END DO
 
# ifdef NESTING
!
!-----------------------------------------------------------------------
!  If refinement grid, interpolate (space, time) state variables
!  contact points from donor grid extracted data.
#  ifdef NESTING_DEBUG
!
!  Also, fill BRY_CONTACT(:,:)%Mflux to check for mass conservation
!  between coarse and fine grids.  This is only done for diagnostic
!  purposes. Also, debugging is possible with very verbose output
!  to fort.300 is allowed by activating uppercase(nesting_debug).
#  endif
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (refinedgrid(ng).and.(refinescale(ng).gt.0)) THEN
                CALL nesting (ng, inlm, nputd)
#  ifdef NESTING_DEBUG
                CALL nesting (ng, inlm, nmflx)
#  endif
              END IF
            END DO
# endif
 
# ifdef STEP2D_FB_AB3_AM4
!
!-----------------------------------------------------------------------
!  Solve nonlinear vertically integrated primitive equations for
!  free-surface and momentum components using a generalized Forward-
!  Backward, 3rd-order Adams-Bashforth / 4th-order Adams-Moulton
!  (FB AB3-AM4) time stepping scheme (Shchepetkin and McWilliams,
!  2009).
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              iif(ng)=1
              nfast(ng)=1
              kstp(ng)=knew(ng)
              knew(ng)=kstp(ng)+1
              IF (knew(ng).gt.4) knew(ng)=1
              IF (mod(knew(ng),2).eq.0) THEN                ! zig-zag
                DO tile=first_tile(ng),last_tile(ng),+1     ! processing
                  CALL step2d (ng, tile)                    ! sequence
                END DO
!$OMP BARRIER
              ELSE
                DO tile=last_tile(ng),first_tile(ng),-1
                  CALL step2d (ng, tile)
                END DO
!$OMP BARRIER
              END IF
            END DO
 
# else
 
#  ifdef STEP2D_FB_LF_AM3
!
!-----------------------------------------------------------------------
!  Solve nonlinear vertically integrated primitive equations for
!  free-surface and momentum components using a predictor-corrector
!  LeapFrog / 3rd-order Adams-Moulton with a Forward-Backward
!  feeback (FB LF-AM3) stepping scheme (Shchepetkin and McWilliams,
!  2009).
!-----------------------------------------------------------------------
!
!  Predictor LF substep with FB-feedback.
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              iif(ng)=1
              nfast(ng)=1
              kstp(ng)=next_kstp(ng)
              knew(ng)=3
 
              DO tile=last_tile(ng),first_tile(ng),-1
                CALL step2d (ng, tile)
              END DO
!$OMP BARRIER
            END DO
 
#   ifdef NESTING
!
!  If composite or mosaic grids, process additional points in the
!  contact zone between connected grids for the state variables
!  associated with the 2D engine PREDICTOR STEP section.
#    ifdef NESTING_DEBUG
!  If refinement, check mass flux conservation between coarse and
!  fine grids during debugging.
#    endif
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (any(compositegrid(:,ng))) THEN
                CALL nesting (ng, inlm, n2dps)
              END IF
#    ifdef NESTING_DEBUG
              IF (refinedgrid(ng).and.(refinescale(ng).gt.0)) THEN
                CALL nesting (ng, inlm, nmflx)
              END IF
#    endif
            END DO
#   endif
!
!  Corrector AM3 substep with FB-feedback.
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              knew(ng)=3-kstp(ng)
              next_kstp(ng)=knew(ng)
 
              DO tile=first_tile(ng),last_tile(ng),+1
                CALL step2d (ng, tile)
              END DO
!$OMP BARRIER
            END DO
 
#  else
!
!-----------------------------------------------------------------------
!  Solve nonlinear vertically integrated primitive equations for
!  free-surface and momentum components using a predictor-corrector
!  LeapFrog with 3rd-order Adams-Moulton (LF-AM3) time stepping scheme
!  (ROMS legacy 2D kernel).
!-----------------------------------------------------------------------
!
!  Set time indices for predictor step. The PREDICTOR_2D_STEP switch
!  it is assumed to be false before the first time-step.
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              iif(ng)=1
              nfast(ng)=1
              next_indx1=3-indx1(ng)
              IF (.not.predictor_2d_step(ng)) THEN
                predictor_2d_step(ng)=.true.
                IF (first_2d_step) THEN
                  kstp(ng)=indx1(ng)
                ELSE
                  kstp(ng)=3-indx1(ng)
                END IF
                knew(ng)=3
                krhs(ng)=indx1(ng)
              END IF
!
!  Predictor step - Advance barotropic equations using 2D time-step
!  ==============   predictor scheme.
!
              DO tile=last_tile(ng),first_tile(ng),-1
                CALL step2d (ng, tile)
              END DO
!$OMP BARRIER
            END DO
 
#   ifdef NESTING
!
!  If composite or mosaic grids, process additional points in the
!  contact zone between connected grids for the state variables
!  associated with the 2D engine PREDICTOR STEP section.
#    ifdef NESTING_DEBUG
!  If refinement, check mass flux conservation between coarse and
!  fine grids during debugging.
!  Warning: very verbose output to fort.300 ascii file to check
!           mass flux conservation.
#    endif
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (any(compositegrid(:,ng))) THEN
                CALL nesting (ng, inlm, n2dps)
              END IF
#    ifdef NESTING_DEBUG
              IF (refinedgrid(ng).and.(refinescale(ng).gt.0)) THEN
                CALL nesting (ng, inlm, nmflx)
              END IF
#    endif
            END DO
#   endif
!
!  Set time indices for corrector step.
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (predictor_2d_step(ng)) THEN
                predictor_2d_step(ng)=.false.
                knew(ng)=next_indx1
                kstp(ng)=3-knew(ng)
                krhs(ng)=3
                IF (iif(ng).lt.(nfast(ng)+1)) indx1(ng)=next_indx1
              END IF
!
!  Corrector step - Apply 2D time-step corrector scheme.  Notice that
!  ==============   there is not need for a corrector step during the
!  auxiliary (nfast+1) time-step.
!
              IF (iif(ng).lt.(nfast(ng)+1)) THEN
                DO tile=first_tile(ng),last_tile(ng),+1
                  CALL step2d (ng, tile)
                END DO
!$OMP BARRIER
              END IF
            END DO
#  endif
 
# endif
 
# ifdef NESTING
#  if defined MASKING && defined WET_DRY
!
!-----------------------------------------------------------------------
!  If nesting and wetting and drying, scale horizontal interpolation
!  weights to account for land/sea masking in contact areas. This needs
!  to be done at very time-step since the Land/Sea masking is time
!  dependent.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              CALL nesting (ng, inlm, nmask)
            END DO
#  endif
!
!-----------------------------------------------------------------------
!  If composite or mosaic grids, process additional points in the
!  contact zone between connected grids for the state variables
!  associated with the 2D engine CORRECTOR STEP section (KNEW INDEX).
#  ifdef NESTING_DEBUG
!  If refinement, check mass flux conservation between coarse and
!  fine grids during debugging.
!  Warning: very verbose output to fort.300 ascii file to check
!           mass flux conservation.
#  endif
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (any(compositegrid(:,ng))) THEN
                CALL nesting (ng, inlm, n2dcs)
              END IF
#  ifdef NESTING_DEBUG
                IF (refinedgrid(ng).and.(refinescale(ng).gt.0)) THEN
                  CALL nesting (ng, inlm, nmflx)
                END IF
#  endif
            END DO
# endif
 
# ifdef NESTING
#  ifndef ONE_WAY
!
!-----------------------------------------------------------------------
!  If refinement grids, perform two-way coupling between fine and
!  coarse grids. Correct coarse grid tracers values at the refinement
!  grid with refined accumulated fluxes.  Then, replace coarse grid
!  state variable with averaged refined grid values (two-way nesting).
!  Update coarse grid depth variables.
!
!  The two-way exchange of infomation between nested grids needs to be
!  done at the correct time-step and in the right sequence.
!-----------------------------------------------------------------------
!
            DO il=nestlayers,1,-1
              DO ig=1,gridsinlayer(il)
                ng=gridnumber(ig,il)
                IF (do_twoway(inlm, nl, il, ng, istep)) THEN
                  CALL nesting (ng, inlm, n2way)
                END IF
              END DO
            END DO
#  endif
!
!-----------------------------------------------------------------------
!  If donor to a finer grid, extract data for the external contact
!  points. This is the latest solution for the coarser grid.
!
!  It is stored in the REFINED structure so it can be used for the
!  space-time interpolation.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (donortofiner(ng)) THEN
                CALL nesting (ng, inlm, ngetd)
              END IF
            END DO
# endif
 
# ifdef FLOATS
!
!-----------------------------------------------------------------------
!  Compute Lagrangian drifters trajectories: Split all the drifters
!  between all the computational threads, except in distributed-memory
!  and serial configurations. In distributed-memory, the parallel node
!  containing the drifter is selected internally since the state
!  variables do not have a global scope.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              IF (lfloats(ng)) THEN
#  ifdef _OPENMP
                chunk_size=(nfloats(ng)+numthreads-1)/numthreads
                lstr=1+mythread*chunk_size
                lend=min(nfloats(ng),lstr+chunk_size-1)
#  else
                lstr=1
                lend=nfloats(ng)
#  endif
                CALL step_floats (ng, lstr, lend)
!$OMP BARRIER
!
!  Shift floats time indices.
!
                nfp1(ng)=mod(nfp1(ng)+1,nft+1)
                nf(ng)=mod(nf(ng)+1,nft+1)
                nfm1(ng)=mod(nfm1(ng)+1,nft+1)
                nfm2(ng)=mod(nfm2(ng)+1,nft+1)
                nfm3(ng)=mod(nfm3(ng)+1,nft+1)
              END IF
            END DO
# endif
!
!-----------------------------------------------------------------------
!  Advance time index and time clock.
!-----------------------------------------------------------------------
!
            DO ig=1,gridsinlayer(nl)
              ng=gridnumber(ig,nl)
              iic(ng)=iic(ng)+1
              time(ng)=time(ng)+dt(ng)
              step_counter(ng)=step_counter(ng)-1
              CALL time_string (time(ng), time_code(ng))
            END DO
 
          END DO step_loop
 
        END DO nest_layer
 
      END DO kernel_loop
!
      RETURN
      END SUBROUTINE main2d
#else
      SUBROUTINE main2d
      RETURN
      END SUBROUTINE main2d
#endif