get_idata.F

Go to the documentation of this file.

#include "cppdefs.h"
      SUBROUTINE get_idata (ng)
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine reads input data that needs to be obtained only once.  !
!                                                                      !
!  Currently,  this routine is only executed in serial mode by the     !
!  main thread.                                                        !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
#ifdef RED_TIDE
      USE mod_biology
#endif
      USE mod_grid
      USE mod_iounits
      USE mod_ncparam
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
      USE mod_netcdf
# if defined PIO_LIB && defined DISTRIBUTE
      USE mod_pio_netcdf
# endif
#endif
#ifdef RED_TIDE
      USE mod_ocean
#endif
      USE mod_scalars
      USE mod_sources
      USE mod_stepping
#if defined SSH_TIDES || defined UV_TIDES
      USE mod_tides
#endif
!
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
      USE def_tides_mod,  ONLY : def_tides
#endif
      USE nf_fread3d_mod, ONLY : nf_fread3d
#ifdef SOLVE3D
      USE nf_fread4d_mod, ONLY : nf_fread4d
#endif
      USE strings_mod,    ONLY : founderror
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng
!
!  Local variable declarations.
!
      logical, save :: recordless = .true.
 
      logical, dimension(3) :: update =                                 &
     &         (/ .FALSE., .FALSE., .FALSE. /)
!
      integer :: LBi, UBi, LBj, UBj
      integer :: itrc, is
 
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
      integer :: gtype, status, varid, Vsize(4)
!
      real(r8), parameter :: Fscl = 1.0_r8
 
      real(r8) :: Fmin, Fmax, Htime
#endif
      real(r8) :: time_save = 0.0_r8
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
 
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
# if defined PIO_LIB && defined DISTRIBUTE
!
      TYPE (IO_Desc_t),  pointer :: ioDesc
      TYPE (My_VarDesc), pointer :: pioVar
# endif
#endif
!
      sourcefile=myfile
!
!  Lower and upper bounds for tiled arrays.
!
      lbi=lbound(grid(ng)%h,dim=1)
      ubi=ubound(grid(ng)%h,dim=1)
      lbj=lbound(grid(ng)%h,dim=2)
      ubj=ubound(grid(ng)%h,dim=2)
 
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
!
!  Set Vsize to zero to deactivate interpolation of input data to model
!  grid in "nf_fread2d" and "nf_fread3d".
!
      DO is=1,4
        vsize(is)=0
      END DO
#endif
 
#ifdef PROFILE
!
!-----------------------------------------------------------------------
!  Turn on input data time wall clock.
!-----------------------------------------------------------------------
!
      CALL wclock_on (ng, inlm, 3, __line__, myfile)
#endif
 
#if defined SSH_TIDES || defined UV_TIDES
!
!-----------------------------------------------------------------------
!  Tide period, amplitude, phase, and currents.
!-----------------------------------------------------------------------
!
!  Tidal Period.
!
      IF (lprocesstides(ng)) THEN
        IF (iic(ng).eq.0) THEN
          CALL get_ngfld (ng, inlm, idtper, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), recordless, update(1),           &
     &                    1, mtc, 1, 1, 1, ntc(ng), 1,                  &
     &                    tides(ng) % Tperiod)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
      END IF
#endif
 
#ifdef SSH_TIDES
!
!  Tidal elevation amplitude and phase. In order to read data as a
!  function of tidal period, we need to reset the model time variables
!  temporarily.
!
      IF (lprocesstides(ng)) THEN
        IF (iic(ng).eq.0) THEN
          time_save=time(ng)
          time(ng)=8640000.0_r8
          tdays(ng)=time(ng)*sec2day
!
          CALL get_2dfld (ng, inlm, idtzam, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), update(1),                       &
     &                    lbi, ubi, lbj, ubj, mtc, ntc(ng),             &
# ifdef MASKING
     &                    grid(ng) % rmask,                             &
