get_2dfld.F File Reference

#include "cppdefs.h"

Include dependency graph for get_2dfld.F:

Go to the source code of this file.

Functions/Subroutines
subroutine	get_2dfld (ng, model, ifield, ncid, piofile, nfiles, s, update, lbi, ubi, lbj, ubj, iout, irec, fmask, fout)
subroutine	get_2dfld_nf90 (ng, model, ifield, ncid, nfiles, s, update, lbi, ubi, lbj, ubj, iout, irec, fmask, fout)
subroutine	get_2dfld_pio (ng, model, ifield, piofile, nfiles, s, update, lbi, ubi, lbj, ubj, iout, irec, fmask, fout)

Function/Subroutine Documentation

get_2dfld()

subroutine get_2dfld	(	integer, intent(in)	ng,
		integer, intent(in)	model,
		integer, intent(in)	ifield,
		integer, intent(inout)	ncid,
		type (file_desc_t), intent(inout)	piofile,
		integer, intent(in)	nfiles,
		type(t_io), dimension(nfiles), intent(inout)	s,
		logical, intent(out)	update,
		integer, intent(in)	lbi,
		integer, intent(in)	ubi,
		integer, intent(in)	lbj,
		integer, intent(in)	ubj,
		integer, intent(in)	iout,
		integer, intent(in)	irec,
		real(r8), dimension(lbi:ubi,lbj:ubj), intent(in)	fmask,
		real(r8), dimension(lbi:ubi,lbj:ubj,iout), intent(inout)	fout )

Definition at line 2 of file get_2dfld.F.

!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine reads in requested 2D field (point or grided) from     !
!  specified NetCDF file. Forward time processing.                     !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng         Nested grid number.                                   !
!     model      Calling model identifier.                             !
!     ifield     Field ID.                                             !
!     ncid       NetCDF file ID.                                       !
#if defined PIO_LIB && defined DISTRIBUTE
!     pioFile    PIO file descriptor structure, TYPE(file_desc_t)      !
!                  pioFile%fh         file handler                     !
!                  pioFile%iosystem   IO system descriptor (struct)    !
#endif
!     nfiles     Number of input NetCDF files.                         !
!     S          I/O derived type structure, TYPE(T_IO).               !
!     LBi        I-dimension Lower bound.                              !
!     UBi        I-dimension Upper bound.                              !
!     LBj        J-dimension Lower bound.                              !
!     UBj        J-dimension Upper bound.                              !
!     Iout       Size of the outer dimension,  if any.  Otherwise,     !
!                  Iout must be set to one by the calling program.     !
!     Irec       Number of 2D field records to read.                   !
!     Fmask      Land/Sea mask, if any.                                !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     Fout       Read field.                                           !
!     update     Switch indicating reading of the requested field      !
!                  the current time step.                              !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE strings_mod, ONLY : founderror
!
      implicit none
!
!  Imported variable declarations.
!
      logical, intent(out) :: update
!
      integer, intent(in) :: ng, model, ifield, nfiles, Iout, Irec
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(inout) :: ncid
!
#if defined PIO_LIB && defined DISTRIBUTE
      TYPE (File_desc_t), intent(inout) :: pioFile
#endif
      TYPE(T_IO), intent(inout) :: S(nfiles)
!
#ifdef MASKING
      real(r8), intent(in) :: Fmask(LBi:UBi,LBj:UBj)
#endif
      real(r8), intent(inout) :: Fout(LBi:UBi,LBj:UBj,Iout)
!
!  Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
!-----------------------------------------------------------------------
!  Read in requested 2D field according to IO type.
!-----------------------------------------------------------------------
!
      SELECT CASE (s(1)%IOtype)
        CASE (io_nf90)
          CALL get_2dfld_nf90 (ng, model, ifield, ncid, nfiles, s,      &
     &                         update, lbi, ubi, lbj, ubj, iout, irec,  &
#ifdef MASKING
     &                         fmask,                                   &
#endif
     &                         fout)
 
#if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL get_2dfld_pio (ng, model, ifield, piofile, nfiles, s,    &
     &                        update, lbi, ubi, lbj, ubj, iout, irec,   &
# ifdef MASKING
     &                        fmask,                                    &
