output.F

Go to the documentation of this file.

#include "cppdefs.h"
#ifdef NONLINEAR
      SUBROUTINE output (ng)
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This subroutine manages nonlinear model output. It creates output   !
!  NetCDF files and writes out data into NetCDF files. If requested,   !
!  it can create several history and/or time-averaged files to avoid   !
!  generating too large files during a single model run.               !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
# ifdef FLOATS
      USE mod_floats
# endif
# if defined FOUR_DVAR || defined VERIFICATION
      USE mod_fourdvar
# endif
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE close_io_mod,    ONLY : close_file
# ifdef AVERAGES
      USE def_avg_mod,     ONLY : def_avg
# endif
# ifdef DIAGNOSTICS
      USE def_diags_mod,   ONLY : def_diags
# endif
# ifdef GRID_EXTRACT
      USE def_extract_mod, ONLY : def_extract
# endif
# ifdef FLOATS
      USE def_floats_mod,  ONLY : def_floats
# endif
      USE def_his_mod,     ONLY : def_his
      USE def_quick_mod,   ONLY : def_quick
      USE def_rst_mod,     ONLY : def_rst
# ifdef STATIONS
      USE def_station_mod, ONLY : def_station
# endif
# ifdef DISTRIBUTE
      USE distribute_mod,  ONLY : mp_bcasts
# endif
# ifdef OBSERVATIONS
      USE obs_read_mod,    ONLY : obs_read
      USE obs_write_mod,   ONLY : obs_write
# endif
      USE strings_mod,     ONLY : founderror
# ifdef AVERAGES
      USE wrt_avg_mod,     ONLY : wrt_avg
# endif
# ifdef DIAGNOSTICS
      USE wrt_diags_mod,   ONLY : wrt_diags
# endif
# ifdef GRID_EXTRACT
      USE wrt_extract_mod, ONLY : wrt_extract
# endif
# ifdef FLOATS
      USE wrt_floats_mod,  ONLY : wrt_floats
# endif
      USE wrt_his_mod,     ONLY : wrt_his
      USE wrt_quick_mod,   ONLY : wrt_quick
      USE wrt_rst_mod,     ONLY : wrt_rst
# ifdef STATIONS
      USE wrt_station_mod, ONLY : wrt_station
# endif
# if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
      USE wrt_tides_mod,   ONLY : wrt_tides
# endif
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng
!
!  Local variable declarations.
!
      logical :: Ldefine, Lupdate, NewFile
!
      integer :: Fcount, ifile, status, tile
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
      sourcefile=myfile
 
# ifdef PROFILE
!
!-----------------------------------------------------------------------
!  Turn on output data time wall clock.
!-----------------------------------------------------------------------
!
      CALL wclock_on (ng, inlm, 8, __line__, myfile)
# endif
!
!-----------------------------------------------------------------------
!  If appropriate, process nonlinear history NetCDF file.
!-----------------------------------------------------------------------
!
!  Set tile for local array manipulations in output routines.
!
# ifdef DISTRIBUTE
      tile=myrank
# else
      tile=-1
# endif
!
!  Turn off checking for analytical header files.
!
      IF (lanafile) THEN
        lanafile=.false.
      END IF
!
!  If appropriate, set switch for updating biology header file global
!  attribute in output NetCDF files.
!
# ifdef BIOLOGY
      lupdate=.true.
# else
      lupdate=.false.