# endif
     &                    tides(ng) % SSH_Tamp)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          CALL get_2dfld (ng, inlm, idtzph, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), update(1),                       &
     &                    lbi, ubi, lbj, ubj, mtc, ntc(ng),             &
# ifdef MASKING
     &                    grid(ng) % rmask,                             &
# endif
     &                    tides(ng) % SSH_Tphase)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          time(ng)=time_save
          tdays(ng)=time(ng)*sec2day
        END IF
      END IF
#endif
 
#ifdef UV_TIDES
!
!  Tidal currents angle, phase, major and minor ellipse axis.
!
      IF (lprocesstides(ng)) THEN
        IF (iic(ng).eq.0) THEN
          time_save=time(ng)
          time(ng)=8640000.0_r8
          tdays(ng)=time(ng)*sec2day
!
          CALL get_2dfld (ng, inlm, idtvan, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), update(1),                       &
     &                    lbi, ubi, lbj, ubj, mtc, ntc(ng),             &
# ifdef MASKING
     &                    grid(ng) % rmask,                             &
# endif
     &                    tides(ng) % UV_Tangle)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          CALL get_2dfld (ng, inlm, idtvph, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), update(1),                       &
     &                    lbi, ubi, lbj, ubj, mtc, ntc(ng),             &
# ifdef MASKING
     &                    grid(ng) % rmask,                             &
# endif
     &                    tides(ng) % UV_Tphase)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          CALL get_2dfld (ng, inlm, idtvma, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), update(1),                       &
     &                    lbi, ubi, lbj, ubj, mtc, ntc(ng),             &
# ifdef MASKING
     &                    grid(ng) % rmask,                             &
# endif
     &                    tides(ng) % UV_Tmajor)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          CALL get_2dfld (ng, inlm, idtvmi, tide(ng)%ncid,              &
# if defined PIO_LIB && defined DISTRIBUTE
     &                    tide(ng)%pioFile,                             &
# endif
     &                    1, tide(ng), update(1),                       &
     &                    lbi, ubi, lbj, ubj, mtc, ntc(ng),             &
# ifdef MASKING
     &                    grid(ng) % rmask,                             &
# endif
     &                    tides(ng) % UV_Tminor)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          time(ng)=time_save
          tdays(ng)=time(ng)*sec2day
        END IF
      END IF
#endif
 
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
!
!-----------------------------------------------------------------------
!  If detiding and applicable, define additional variable to store
!  time-accumulated tide harmonics variables.  This variable are
!  defined and written into input tide forcing NetCDF file.
!-----------------------------------------------------------------------
!
      CALL def_tides (ng, ldeftide(ng))
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!-----------------------------------------------------------------------
!  If restarting, read in time-accumulated tide harmonics variables.
!-----------------------------------------------------------------------
!
      IF (.not.ldeftide(ng).and.(nrrec(ng).ne.0)) THEN
!
!  For consistency, check time of written accumulate harmonics and
!  compare to current time.
!
        SELECT CASE (har(ng)%IOtype)
          CASE (io_nf90)
            CALL netcdf_get_time (ng, inlm, har(ng)%name,               &
     &                            vname(1,idtime),                      &
     &                            rclock%DateNumber, htime,             &
     &                            ncid = har(ng)%ncid)
 
# if defined PIO_LIB && defined DISTRIBUTE
          CASE (io_pio)
            CALL pio_netcdf_get_time (ng, inlm, har(ng)%name,           &
     &                                vname(1,idtime),                  &
     &                                rclock%DateNumber, htime,         &
     &                                piofile = har(ng)%pioFile)
# endif
        END SELECT
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
        IF (time(ng).ne.htime) THEN
          IF (master) THEN
            WRITE (stdout,20) tdays(ng), htime*sec2day
          END IF
          exit_flag=2
          ioerror=0
          RETURN
        END IF
!
!  Number of time-acummulate tide harmonics.
!
        SELECT CASE (har(ng)%IOtype)
          CASE (io_nf90)
            CALL netcdf_get_ivar (ng, inlm, har(ng)%name,               &
     &                            'Hcount', hcount(ng),                 &
     &                            ncid = har(ng)%ncid)
 