# endif
     &                        fout)
#endif
        CASE DEFAULT
          IF (master) WRITE (stdout,10) s(1)%IOtype
          exit_flag=2
      END SELECT
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
  10  FORMAT (' GET_2DFLD - Illegal input file type, io_type = ',i0,    &
     &        /,13x,'Check KeyWord ''INP_LIB'' in ''roms.in''.')
!
      RETURN

References mod_scalars::exit_flag, strings_mod::founderror(), get_2dfld_nf90(), get_2dfld_pio(), mod_ncparam::io_nf90, mod_ncparam::io_pio, mod_parallel::master, mod_scalars::noerror, and mod_iounits::stdout.

Referenced by get_data(), get_idata(), rp_get_data(), rp_get_idata(), tl_get_data(), and tl_get_idata().

Here is the call graph for this function:

Here is the caller graph for this function:

get_2dfld_nf90()

subroutine get_2dfld_nf90	(	integer, intent(in)	ng,
		integer, intent(in)	model,
		integer, intent(in)	ifield,
		integer, intent(inout)	ncid,
		integer, intent(in)	nfiles,
		type(t_io), dimension(nfiles), intent(inout)	s,
		logical, intent(out)	update,
		integer, intent(in)	lbi,
		integer, intent(in)	ubi,
		integer, intent(in)	lbj,
		integer, intent(in)	ubj,
		integer, intent(in)	iout,
		integer, intent(in)	irec,
		real(r8), dimension(lbi:ubi,lbj:ubj), intent(in)	fmask,
		real(r8), dimension(lbi:ubi,lbj:ubj,iout), intent(inout)	fout )

Definition at line 121 of file get_2dfld.F.

!***********************************************************************
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_netcdf
      USE mod_scalars
!
      USE dateclock_mod,  ONLY : time_string
      USE inquiry_mod,    ONLY : inquiry
      USE nf_fread2d_mod, ONLY : nf_fread2d
      USE nf_fread3d_mod, ONLY : nf_fread3d
      USE strings_mod,    ONLY : founderror
!
      implicit none
!
!  Imported variable declarations.
!
      logical, intent(out) :: update
!
      integer, intent(in) :: ng, model, ifield, nfiles, Iout, Irec
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(inout) :: ncid
!
      TYPE(T_IO), intent(inout) :: S(nfiles)
!
#ifdef MASKING
      real(r8), intent(in) :: Fmask(LBi:UBi,LBj:UBj)
#endif
      real(r8), intent(inout) :: Fout(LBi:UBi,LBj:UBj,Iout)
!
!  Local variable declarations.
!
      logical :: Lgridded, Linquire, Liocycle, Lmulti, Lonerec, Lregrid
      logical :: special
!
      integer :: Nrec, Tid, Tindex, Trec, Vid, Vtype
      integer :: gtype, job, lend, lstr, lvar, status
      integer :: Vsize(4)
#ifdef CHECKSUM
      integer(i8b) :: Fhash
#endif
!
      real(r8) :: Fmax, Fmin, Fval
 
      real(dp) :: Clength, Tdelta, Tend
      real(dp) :: Tmax, Tmin, Tmono, Tscale, Tstr
      real(dp) :: Tsec, Tval
!
      character (len= 1) :: Rswitch
      character (len=22) :: t_code
 
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", get_2dfld_nf90"
!
      sourcefile=myfile
!
!-----------------------------------------------------------------------
!  Initialize.
!-----------------------------------------------------------------------
!
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Determine if inquiring about the field to process in input NetCDF
!  file(s).  This usually happens on first call or when the field
!  time records are split (saved) in several multi-files.
!
      linquire=.false.
      lmulti=.false.
      IF (iic(ng).eq.0) linquire=.true.
      IF (.not.linquire.and.                                            &
     &    ((iinfo(10,ifield,ng).gt.1).and.                              &
     &     (linfo( 6,ifield,ng).or.                                     &
     &     (finfo( 2,ifield,ng)*day2sec.lt.time(ng))))) THEN
        linquire=.true.
        lmulti=.true.
      END IF