# endif
!
!  Create output history NetCDF file or prepare existing file to
!  append new data to it.  Also,  notice that it is possible to
!  create several files during a single model run.
!
      IF (ldefhis(ng)) THEN
        IF (ndefhis(ng).gt.0) THEN
          IF (idefhis(ng).lt.0) THEN
            idefhis(ng)=((ntstart(ng)-1)/ndefhis(ng))*ndefhis(ng)
            IF (idefhis(ng).lt.iic(ng)-1) THEN
              idefhis(ng)=idefhis(ng)+ndefhis(ng)
            END IF
          END IF
          IF ((nrrec(ng).ne.0).and.(iic(ng).eq.ntstart(ng))) THEN
            IF ((iic(ng)-1).eq.idefhis(ng)) THEN
              his(ng)%load=0                  ! restart, reset counter
              ldefine=.false.                 ! finished file, delay
            ELSE                              ! creation of next file
              ldefine=.true.
              newfile=.false.                 ! unfinished file, inquire
            END IF                            ! content for appending
            idefhis(ng)=idefhis(ng)+nhis(ng)  ! restart offset
          ELSE IF ((iic(ng)-1).eq.idefhis(ng)) THEN
            idefhis(ng)=idefhis(ng)+ndefhis(ng)
            IF (nhis(ng).ne.ndefhis(ng).and.iic(ng).eq.ntstart(ng)) THEN
              idefhis(ng)=idefhis(ng)+nhis(ng)  ! multiple record offset
            END IF
            ldefine=.true.
            newfile=.true.
          ELSE
            ldefine=.false.
          END IF
          IF (ldefine) THEN                     ! create new file or
            IF (iic(ng).eq.ntstart(ng)) THEN    ! inquire existing file
              his(ng)%load=0                    ! reset filename counter
            END IF
            ifile=(iic(ng)-1)/ndefhis(ng)+1     ! next filename suffix
            his(ng)%load=his(ng)%load+1
            IF (his(ng)%load.gt.his(ng)%Nfiles) THEN
              IF (master) THEN
                WRITE (stdout,10) 'HIS(ng)%load = ', his(ng)%load,      &
     &                             his(ng)%Nfiles, trim(his(ng)%base),  &
     &                             ifile
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
            fcount=his(ng)%load
            his(ng)%Nrec(fcount)=0
            IF (master) THEN
              WRITE (his(ng)%name,20) trim(his(ng)%base), ifile
            END IF
# ifdef DISTRIBUTE
            CALL mp_bcasts (ng, inlm, his(ng)%name)