# if defined PIO_LIB && defined DISTRIBUT
          CASE (io_pio)
            CALL pio_netcdf_get_ivar (ng, inlm, har(ng)%name,           &
     &                                'Hcount', hcount(ng),             &
     &                                piofile = har(ng)%pioFile)
# endif
        END SELECT
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Time-accumulated COS(omega(k)*t) harmonics.
!
        CALL get_ngfld (ng, inlm, idcosw, har(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  har(ng)%pioFile,                                &
# endif
     &                  1, har(ng), recordless, update(1),              &
     &                  1, mtc, 1, 1, 1, ntc(ng), 1,                    &
     &                  tides(ng) % CosW_sum)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Time-accumulated SIN(omega(k)*t) harmonics.
!
        CALL get_ngfld (ng, inlm, idsinw, har(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  har(ng)%pioFile,                                &
# endif
     &                  1, har(ng), recordless, update(1),              &
     &                  1, mtc, 1, 1, 1, ntc(ng), 1,                    &
     &                  tides(ng) % SinW_sum)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Time-accumulated COS(omega(k)*t)*COS(omega(k)*t) harmonics.
!
        CALL get_ngfld (ng, inlm, idcos2, har(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  har(ng)%pioFile,                                &
# endif
     &                  1, har(ng), recordless, update(1),              &
     &                  1, mtc, mtc, 1, 1, ntc(ng), ntc(ng),            &
     &                  tides(ng) % CosWCosW)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Time-accumulated SIN(omega(k)*t)*SIN(omega(k)*t) harmonics.
!
        CALL get_ngfld (ng, inlm, idsin2, har(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  har(ng)%pioFile,                                &
# endif
     &                  1, har(ng), recordless, update(1),              &
     &                  1, mtc, mtc, 1, 1, ntc(ng), ntc(ng),            &
     &                  tides(ng) %  SinWSinW)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Time-accumulated SIN(omega(k)*t)*COS(omega(k)*t) harmonics.
!
        CALL get_ngfld (ng, inlm, idswcw, har(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  har(ng)%pioFile,                                &
# endif
     &                  1, har(ng), recordless, update(1),              &
     &                  1, mtc, mtc, 1, 1, ntc(ng), ntc(ng),            &
     &                  tides(ng) %  SinWCosW)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Time-accumulated free-surface tide harmonics.
!
        IF (aout(idfsud,ng)) THEN
          SELECT CASE (har(ng)%IOtype)
            CASE (io_nf90)
              gtype=r3dvar
              status=nf_fread3d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%ncid,                           &
     &                          vname(1,idfsuh),                        &
     &                          har(ng)%Vid(idfsuh),                    &
     &                          0, gtype, vsize,                        &
     &                          lbi, ubi, lbj, ubj, 0, 2*ntc(ng),       &
     &                          fscl, fmin, fmax,                       &
# ifdef MASKING
     &                          grid(ng) % rmask,                       &
# endif
     &                          tides(ng) % zeta_tide)
 
# if defined PIO_LIB && defined DISTRIBUTE
            CASE (io_pio)
 
              piovar%vd => har(ng)%pioVar(idfsuh)%vd
              IF (kind(tides(ng)%zeta_tide).eq.8) THEN
                piovar%dkind=pio_double
                iodesc => iodesc_dp_r2dhar(ng)
              ELSE
                piovar%dkind=pio_real
                iodesc => iodesc_sp_r2dhar(ng)
              END IF
              piovar%gtype=r2dvar
!
              status=nf_fread3d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%pioFile,                        &
     &                          vname(1,idfsuh),                        &
     &                          piovar,                                 &
     &                          0, iodesc, vsize,                       &
     &                          lbi, ubi, lbj, ubj, 0, 2*ntc(ng),       &
     &                          fscl, fmin, fmax,                       &
#  ifdef MASKING
     &                          grid(ng) % rmask,                       &
#  endif
     &                          tides(ng) % zeta_tide)
 
# endif
          END SELECT
          IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
            IF (master) THEN
              WRITE (stdout,10) trim(vname(1,idfsuh)),                  &
     &                          trim(har(ng)%name)
            END IF
            exit_flag=2
            ioerror=status
            RETURN
          ELSE
            IF (master) THEN
              WRITE (stdout,30) trim(vname(2,idfsuh)), fmin, fmax
            END IF
          END IF
        END IF
!
!  Time-accumulated 2D u-momentum tide harmonics.
!
        IF (aout(idu2dd,ng)) THEN
          SELECT CASE (har(ng)%IOtype)
            CASE (io_nf90)
              gtype=u3dvar
              status=nf_fread3d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%ncid,                           &
     &                          vname(1,idu2dh),                        &
     &                          har(ng)%Vid(idu2dh),                    &
     &                          0, gtype, vsize,                        &
     &                          lbi, ubi, lbj, ubj, 0, 2*ntc(ng),       &
     &                          fscl, fmin, fmax,                       &
# ifdef MASKING
     &                          grid(ng) % umask,                       &
# endif
     &                          tides(ng) % ubar_tide)
 
# if defined PIO_LIB && defined DISTRIBUTE
            CASE (io_pio)
 
              piovar%vd => har(ng)%pioVar(idu2dh)%vd
              IF (kind(tides(ng)%ubar_tide).eq.8) THEN
                piovar%dkind=pio_double
                iodesc => iodesc_dp_u2dhar(ng)
              ELSE
                piovar%dkind=pio_real
                iodesc => iodesc_sp_u2dhar(ng)
              END IF
              piovar%gtype=u2dvar
!
              status=nf_fread3d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%pioFile,                        &
     &                          vname(1,idu2dh),                        &
     &                          piovar,                                 &
     &                          0, iodesc, vsize,                       &
     &                          lbi, ubi, lbj, ubj, 0, 2*ntc(ng),       &
     &                          fscl, fmin, fmax,                       &
#  ifdef MASKING
     &                          grid(ng) % umask,                       &
#  endif
     &                          tides(ng) % ubar_tide)
# endif
          END SELECT
          IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
            IF (master) THEN
              WRITE (stdout,10) trim(vname(1,idu2dh)),                  &
     &                          trim(har(ng)%name)
            END IF
            exit_flag=2
            ioerror=status
            RETURN
          ELSE
            IF (master) THEN
              WRITE (stdout,30) trim(vname(2,idu2dh)), fmin, fmax
            END IF
          END IF
        END IF
!
!  Time-accumulated 2D v-momentum tide harmonics.
!
        IF (aout(idv2dd,ng)) THEN
          SELECT CASE (har(ng)%IOtype)
            CASE (io_nf90)
              gtype=v3dvar
              status=nf_fread3d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%ncid,                           &
     &                          vname(1,idv2dh),                        &
     &                          har(ng)%Vid(idv2dh),                    &
     &                          0, gtype, vsize,                        &
     &                          lbi, ubi, lbj, ubj, 0, 2*ntc(ng),       &
     &                          fscl, fmin, fmax,                       &
# ifdef MASKING
     &                          grid(ng) % vmask,                       &
# endif
     &                          tides(ng) % vbar_tide)
 