!
!  If appropriate, inquire about the contents of input NetCDF file and
!  fill information arrays.
!
!  Also, if appropriate, deactivate the Linfo(6,ifield,ng) switch after
!  the query for the UPPER snapshot interpolant from previous multifile
!  in the list. The switch was activated previously to indicate the
!  processing of the FIRST record of the file for the LOWER snapshot
!  interpolant.
!
      IF (linquire) THEN
        job=2
        CALL inquiry (ng, model, job, iout, irec, 1, ifield, ncid,      &
     &                lmulti, nfiles, s)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        IF (linfo(6,ifield,ng)) THEN
          linfo(6,ifield,ng)=.false.
        END IF
      END IF
!
!-----------------------------------------------------------------------
!  If appropriate, read in new data.
!-----------------------------------------------------------------------
!
      update=.false.
      lregrid=.false.
      tmono=finfo(7,ifield,ng)
!
      IF ((tmono.lt.time(ng)).or.(iic(ng).eq.0).or.                     &
     &    (iic(ng).eq.ntstart(ng))) THEN
!
!  Load properties for requested field from information arrays.
!
        lgridded=linfo(1,ifield,ng)
        liocycle=linfo(2,ifield,ng)
        lonerec =linfo(3,ifield,ng)
        special =linfo(4,ifield,ng)
        vtype   =iinfo(1,ifield,ng)
        vid     =iinfo(2,ifield,ng)
        tid     =iinfo(3,ifield,ng)
        nrec    =iinfo(4,ifield,ng)
        vsize(1)=iinfo(5,ifield,ng)
        vsize(2)=iinfo(6,ifield,ng)
        tindex  =iinfo(8,ifield,ng)
        trec    =iinfo(9,ifield,ng)
        tmin    =finfo(1,ifield,ng)
        tmax    =finfo(2,ifield,ng)
        clength =finfo(5,ifield,ng)
        tscale  =finfo(6,ifield,ng)
        ncfile  =cinfo(ifield,ng)
!
        IF (liocycle) THEN
          trec=mod(trec,nrec)+1
        ELSE
          trec=trec+1
        END IF
        iinfo(9,ifield,ng)=trec
!
        IF (trec.le.nrec) THEN
!
!  Set rolling index for two-time record storage of input data.  If
!  "Iout" is unity, input data is stored in timeless array by the
!  calling program.  If Irec > 1, this routine is used to read a 2D
!  field varying in another non-time dimension like tidal constituent
!  component.
!
          IF (.not.special.and.(irec.eq.1)) THEN
            IF (iout.eq.1) THEN
              tindex=1
            ELSE
              tindex=3-tindex
            END IF
            iinfo(8,ifield,ng)=tindex
          END IF
!
!  Read in time coordinate and scale it to day units.
!
          IF (.not.special.and.(tid.ge.0)) THEN
            CALL netcdf_get_time (ng, model, ncfile, tname(ifield),     &
     &                            rclock%DateNumber, tval,              &
     &                            ncid = ncid,                          &
     &                            start = (/trec/),                     &
     &                            total = (/1/))
            IF (founderror(exit_flag, noerror, __line__, myfile)) THEN
              IF (master) WRITE (stdout,40) trim(tname(ifield)), trec
              RETURN
            END IF
            tval=tval*tscale
            vtime(tindex,ifield,ng)=tval
!
!  Activate switch Linfo(6,ifield,ng) if processing the LAST record of
!  the file for the LOWER time snapshot. We need to get the UPPER time
!  snapshot from NEXT multifile.
!
            IF ((trec.eq.nrec).and.(tval*day2sec.le.time(ng))) THEN
              linfo(6,ifield,ng)=.true.
            END IF
          END IF
!
!  Read in 2D-grided or point data. Notice for special 2D fields, Vtype
!  is augmented by four indicating reading a 3D field. This rational is
!  used to read fields like tide data.
!
          IF (vid.ge.0) THEN
            IF (lgridded) THEN
              IF (special) THEN
                vsize(3)=irec
                gtype=vtype+4
                status=nf_fread3d(ng, model, ncfile, ncid,              &
     &                            vname(1,ifield), vid,                 &
     &                            0, gtype, vsize,                      &
     &                            lbi, ubi, lbj, ubj, 1, irec,          &
     &                            fscale(ifield,ng), fmin, fmax,        &
#ifdef MASKING
     &                            fmask,                                &
#endif
#ifdef CHECKSUM
     &                            fout,                                 &
     &                            checksum = fhash)