# endif
            his(ng)%files(fcount)=trim(his(ng)%name)
            CALL close_file (ng, inlm, his(ng), his(ng)%name, lupdate)
            CALL def_his (ng, newfile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
          IF ((iic(ng).eq.ntstart(ng)).and.(nrrec(ng).ne.0)) THEN
            lwrthis(ng)=.false.                 ! avoid writing initial
          ELSE                                  ! fields during restart
            lwrthis(ng)=.true.
          END IF
        ELSE
          IF (iic(ng).eq.ntstart(ng)) THEN
            CALL def_his (ng, ldefout(ng))
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrthis(ng)=.true.
            ldefhis(ng)=.false.
          END IF
        END IF
      END IF
!
!  Write out data into history NetCDF file.  Avoid writing initial
!  conditions in perturbation mode computations.
!
      IF (lwrthis(ng)) THEN
        IF (lwrtper(ng)) THEN
          IF ((iic(ng).gt.ntstart(ng)).and.                             &
     &        (mod(iic(ng)-1,nhis(ng)).eq.0)) THEN
            IF (nrrec(ng).eq.0.or.iic(ng).ne.ntstart(ng)) THEN
              CALL wrt_his (ng, tile)
            END IF
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        ELSE
          IF (mod(iic(ng)-1,nhis(ng)).eq.0) THEN
            CALL wrt_his (ng, tile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        END IF
      END IF
 
# ifdef GRID_EXTRACT
!
!-----------------------------------------------------------------------
!  If appropriate, process nonlinear history extraction NetCDF file.
!-----------------------------------------------------------------------
!
!  Create output history extraction NetCDF file or prepare existing
!  file to append new data to it.  Also,  notice that it is possible
!  to create several files during a single model run.
!
      IF (ldefxtr(ng)) THEN
        IF (ndefxtr(ng).gt.0) THEN
          IF (idefxtr(ng).lt.0) THEN
            idefxtr(ng)=((ntstart(ng)-1)/ndefxtr(ng))*ndefxtr(ng)
            IF (idefxtr(ng).lt.iic(ng)-1) THEN
              idefxtr(ng)=idefxtr(ng)+ndefxtr(ng)
            END IF
          END IF
          IF ((nrrec(ng).ne.0).and.(iic(ng).eq.ntstart(ng))) THEN
            IF ((iic(ng)-1).eq.idefxtr(ng)) THEN
              xtr(ng)%load=0                  ! restart, reset counter
              ldefine=.false.                 ! finished file, delay
            ELSE                              ! creation of next file
              ldefine=.true.
              newfile=.false.                 ! unfinished file, inquire
            END IF                            ! content for appending
            idefxtr(ng)=idefxtr(ng)+nxtr(ng)  ! restart offset
          ELSE IF ((iic(ng)-1).eq.idefxtr(ng)) THEN
            idefxtr(ng)=idefxtr(ng)+ndefxtr(ng)
            IF (nxtr(ng).ne.ndefxtr(ng).and.iic(ng).eq.ntstart(ng)) THEN
              idefxtr(ng)=idefxtr(ng)+nxtr(ng)  ! multiple record offset
            END IF
            ldefine=.true.
            newfile=.true.
          ELSE
            ldefine=.false.
          END IF
          IF (ldefine) THEN                     ! create new file or
            IF (iic(ng).eq.ntstart(ng)) THEN    ! inquire existing file
              xtr(ng)%load=0                    ! reset filename counter
            END IF
            ifile=(iic(ng)-1)/ndefxtr(ng)+1     ! next filename suffix
            xtr(ng)%load=xtr(ng)%load+1
            IF (xtr(ng)%load.gt.xtr(ng)%Nfiles) THEN
              IF (master) THEN
                WRITE (stdout,10) 'XTR(ng)%load = ', xtr(ng)%load,      &
     &                             xtr(ng)%Nfiles, trim(xtr(ng)%base),  &
     &                             ifile
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
            fcount=xtr(ng)%load
            xtr(ng)%Nrec(fcount)=0
            IF (master) THEN
              WRITE (xtr(ng)%name,20) trim(xtr(ng)%base), ifile
            END IF
#  ifdef DISTRIBUTE
            CALL mp_bcasts (ng, inlm, xtr(ng)%name)
#  endif
            xtr(ng)%files(fcount)=trim(xtr(ng)%name)
            CALL close_file (ng, inlm, xtr(ng), xtr(ng)%name, lupdate)
            CALL def_extract (ng, newfile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
          IF ((iic(ng).eq.ntstart(ng)).and.(nrrec(ng).ne.0)) THEN
            lwrtxtr(ng)=.false.                 ! avoid writing initial
          ELSE                                  ! fields during restart
            lwrtxtr(ng)=.true.
          END IF
        ELSE
          IF (iic(ng).eq.ntstart(ng)) THEN
            CALL def_extract (ng, ldefout(ng))
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrtxtr(ng)=.true.
            ldefxtr(ng)=.false.
          END IF
        END IF
      END IF
!
!  Write out data into history NetCDF file.  Avoid writing initial
!  conditions in perturbation mode computations.
!
      IF (lwrtxtr(ng)) THEN
        IF (lwrtper(ng)) THEN
          IF ((iic(ng).gt.ntstart(ng)).and.                             &
     &        (mod(iic(ng)-1,nxtr(ng)).eq.0)) THEN
            IF (nrrec(ng).eq.0.or.iic(ng).ne.ntstart(ng)) THEN
              CALL wrt_extract (ng, tile)
            END IF
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        ELSE
          IF (mod(iic(ng)-1,nxtr(ng)).eq.0) THEN
            CALL wrt_extract (ng, tile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        END IF
      END IF
# endif
!
!-----------------------------------------------------------------------
!  If appropriate, process nonlinear quicksave NetCDF file.
!-----------------------------------------------------------------------
!
!  Create output quicksave NetCDF file or prepare existing file to
!  append new data to it.  Also,  notice that it is possible to
!  create several files during a single model run.
!
      IF (ldefqck(ng)) THEN
        IF (ndefqck(ng).gt.0) THEN
          IF (idefqck(ng).lt.0) THEN
            idefqck(ng)=((ntstart(ng)-1)/ndefqck(ng))*ndefqck(ng)
            IF (idefqck(ng).lt.iic(ng)-1) THEN
              idefqck(ng)=idefqck(ng)+ndefqck(ng)
            END IF
          END IF
          IF ((nrrec(ng).ne.0).and.(iic(ng).eq.ntstart(ng))) THEN
            IF ((iic(ng)-1).eq.idefqck(ng)) THEN
              qck(ng)%load=0                  ! restart, reset counter
              ldefine=.false.                 ! finished file, delay
            ELSE                              ! creation of next file
              ldefine=.true.
              newfile=.false.                 ! unfinished file, inquire
            END IF                            ! content for appending
            idefqck(ng)=idefqck(ng)+nqck(ng)  ! restart offset
          ELSE IF ((iic(ng)-1).eq.idefqck(ng)) THEN
            idefqck(ng)=idefqck(ng)+ndefqck(ng)
            IF (nqck(ng).ne.ndefqck(ng).and.iic(ng).eq.ntstart(ng)) THEN
              idefqck(ng)=idefqck(ng)+nqck(ng)  ! multiple record offset
            END IF
            ldefine=.true.
            newfile=.true.
          ELSE
            ldefine=.false.
          END IF
          IF (ldefine) THEN                     ! create new file or
            IF (iic(ng).eq.ntstart(ng)) THEN    ! inquire existing file
              qck(ng)%load=0                    ! reset filename counter
            END IF
            ifile=(iic(ng)-1)/ndefqck(ng)+1     ! next filename suffix
            qck(ng)%load=qck(ng)%load+1
            IF (qck(ng)%load.gt.qck(ng)%Nfiles) THEN
              IF (master) THEN
                WRITE (stdout,10) 'QCK(ng)%load = ', qck(ng)%load,      &
     &                             qck(ng)%Nfiles, trim(qck(ng)%base),  &
     &                             ifile
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
            fcount=qck(ng)%load
            qck(ng)%Nrec(fcount)=0
            IF (master) THEN
              WRITE (qck(ng)%name,20) trim(qck(ng)%base), ifile
            END IF
# ifdef DISTRIBUTE
            CALL mp_bcasts (ng, inlm, qck(ng)%name)
# endif
            qck(ng)%files(fcount)=trim(qck(ng)%name)
            CALL close_file (ng, inlm, qck(ng), qck(ng)%name, lupdate)
            CALL def_quick (ng, newfile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
          IF ((iic(ng).eq.ntstart(ng)).and.(nrrec(ng).ne.0)) THEN
            lwrtqck(ng)=.false.                 ! avoid writing initial
          ELSE                                  ! fields during restart
            lwrtqck(ng)=.true.
          END IF
        ELSE
          IF (iic(ng).eq.ntstart(ng)) THEN
            CALL def_quick (ng, ldefout(ng))
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrtqck(ng)=.true.
            ldefqck(ng)=.false.
          END IF
        END IF
      END IF
!
!  Write out data into quicksave NetCDF file.  Avoid writing initial
!  conditions in perturbation mode computations.
!
      IF (lwrtqck(ng)) THEN
        IF (lwrtper(ng)) THEN
          IF ((iic(ng).gt.ntstart(ng)).and.                             &
     &        (mod(iic(ng)-1,nqck(ng)).eq.0)) THEN
            IF (nrrec(ng).eq.0.or.iic(ng).ne.ntstart(ng)) THEN
              CALL wrt_quick (ng, tile)
            END IF
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        ELSE
          IF (mod(iic(ng)-1,nqck(ng)).eq.0) THEN
            CALL wrt_quick (ng, tile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        END IF
      END IF
 
# ifdef AVERAGES
!
!-----------------------------------------------------------------------
!  If appropriate, process time-averaged NetCDF file.
!-----------------------------------------------------------------------
!
!  Create output time-averaged NetCDF file or prepare existing file
!  to append new data to it. Also, notice that it is possible to
!  create several files during a single model run.
!
      IF (ldefavg(ng)) THEN
        IF (ndefavg(ng).gt.0) THEN
          IF (idefavg(ng).lt.0) THEN
            idefavg(ng)=((ntstart(ng)-1)/ndefavg(ng))*ndefavg(ng)
            IF ((ndefavg(ng).eq.navg(ng)).and.(idefavg(ng).le.0)) THEN
              idefavg(ng)=ndefavg(ng)         ! one file per record
            ELSE IF (idefavg(ng).lt.iic(ng)-1) THEN
              idefavg(ng)=idefavg(ng)+ndefavg(ng)
            END IF
          END IF
          IF ((nrrec(ng).ne.0).and.(iic(ng).eq.ntstart(ng))) THEN
            IF ((iic(ng)-1).eq.idefavg(ng)) THEN
              avg(ng)%load=0                  ! restart, reset counter
              ldefine=.false.                 ! finished file, delay
            ELSE                              ! creation of next file
              newfile=.false.
              ldefine=.true.                  ! unfinished file, inquire
            END IF                            ! content for appending
            idefavg(ng)=idefavg(ng)+navg(ng)  ! restart offset
          ELSE IF ((iic(ng)-1).eq.idefavg(ng)) THEN
            idefavg(ng)=idefavg(ng)+ndefavg(ng)
            IF (navg(ng).ne.ndefavg(ng).and.iic(ng).eq.ntstart(ng)) THEN
              idefavg(ng)=idefavg(ng)+navg(ng)
            END IF
            ldefine=.true.
            newfile=.true.
          ELSE
            ldefine=.false.
          END IF
          IF (ldefine) THEN
            IF (iic(ng).eq.ntstart(ng)) THEN
              avg(ng)%load=0                  ! reset filename counter
            END IF
            IF (ndefavg(ng).eq.navg(ng)) THEN ! next filename suffix
              ifile=(iic(ng)-1)/ndefavg(ng)
            ELSE
              ifile=(iic(ng)-1)/ndefavg(ng)+1
            END IF
            avg(ng)%load=avg(ng)%load+1
            IF (avg(ng)%load.gt.avg(ng)%Nfiles) THEN
              IF (master) THEN
                WRITE (stdout,10) 'AVG(ng)%load = ', avg(ng)%load,      &
     &                             avg(ng)%Nfiles, trim(avg(ng)%base),  &
     &                             ifile
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
            fcount=avg(ng)%load
            avg(ng)%Nrec(fcount)=0
            IF (master) THEN
              WRITE (avg(ng)%name,20) trim(avg(ng)%base), ifile
            END IF
#  ifdef DISTRIBUTE
            CALL mp_bcasts (ng, inlm, avg(ng)%name)
#  endif
            avg(ng)%files(fcount)=trim(avg(ng)%name)
            CALL close_file (ng, inlm, avg(ng), avg(ng)%name, lupdate)
            CALL def_avg (ng, newfile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrtavg(ng)=.true.
          END IF
        ELSE
          IF (iic(ng).eq.ntstart(ng)) THEN
            CALL def_avg (ng, ldefout(ng))
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrtavg(ng)=.true.
            ldefavg(ng)=.false.
          END IF
        END IF
      END IF
!
!  Write out data into time-averaged NetCDF file.
!
      IF (lwrtavg(ng)) THEN
        IF (((iic(ng).gt.ntstart(ng)).and.                              &
     &       (mod(iic(ng)-1,navg(ng)).eq.0)).or.                        &
     &      ((iic(ng).ge.ntsavg(ng)).and.(navg(ng).eq.1))) THEN
          CALL wrt_avg (ng, tile)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#  if defined AVERAGES_DETIDE && (defined SSH_TIDES || defined UV_TIDES)
          CALL wrt_tides (ng, tile)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#  endif
        END IF
      END IF
# endif
 
# ifdef DIAGNOSTICS
!
!-----------------------------------------------------------------------
!  If appropriate, process time-averaged diagnostics NetCDF file.
!-----------------------------------------------------------------------
!
!  Create output time-averaged diagnostics NetCDF file or prepare
!  existing file to append new data to it. Also, notice that it is
!  possible to create several files during a single model run.
!
      IF (ldefdia(ng)) THEN
        IF (ndefdia(ng).gt.0) THEN
          IF (idefdia(ng).lt.0) THEN
            idefdia(ng)=((ntstart(ng)-1)/ndefdia(ng))*ndefdia(ng)
            IF ((ndefdia(ng).eq.ndia(ng)).and.(idefdia(ng).le.0)) THEN
              idefdia(ng)=ndefdia(ng)         ! one file per record
            ELSE IF (idefdia(ng).lt.iic(ng)-1) THEN
              idefdia(ng)=idefdia(ng)+ndefdia(ng)
            END IF
          END IF
          IF ((nrrec(ng).ne.0).and.(iic(ng).eq.ntstart(ng))) THEN
            IF ((iic(ng)-1).eq.idefdia(ng)) THEN
              dia(ng)%load=0                  ! restart, reset counter
              ldefine=.false.                 ! finished file, delay
            ELSE                              ! creation of next file
              newfile=.false.
              ldefine=.true.                  ! unfinished file, inquire
            END IF                            ! content for appending
            idefdia(ng)=idefdia(ng)+ndia(ng)  ! restart offset
          ELSE IF ((iic(ng)-1).eq.idefdia(ng)) THEN
            idefdia(ng)=idefdia(ng)+ndefdia(ng)
            IF (ndia(ng).ne.ndefdia(ng).and.iic(ng).eq.ntstart(ng)) THEN
              idefdia(ng)=idefdia(ng)+ndia(ng)
            END IF
            ldefine=.true.
            newfile=.true.
          ELSE
            ldefine=.false.
          END IF
          IF (ldefine) THEN
            IF (iic(ng).eq.ntstart(ng)) THEN
              dia(ng)%load=0                  ! reset filename counter
            END IF
            IF (ndefdia(ng).eq.ndia(ng)) THEN ! next filename suffix
              ifile=(iic(ng)-1)/ndefdia(ng)
            ELSE
              ifile=(iic(ng)-1)/ndefdia(ng)+1
            END IF
            dia(ng)%load=dia(ng)%load+1
            IF (dia(ng)%load.gt.dia(ng)%Nfiles) THEN
              IF (master) THEN
                WRITE (stdout,10) 'DIA(ng)%load = ', dia(ng)%load,      &
     &                             dia(ng)%Nfiles, trim(dia(ng)%base),  &
     &                             ifile
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
            fcount=dia(ng)%load
            dia(ng)%Nrec(fcount)=0
            IF (master) THEN
              WRITE (dia(ng)%name,20) trim(dia(ng)%base), ifile
            END IF
#  ifdef DISTRIBUTE
            CALL mp_bcasts (ng, inlm, dia(ng)%name)
#  endif
            dia(ng)%files(fcount)=trim(dia(ng)%name)
            CALL close_file (ng, inlm, dia(ng), dia(ng)%name, lupdate)
            CALL def_diags (ng, newfile)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrtdia(ng)=.true.
          END IF
        ELSE
          IF (iic(ng).eq.ntstart(ng)) THEN
            CALL def_diags (ng, ldefout(ng))
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
            lwrtdia(ng)=.true.
            ldefdia(ng)=.false.
          END IF
        END IF
      END IF
!
!  Write out data into time-averaged diagnostics NetCDF file.
!
      IF (lwrtdia(ng)) THEN
        IF (((iic(ng).gt.ntstart(ng)).and.                              &
     &       (mod(iic(ng)-1,ndia(ng)).eq.0)).or.                        &
     &      ((iic(ng).ge.ntsdia(ng)).and.(ndia(ng).eq.1))) THEN
          CALL wrt_diags (ng, tile)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
      END IF
# endif
 
# ifdef STATIONS
!
!-----------------------------------------------------------------------
!  If appropriate, process stations NetCDF file.
!-----------------------------------------------------------------------
!
      IF (lstations(ng).and.                                            &
     &    (nstation(ng).gt.0).and.(nsta(ng).gt.0)) THEN
!
!  Create output station NetCDF file or prepare existing file to
!  append new data to it.
!
        IF (ldefsta(ng).and.(iic(ng).eq.ntstart(ng))) THEN
          CALL def_station (ng, ldefout(ng))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          ldefsta(ng)=.false.
        END IF
!
!  Write out data into stations NetCDF file.
!
        IF (mod(iic(ng)-1,nsta(ng)).eq.0) THEN
          CALL wrt_station (ng, tile)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
      END IF
# endif
 
# ifdef FLOATS
!
!-----------------------------------------------------------------------
!  If appropriate, process floats NetCDF file.
!-----------------------------------------------------------------------
!
      IF (lfloats(ng).and.                                              &
     &    (nfloats(ng).gt.0).and.(nflt(ng).gt.0)) THEN
!
!  Create output floats NetCDF file or prepare existing file to
!  append new data to it.
!
        IF (ldefflt(ng)) THEN
          IF (frrec(ng).eq.0) THEN
            newfile=.true.
          ELSE
            newfile=.false.
          END IF
          CALL def_floats (ng, newfile)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          ldefflt(ng)=.false.
        END IF
!
!  Write out data into floats NetCDF file.
!
        IF ((mod(iic(ng)-1,nflt(ng)).eq.0).and.                         &
     &      ((frrec(ng).eq.0).or.(iic(ng).ne.ntstart(ng)))) THEN
          CALL wrt_floats (ng)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
      END IF
# endif
!
!-----------------------------------------------------------------------
!  If appropriate, process restart NetCDF file.
!-----------------------------------------------------------------------
!
!  Create output restart NetCDF file or prepare existing file to
!  append new data to it.
!
      IF (ldefrst(ng)) THEN
        CALL def_rst (ng)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        lwrtrst(ng)=.true.
        ldefrst(ng)=.false.
      END IF
!
!  Write out data into restart NetCDF file.
!
      IF (lwrtrst(ng)) THEN
        IF ((iic(ng).gt.ntstart(ng)).and.                               &
     &      (mod(iic(ng)-1,nrst(ng)).eq.0)) THEN
          CALL wrt_rst (ng, tile)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
      END IF
 
# if (defined FOUR_DVAR              || \
      defined verification)          && \
     !defined I4DVAR_ANA_SENSITIVITY
#  ifdef OBSERVATIONS
!
!-----------------------------------------------------------------------
!  If appropriate, process and write model state at observation
!  locations. Compute misfit (model-observations) cost function.
!-----------------------------------------------------------------------
!
      IF (((time(ng)-0.5_r8*dt(ng)).le.obstime(ng)).and.                &
     &    (obstime(ng).lt.(time(ng)+0.5_r8*dt(ng)))) THEN
        processobs=.true.
        CALL obs_read (ng, inlm, .false.)
#   ifdef SP4DVAR
        IF (iic(ng).ne.ntend(ng)+1.or.lsadd(ng)) THEN
          CALL obs_write (ng, tile, inlm)
          CALL obs_cost (ng, inlm)
        END IF
#   else
        CALL obs_write (ng, tile, inlm)
#    if !(defined R4DVAR || defined VERIFICATION)
        CALL obs_cost (ng, inlm)
#    endif
#   endif
      ELSE
        processobs=.false.
      END IF
#  endif
# endif
# ifdef PROFILE
!
!-----------------------------------------------------------------------
!  Turn off output data time wall clock.
!-----------------------------------------------------------------------
!
      CALL wclock_off (ng, inlm, 8, __line__, myfile)
# endif
!
 10   FORMAT (/,' OUTPUT - multi-file counter ',a,i0,                   &
     &          ', is greater than Nfiles = ',i0,1x,'dimension',        &
     &        /,10x,'in structure when creating next file: ',           &
     &           a,'_',i4.4,'.nc',                                      &
     &        /,10x,'Incorrect OutFiles logic in ''read_phypar''.')
 20   FORMAT (a,'_',i4.4,'.nc')
!
      RETURN
      END SUBROUTINE output
#else
      SUBROUTINE output
      RETURN
      END SUBROUTINE output
#endif