# if defined PIO_LIB && defined DISTRIBUTE
            CASE (io_pio)
 
              piovar%vd => har(ng)%pioVar(idv2dh)%vd
              IF (kind(tides(ng)%vbar_tide).eq.8) THEN
                piovar%dkind=pio_double
                iodesc => iodesc_dp_v2dhar(ng)
              ELSE
                piovar%dkind=pio_real
                iodesc => iodesc_sp_v2dhar(ng)
              END IF
              piovar%gtype=v2dvar
!
              status=nf_fread3d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%pioFile,                        &
     &                          vname(1,idv2dh),                        &
     &                          piovar,                                 &
     &                          0, iodesc, vsize,                       &
     &                          lbi, ubi, lbj, ubj, 0, 2*ntc(ng),       &
     &                          fscl, fmin, fmax,                       &
#  ifdef MASKING
     &                          grid(ng) % vmask,                       &
#  endif
     &                          tides(ng) % vbar_tide)
# endif
          END SELECT
          IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
            IF (master) THEN
              WRITE (stdout,10) trim(vname(1,idv2dh)),                  &
     &                          trim(har(ng)%name)
            END IF
            exit_flag=2
            ioerror=status
            RETURN
          ELSE
            IF (master) THEN
              WRITE (stdout,30) trim(vname(2,idv2dh)), fmin, fmax
            END IF
          END IF
        END IF
 