#else
     &                            fout)
#endif
              ELSE
                status=nf_fread2d(ng, model, ncfile, ncid,              &
     &                            vname(1,ifield), vid,                 &
     &                            trec, vtype, vsize,                   &
     &                            lbi, ubi, lbj, ubj,                   &
     &                            fscale(ifield,ng), fmin, fmax,        &
#ifdef MASKING
     &                            fmask,                                &
#endif
     &                            fout(:,:,tindex),                     &
#ifdef CHECKSUM
     &                            checksum = fhash,                     &
#endif
     &                            lregrid = lregrid)
 
              END IF
            ELSE
              CALL netcdf_get_fvar (ng, model, ncfile,                  &
     &                              vname(1,ifield), fval,              &
     &                              ncid = ncid,                        &
     &                              start = (/trec/),                   &
     &                              total = (/1/))
              fval=fval*fscale(ifield,ng)
              fpoint(tindex,ifield,ng)=fval
              fmin=fval
              fmax=fval
            END IF
            IF (founderror(exit_flag, noerror, __line__, myfile)) THEN
              IF (master) WRITE (stdout,40) trim(vname(1,ifield)), trec
              RETURN
            END IF
            finfo(8,ifield,ng)=fmin
            finfo(9,ifield,ng)=fmax
            IF (master) THEN
              IF (special) THEN
                WRITE (stdout,50) trim(vname(2,ifield)), ng, fmin, fmax
              ELSE
                lstr=scan(ncfile,'/',back=.true.)+1
                lend=len_trim(ncfile)
                lvar=min(46,len_trim(vname(2,ifield)))
                tsec=tval*day2sec
                CALL time_string (tsec, t_code)
                IF (lregrid) THEN
                  rswitch='T'
                ELSE
                  rswitch='F'
                END IF
                WRITE (stdout,60) vname(2,ifield)(1:lvar), t_code,      &
     &                            ng, trec, tindex, ncfile(lstr:lend),  &
     &                            tmin, tmax, tval, fmin, fmax, rswitch
              END IF
#ifdef CHECKSUM
              WRITE (stdout,70) fhash
#endif
            END IF
            update=.true.
          END IF
        END IF
!
!  Increment the local time variable "Tmono" by the interval between
!  snapshots. If the interval is negative, indicating cycling, add in
!  a cycle length.  Load time value (sec) into "Tintrp" which used
!  during interpolation between snapshots.
!
        IF (.not.lonerec.and.(.not.special)) THEN
          tdelta=vtime(tindex,ifield,ng)-vtime(3-tindex,ifield,ng)
          IF (liocycle.and.(tdelta.lt.0.0_r8)) THEN
            tdelta=tdelta+clength
          END IF
          tmono=tmono+tdelta*day2sec
          finfo(7,ifield,ng)=tmono
          tintrp(tindex,ifield,ng)=tmono
        END IF
      END IF
!
  10  FORMAT (/,' GET_2DFLD_NF90 - unable to find dimension ',a,        &
     &        /,18x,'for variable: ',a,/,18x,'in file: ',a,             &
     &        /,18x,'file is not CF compliant...')
  20  FORMAT (/,' GET_2DFLD_NF90 - unable to find requested variable:', &
     &        1x,a,/,18x,'in ',a)
  30  FORMAT (/,' GET_2DFLD_NF90 - unable to open input NetCDF',        &
     &        ' file: ',a)
  40  FORMAT (/,' GET_2DFLD_NF90 - error while reading variable: ',a,   &
     &        2x,' at TIME index = ',i0)
  50  FORMAT (2x,'GET_2DFLD_NF90   - ',a,/,22x,'(Grid = ',i2.2,         &
     &        ', Min = ',1p,e15.8,0p,' Max = ',1p,e15.8,0p,')')
  60  FORMAT (2x,'GET_2DFLD_NF90   - ',a,',',t75,a,/,22x,               &
     &        '(Grid=',i2.2,', Rec=',i0,', Index=',i1,                  &
     &          ', File: ',a,')',/,22x,                                 &
     &        '(Tmin= ', f15.4, ' Tmax= ', f15.4,')',                   &
     &        t71, 't = ', f15.4 ,/, 22x,                               &
     &        '(Min = ', 1p,e15.8,0p,' Max = ',1p,e15.8,0p,')',         &
     &        t71, 'regrid = ',a)