# ifdef SOLVE3D
!
!  Time-accumulated 3D u-momentum tide harmonics.
!
        IF (aout(idu3dd,ng)) THEN
          SELECT CASE (har(ng)%IOtype)
            CASE (io_nf90)
              gtype=u3dvar
              status=nf_fread4d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%ncid,                           &
     &                          vname(1,idu3dh),                        &
     &                          har(ng)%Vid(idu3dh),                    &
     &                          0, gtype, vsize,                        &
     &                          lbi, ubi, lbj, ubj, 1, n(ng),           &
     &                          0, 2*ntc(ng),                           &
     &                          fscl, fmin, fmax,                       &
#  ifdef MASKING
     &                          grid(ng) % umask,                       &
#  endif
     &                          tides(ng) % u_tide)
 
#  if defined PIO_LIB && defined DISTRIBUTE
            CASE (io_pio)
 
              piovar%vd => har(ng)%pioVar(idu3dh)%vd
              IF (kind(tides(ng)%u_tide).eq.8) THEN
                piovar%dkind=pio_double
                iodesc => iodesc_dp_u3dhar(ng)
              ELSE
                piovar%dkind=pio_real
                iodesc => iodesc_sp_u3dhar(ng)
              END IF
              piovar%gtype=u3dvar
!
              status=nf_fread4d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%pioFile,                        &
     &                          vname(1,idu3dh),                        &
     &                          piovar,                                 &
     &                          0, iodesc, vsize,                       &
     &                          lbi, ubi, lbj, ubj, 1, n(ng),           &
     &                          0, 2*ntc(ng),                           &
     &                          fscl, fmin, fmax,                       &
#   ifdef MASKING
     &                          grid(ng) % umask,                       &
#   endif
     &                          tides(ng) % u_tide)
#  endif
          END SELECT
          IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
            IF (master) THEN
              WRITE (stdout,10) trim(vname(1,idu3dh)),                  &
     &                          trim(har(ng)%name)
            END IF
            exit_flag=2
            ioerror=status
            RETURN
          ELSE
            IF (master) THEN
              WRITE (stdout,30) trim(vname(2,idu3dh)), fmin, fmax
            END IF
          END IF
        END IF
!
!  Time-accumulated 3D v-momentum tide harmonics.
!
        IF (aout(idv3dd,ng)) THEN
          SELECT CASE (har(ng)%IOtype)
            CASE (io_nf90)
              gtype=v3dvar
              status=nf_fread4d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%ncid,                           &
     &                          vname(1,idv3dh),                        &
     &                          har(ng)%Vid(idv3dh),                    &
     &                          0, gtype, vsize,                        &
     &                          lbi, ubi, lbj, ubj, 1, n(ng),           &
     &                          0, 2*ntc(ng),                           &
     &                          fscl, fmin, fmax,                       &
#  ifdef MASKING
     &                          grid(ng) % vmask,                       &
#  endif
     &                          tides(ng) % v_tide)
 
#  if defined PIO_LIB && defined DISTRIBUTE
            CASE (io_pio)
 
              piovar%vd => har(ng)%pioVar(idv3dh)%vd
              IF (kind(tides(ng)%v_tide).eq.8) THEN
                piovar%dkind=pio_double
                iodesc => iodesc_dp_v3dhar(ng)
              ELSE
                piovar%dkind=pio_real
                iodesc => iodesc_sp_v3dhar(ng)
              END IF
              piovar%gtype=v3dvar