#ifdef CHECKSUM
  70  FORMAT (22x,'(CheckSum = ',i0,')')
#endif
!
      RETURN

References mod_ncparam::cinfo, mod_scalars::day2sec, mod_scalars::exit_flag, mod_ncparam::finfo, strings_mod::founderror(), mod_ncparam::fpoint, mod_ncparam::fscale, mod_scalars::iic, mod_ncparam::iinfo, mod_ncparam::linfo, mod_parallel::master, mod_iounits::ncfile, mod_scalars::noerror, mod_scalars::ntstart, mod_scalars::rclock, mod_iounits::sourcefile, mod_iounits::stdout, mod_scalars::time, dateclock_mod::time_string(), mod_ncparam::tintrp, mod_ncparam::tname, mod_ncparam::vname, and mod_ncparam::vtime.

Referenced by get_2dfld().

Here is the call graph for this function:

Here is the caller graph for this function:

get_2dfld_pio()

subroutine get_2dfld_pio	(	integer, intent(in)	ng,
		integer, intent(in)	model,
		integer, intent(in)	ifield,
		type (file_desc_t), intent(inout)	piofile,
		integer, intent(in)	nfiles,
		type(t_io), dimension(nfiles), intent(inout)	s,
		logical, intent(out)	update,
		integer, intent(in)	lbi,
		integer, intent(in)	ubi,
		integer, intent(in)	lbj,
		integer, intent(in)	ubj,
		integer, intent(in)	iout,
		integer, intent(in)	irec,
		real(r8), dimension(lbi:ubi,lbj:ubj), intent(in)	fmask,
		real(r8), dimension(lbi:ubi,lbj:ubj,iout), intent(inout)	fout )

Definition at line 431 of file get_2dfld.F.

!***********************************************************************
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_pio_netcdf
      USE mod_scalars
!
      USE dateclock_mod,  ONLY : time_string
      USE inquiry_mod,    ONLY : inquiry
      USE nf_fread2d_mod, ONLY : nf_fread2d
      USE nf_fread3d_mod, ONLY : nf_fread3d
      USE strings_mod,    ONLY : founderror
!
      implicit none
!
!  Imported variable declarations.
!
      logical, intent(out) :: update
!
      integer, intent(in) :: ng, model, ifield, nfiles, Iout, Irec
      integer, intent(in) :: LBi, UBi, LBj, UBj
!
      TYPE (File_desc_t), intent(inout) :: pioFile
      TYPE(T_IO), intent(inout) :: S(nfiles)
!
# ifdef MASKING
      real(r8), intent(in) :: Fmask(LBi:UBi,LBj:UBj)
# endif
      real(r8), intent(inout) :: Fout(LBi:UBi,LBj:UBj,Iout)
!
!  Local variable declarations.
!
      logical :: Lgridded, Linquire, Liocycle, Lmulti, Lonerec, Lregrid
      logical :: special
!
      integer :: Nrec, Tindex, Trec, Vtype
      integer :: i, job, lend, lstr, lvar, status
      integer :: Vsize(4)
# ifdef CHECKSUM
      integer(i8b) :: Fhash
# endif
!
      real(r8) :: Fmax, Fmin, Fval
 
      real(dp) :: Clength, Tdelta, Tend
      real(dp) :: Tmax, Tmin, Tmono, Tscale, Tstr
      real(dp) :: Tsec, Tval
!
      character (len= 1) :: Rswitch
      character (len=22) :: t_code
 
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", get_2dfld_pio"
!
      TYPE (IO_Desc_t), pointer :: ioDesc
      TYPE (My_VarDesc) :: TpioVar, VpioVar
!
      sourcefile=myfile
!
!-----------------------------------------------------------------------
!  Initialize.
!-----------------------------------------------------------------------
!
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Determine if inquiring about the field to process in input NetCDF
!  file(s).  This usually happens on first call or when the field
!  time records are split (saved) in several multi-files.
!
      linquire=.false.
      lmulti=.false.
      IF (iic(ng).eq.0) linquire=.true.
      IF (.not.linquire.and.                                            &
     &    ((iinfo(10,ifield,ng).gt.1).and.                              &
     &     (linfo( 6,ifield,ng).or.                                     &
     &     (finfo( 2,ifield,ng)*day2sec.lt.time(ng))))) THEN
        linquire=.true.
        lmulti=.true.
      END IF
!
!  If appropriate, inquire about the contents of input NetCDF file and
!  fill information arrays.
!
!  Also, if appropriate, deactivate the Linfo(6,ifield,ng) switch after
!  the query for the UPPER snapshot interpolant from previous multifile
!  in the list. The switch was activated previously to indicate the
!  processing of the FIRST record of the file for the LOWER snapshot
!  interpolant.
!
      IF (linquire) THEN
        job=2
        CALL inquiry (ng, model, job, iout, irec, 1, ifield, piofile,   &
     &                lmulti, nfiles, s)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        IF (linfo(6,ifield,ng)) THEN
          linfo(6,ifield,ng)=.false.
        END IF
      END IF
!
!-----------------------------------------------------------------------
!  If appropriate, read in new data.
!-----------------------------------------------------------------------
!
      update=.false.
      lregrid=.false.
      tmono=finfo(7,ifield,ng)
!
      IF ((tmono.lt.time(ng)).or.(iic(ng).eq.0).or.                     &
     &    (iic(ng).eq.ntstart(ng))) THEN
!
!  Load properties for requested field from information arrays.
!
        lgridded=linfo(1,ifield,ng)
        liocycle=linfo(2,ifield,ng)
        lonerec =linfo(3,ifield,ng)
        special =linfo(4,ifield,ng)
        vtype   =iinfo(1,ifield,ng)
        vpiovar =dinfo(1,ifield,ng)
        tpiovar =dinfo(2,ifield,ng)
        nrec    =iinfo(4,ifield,ng)
        vsize(1)=iinfo(5,ifield,ng)
        vsize(2)=iinfo(6,ifield,ng)
        tindex  =iinfo(8,ifield,ng)
        trec    =iinfo(9,ifield,ng)
        tmin    =finfo(1,ifield,ng)
        tmax    =finfo(2,ifield,ng)
        clength =finfo(5,ifield,ng)
        tscale  =finfo(6,ifield,ng)
        ncfile  =cinfo(ifield,ng)
!
        IF (liocycle) THEN
          trec=mod(trec,nrec)+1
        ELSE
          trec=trec+1
        END IF
        iinfo(9,ifield,ng)=trec
!
        IF (trec.le.nrec) THEN
!
!  Set rolling index for two-time record storage of input data.  If
!  "Iout" is unity, input data is stored in timeless array by the
!  calling program.  If Irec > 1, this routine is used to read a 2D
!  field varying in another non-time dimension like tidal constituent
!  component.
!
          IF (.not.special.and.(irec.eq.1)) THEN
            IF (iout.eq.1) THEN
              tindex=1
            ELSE
              tindex=3-tindex
            END IF
            iinfo(8,ifield,ng)=tindex
          END IF
!
!  Read in time coordinate and scale it to day units.
!
          IF (.not.special.and.(tpiovar%vd%varID.ge.0)) THEN
            CALL pio_netcdf_get_time (ng, model, ncfile, tname(ifield), &
     &                                rclock%DateNumber, tval,          &
     &                                piofile = piofile,                &
     &                                start = (/trec/),                 &
     &                                total = (/1/))
            IF (founderror(exit_flag, noerror, __line__, myfile)) THEN
              IF (master) WRITE (stdout,40) trim(tname(ifield)), trec
              RETURN
            END IF
            tval=tval*tscale
            vtime(tindex,ifield,ng)=tval
!
!  Activate switch Linfo(6,ifield,ng) if processing the LAST record of
!  the file for the LOWER time snapshot. We need to get the UPPER time
!  snapshot from NEXT multifile.
!
            IF ((trec.eq.nrec).and.(tval*day2sec.le.time(ng))) THEN
              linfo(6,ifield,ng)=.true.
            END IF
          END IF