!
              status=nf_fread4d(ng, inlm, har(ng)%name,                 &
     &                          har(ng)%pioFile,                        &
     &                          vname(1,idv3dh),                        &
     &                          piovar,                                 &
     &                          0, iodesc, vsize,                       &
     &                          lbi, ubi, lbj, ubj, 1, n(ng),           &
     &                          0, 2*ntc(ng),                           &
     &                          fscl, fmin, fmax,                       &
#  ifdef MASKING
     &                          grid(ng) % vmask,                       &
#  endif
     &                          tides(ng) % v_tide)
#  endif
          END SELECT
          IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
            IF (master) THEN
              WRITE (stdout,10) trim(vname(1,idv3dh)),                  &
     &                          trim(har(ng)%name)
            END IF
            exit_flag=2
            ioerror=status
            RETURN
          ELSE
            IF (master) THEN
              WRITE (stdout,30) trim(vname(2,idv3dh)), fmin, fmax
            END IF
          END IF
        END IF
!
!  Time-accumulated temperature and salinity tide harmonics.
!
        DO itrc=1,nat
          IF (aout(idtrcd(itrc),ng)) THEN
            SELECT CASE (har(ng)%IOtype)
              CASE (io_nf90)
                gtype=r3dvar
                status=nf_fread4d(ng, inlm, har(ng)%name,               &
     &                            har(ng)%ncid,                         &
     &                            vname(1,idtrch(itrc)),                &
     &                            har(ng)%Vid(idtrch(itrc)),            &
     &                            0, gtype, vsize,                      &
     &                            lbi, ubi, lbj, ubj, 1, n(ng),         &
     &                            0, 2*ntc(ng),                         &
     &                            fscl, fmin, fmax,                     &
#  ifdef MASKING
     &                            grid(ng) % rmask,                     &
#  endif
     &                            tides(ng) % t_tide(:,:,:,:,itrc))
 
#  if defined PIO_LIB && defined DISTRIBUTE
              CASE (io_pio)
 
                piovar%vd => har(ng)%pioVar(idtrch(itrc))%vd
                IF (kind(tides(ng)%t_tide).eq.8) THEN
                  piovar%dkind=pio_double
                  iodesc => iodesc_dp_r3dhar(ng)
                ELSE
                  piovar%dkind=pio_real
                  iodesc => iodesc_sp_r3dhar(ng)
                END IF
                piovar%gtype=r3dvar
!
                status=nf_fread4d(ng, inlm, har(ng)%name,               &
     &                            har(ng)%pioFile,                      &
     &                            vname(1,idtrch(itrc)),                &
     &                            piovar,                               &
     &                            0, iodesc, vsize,                     &
     &                            lbi, ubi, lbj, ubj, 1, n(ng),         &
     &                            0, 2*ntc(ng),                         &
     &                            fscl, fmin, fmax,                     &
#  ifdef MASKING
     &                            grid(ng) % rmask,                     &
#  endif
     &                            tides(ng) % t_tide(:,:,:,:,itrc))
#  endif
            END SELECT
            IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
              IF (master) THEN
                WRITE (stdout,10) trim(vname(1,idtrch(itrc))),          &
     &                            trim(har(ng)%name)
              END IF
              exit_flag=2
              ioerror=status
              RETURN
            ELSE
              IF (master) THEN
                WRITE (stdout,30) trim(vname(2,idtrch(itrc))),          &
     &                            fmin, fmax
              END IF
            END IF
          END IF
        END DO
# endif
      END IF
#endif
 
#ifndef ANA_PSOURCE
!
!-----------------------------------------------------------------------
!  Read in point Sources/Sinks position, direction, special flag, and
!  mass transport nondimensional shape profile.  Point sources are at
!  U- and V-points.
!-----------------------------------------------------------------------
!
      IF ((iic(ng).eq.0).and.                                           &
     &    (luvsrc(ng).or.lwsrc(ng).or.any(ltracersrc(:,ng)))) THEN
        CALL get_ngfld (ng, inlm, idrxpo, ssf(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  ssf(ng)%pioFile,                                &
# endif
     &                  1, ssf(ng), recordless, update(1),              &
     &                  1, nsrc(ng), 1, 1, 1, nsrc(ng), 1,              &
     &                  sources(ng) % Xsrc)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
        CALL get_ngfld (ng, inlm, idrepo, ssf(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  ssf(ng)%pioFile,                                &
# endif
     &                  1, ssf(ng), recordless, update(1),              &
     &                  1, nsrc(ng), 1, 1, 1, nsrc(ng), 1,              &
     &                  sources(ng) % Ysrc)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
        CALL get_ngfld (ng, inlm, idrdir, ssf(ng)%ncid,                 &
# if defined PIO_LIB && defined DISTRIBUTE
     &                  ssf(ng)%pioFile,                                &
# endif
     &                  1, ssf(ng), recordless, update(1),              &
     &                  1, nsrc(ng), 1, 1, 1, nsrc(ng), 1,              &
     &                  sources(ng) % Dsrc)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
# ifdef SOLVE3D
        CALL get_ngfld (ng, inlm, idrvsh, ssf(ng)%ncid,                 &
#  if defined PIO_LIB && defined DISTRIBUTE
     &                  ssf(ng)%pioFile,                                &
#  endif
     &                  1, ssf(ng), recordless, update(1),              &
     &                  1, nsrc(ng), n(ng), 1, 1, nsrc(ng), n(ng),      &
     &                  sources(ng) % Qshape)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
# endif
 
        DO is=1,nsrc(ng)
          sources(ng)%Isrc(is)=                                         &
     &                max(1,min(nint(sources(ng)%Xsrc(is)),lm(ng)+1))
          sources(ng)%Jsrc(is)=                                         &
     &                max(1,min(nint(sources(ng)%Ysrc(is)),mm(ng)+1))
        END DO
      END IF
#endif
 
#ifdef RED_TIDE
!
!-----------------------------------------------------------------------
!  Red tides.
!-----------------------------------------------------------------------
!
!  Read initial dynoflagellate bottom cyst concentration.
!
      CALL get_2dfld (ng, inlm, idcyst, frcncid(idcyst,ng),             &
# if defined PIO_LIB && defined DISTRIBUTE
     &                frcpiofile(idcyst,ng),                            &
# endif
     &                nffiles(ng), frc(1,ng), update(1),                &
     &                lbi, ubi, lbj, ubj, 1, 1,                         &
# ifdef MASKING
     &                grid(ng) % rmask,                                 &
# endif
     &                ocean(ng) % CystIni)
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      IF (.not.linfo(1,idcyst,ng)) THEN             ! if not gridded,
        ocean(ng) % CystIni = fpoint(1,idcyst,ng)   ! load point data
      END IF
#endif
 
#ifdef PROFILE
!
!-----------------------------------------------------------------------
!  Turn off input data time wall clock.
!-----------------------------------------------------------------------
!
      CALL wclock_off (ng, inlm, 3, __line__, myfile)
#endif
 
#if defined AVERAGES  && defined AVERAGES_DETIDE && \
   (defined ssh_tides || defined uv_tides)
!
  10  FORMAT (/,' GET_IDATA - error while reading variable: ',a,        &
     &        /,13x,'in input NetCDF file: ',a)
  20  FORMAT (/,' GET_IDATA - incosistent restart and harmonics time:', &
     &        /,13x,f15.4,2x,f15.4)
  30  FORMAT (16x,'- ',a,/,19x,'(Min = ',1p,e15.8,                      &
     &        ' Max = ',1p,e15.8,')')
#endif
!
      RETURN
      END SUBROUTINE get_idata