!
!  Read in 2D-grided or point data. Notice for special 2D fields, Vtype
!  is augmented by four indicating reading a 3D field (tidal data with
!  tidal constituents in the third dimension. Currently, all input tidal
!  constituents data is at RHO-points.
!
          IF (special) vtype=vtype+4
!
          IF (vpiovar%vd%varID.ge.0) THEN
            SELECT CASE (vtype)
              CASE (p2dvar)
                IF (kind(fout).eq.8) THEN
                  iodesc => iodesc_dp_p2dvar(ng)
                ELSE
                  iodesc => iodesc_sp_p2dvar(ng)
                END IF
              CASE (r2dvar)
                IF (kind(fout).eq.8) THEN
                  iodesc => iodesc_dp_r2dvar(ng)
                ELSE
                  iodesc => iodesc_sp_r2dvar(ng)
                END IF
              CASE (u2dvar)
                IF (kind(fout).eq.8) THEN
                  iodesc => iodesc_dp_u2dvar(ng)
                ELSE
                  iodesc => iodesc_sp_u2dvar(ng)
                END IF
              CASE (v2dvar)
                IF (kind(fout).eq.8) THEN
                  iodesc => iodesc_dp_v2dvar(ng)
                ELSE
                  iodesc => iodesc_sp_v2dvar(ng)
                END IF
# if defined SSH_TIDES || defined UV_TIDES
              CASE (r2dvar+4)
                IF (kind(fout).eq.8) THEN
                  iodesc => iodesc_dp_rtides(ng)
                ELSE
                  iodesc => iodesc_sp_rtides(ng)
                END IF
                vpiovar%gtype=r2dvar+4
# endif
            END SELECT
!
            IF (lgridded) THEN
              IF (special) THEN
                vsize(3)=irec
                status=nf_fread3d(ng, model, ncfile, piofile,           &
     &                            vname(1,ifield), vpiovar,             &
     &                            0, iodesc, vsize,                     &
     &                            lbi, ubi, lbj, ubj, 1, irec,          &
     &                            fscale(ifield,ng), fmin, fmax,        &
# ifdef MASKING
     &                            fmask,                                &
# endif
# ifdef CHECKSUM
     &                            fout,                                 &
     &                            checksum = fhash)
# else
     &                            fout)
# endif
              ELSE
                status=nf_fread2d(ng, model, ncfile, piofile,           &
     &                            vname(1,ifield), vpiovar,             &
     &                            trec, iodesc, vsize,                  &
     &                            lbi, ubi, lbj, ubj,                   &
     &                            fscale(ifield,ng), fmin, fmax,        &
# ifdef MASKING
     &                            fmask,                                &
# endif
     &                            fout(:,:,tindex),                     &
# ifdef CHECKSUM
     &                            checksum = fhash,                     &
# endif
     &                            lregrid = lregrid)
 
              END IF
            ELSE
              CALL pio_netcdf_get_fvar (ng, model, ncfile,              &
     &                                  vname(1,ifield), fval,          &
     &                                  piofile = piofile,              &
     &                                  start = (/trec/),               &
     &                                  total = (/1/))
              fval=fval*fscale(ifield,ng)
              fpoint(tindex,ifield,ng)=fval
              fmin=fval
              fmax=fval
            END IF
            IF (founderror(exit_flag, noerror, __line__, myfile)) THEN
              IF (master) WRITE (stdout,40) trim(vname(1,ifield)), trec
              RETURN
            END IF
            finfo(8,ifield,ng)=fmin
            finfo(9,ifield,ng)=fmax
            IF (master) THEN
              IF (special) THEN
                WRITE (stdout,50) trim(vname(2,ifield)), ng, fmin, fmax
              ELSE
                lstr=scan(ncfile,'/',back=.true.)+1
                lend=len_trim(ncfile)
                lvar=min(46,len_trim(vname(2,ifield)))
                tsec=tval*day2sec
                CALL time_string (tsec, t_code)
                IF (lregrid) THEN
                  rswitch='T'
                ELSE
                  rswitch='F'
                END IF
                WRITE (stdout,60) vname(2,ifield)(1:lvar), t_code,      &
     &                            ng, trec, tindex, ncfile(lstr:lend),  &
     &                            tmin, tmax, tval, fmin, fmax, rswitch
              END IF
# ifdef CHECKSUM
              WRITE (stdout,70) fhash
# endif
            END IF
            update=.true.
          END IF
        END IF
!
!  Increment the local time variable "Tmono" by the interval between
!  snapshots. If the interval is negative, indicating cycling, add in
!  a cycle length.  Load time value (sec) into "Tintrp" which used
!  during interpolation between snapshots.
!
        IF (.not.lonerec.and.(.not.special)) THEN
          tdelta=vtime(tindex,ifield,ng)-vtime(3-tindex,ifield,ng)
          IF (liocycle.and.(tdelta.lt.0.0_r8)) THEN
            tdelta=tdelta+clength
          END IF
          tmono=tmono+tdelta*day2sec
          finfo(7,ifield,ng)=tmono
          tintrp(tindex,ifield,ng)=tmono
        END IF
      END IF
!
  10  FORMAT (/,' GET_2DFLD_PIO - unable to find dimension ',a,         &
     &        /,17x,'for variable: ',a,/,17x,'in file: ',a,             &
     &        /,17x,'file is not CF compliant...')
  20  FORMAT (/,' GET_2DFLD_PIO - unable to find requested variable:',  &
     &        1x,a,/,17x,'in ',a)
  30  FORMAT (/,' GET_2DFLD_PIO - unable to open input NetCDF',         &
     &        ' file: ',a)
  40  FORMAT (/,' GET_2DFLD_PIO - error while reading variable: ',a,    &
     &        2x,' at TIME index = ',i0)
  50  FORMAT (2x,'GET_2DFLD_PIO    - ',a,/,22x,'(Grid = ',i2.2,         &
     &        ', Min = ',1p,e15.8,0p,' Max = ',1p,e15.8,0p,')')
  60  FORMAT (2x,'GET_2DFLD_PIO    - ',a,',',t75,a,/,22x,               &
     &        '(Grid=',i2.2,', Rec=',i0,', Index=',i1,                  &
     &          ', File: ',a,')',/,22x,                                 &
     &        '(Tmin= ', f15.4, ' Tmax= ', f15.4,')',                   &
     &        t71, 't = ', f15.4 ,/,22x,                                &
     &        '(Min = ', 1p,e15.8,0p,' Max = ',1p,e15.8,0p,')',         &
     &        t71, 'regrid = ',a)
# ifdef CHECKSUM
  70  FORMAT (22x,'(CheckSum = ',i0,')')
# endif
!
      RETURN

References mod_ncparam::cinfo, mod_scalars::day2sec, mod_ncparam::dinfo, mod_scalars::exit_flag, mod_ncparam::finfo, strings_mod::founderror(), mod_ncparam::fpoint, mod_ncparam::fscale, mod_scalars::iic, mod_ncparam::iinfo, mod_pio_netcdf::iodesc_dp_p2dvar, mod_pio_netcdf::iodesc_dp_r2dvar, mod_pio_netcdf::iodesc_dp_rtides, mod_pio_netcdf::iodesc_dp_u2dvar, mod_pio_netcdf::iodesc_dp_v2dvar, mod_pio_netcdf::iodesc_sp_p2dvar, mod_pio_netcdf::iodesc_sp_r2dvar, mod_pio_netcdf::iodesc_sp_rtides, mod_pio_netcdf::iodesc_sp_u2dvar, mod_pio_netcdf::iodesc_sp_v2dvar, mod_ncparam::linfo, mod_parallel::master, mod_iounits::ncfile, mod_scalars::noerror, mod_scalars::ntstart, mod_param::p2dvar, mod_param::r2dvar, mod_scalars::rclock, mod_iounits::sourcefile, mod_iounits::stdout, mod_scalars::time, dateclock_mod::time_string(), mod_ncparam::tintrp, mod_ncparam::tname, mod_param::u2dvar, mod_param::v2dvar, mod_ncparam::vname, and mod_ncparam::vtime.

Referenced by get_2dfld().

Here is the call graph for this function:

Here is the caller graph for this function: