tl_lmd_swfrac.F File Reference

#include "cppdefs.h"
#include "set_bounds.h"

Include dependency graph for tl_lmd_swfrac.F:

Go to the source code of this file.

Functions/Subroutines
subroutine	tl_lmd_swfrac_tile (ng, tile, lbi, ubi, lbj, ubj, imins, imaxs, jmins, jmaxs, zscale, z, tl_z, tl_swdk)

Function/Subroutine Documentation

tl_lmd_swfrac_tile()

subroutine tl_lmd_swfrac_tile	(	integer, intent(in)	ng,
		integer, intent(in)	tile,
		integer, intent(in)	lbi,
		integer, intent(in)	ubi,
		integer, intent(in)	lbj,
		integer, intent(in)	ubj,
		integer, intent(in)	imins,
		integer, intent(in)	imaxs,
		integer, intent(in)	jmins,
		integer, intent(in)	jmaxs,
		real(r8), intent(in)	zscale,
		real(r8), dimension(imins:imaxs,jmins:jmaxs), intent(in)	z,
		real(r8), dimension(imins:imaxs,jmins:jmaxs), intent(in)	tl_z,
		real(r8), dimension(imins:imaxs,jmins:jmaxs), intent(out)	tl_swdk )

Definition at line 6 of file tl_lmd_swfrac.F.

!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine computes the  tangent linear  fraction of solar        !
!  shortwave flux penetrating to specified depth (times Zscale)        !
!  due to exponential decay in Jerlov water type.                      !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     Zscale   Scale factor to apply to depth array.                   !
!     Z        Vertical height (meters, negative) for                  !
!                desired solar short-wave fraction.                    !
!     tl_Z     Tangent linear vertical height for                      !
!                desired solar short-wave fraction.                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     tl_swdk  Tangent linear shortwave (radiation) fractional decay.  !
!                                                                      !
!  Reference:                                                          !
!                                                                      !
!  Paulson, C.A., and J.J. Simpson, 1977: Irradiance meassurements     !
!     in the upper ocean, J. Phys. Oceanogr., 7, 952-956.              !
!                                                                      !
!  This routine was adapted from Bill Large 1995 code.                 !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_mixing
      USE mod_scalars
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
 
      real(r8), intent(in) :: Zscale
 
      real(r8), intent(in) :: Z(IminS:ImaxS,JminS:JmaxS)
      real(r8), intent(in) :: tl_Z(IminS:ImaxS,JminS:JmaxS)
 
      real(r8), intent(out) :: tl_swdk(IminS:ImaxS,JminS:JmaxS)
!
!  Local variable declarations.
!
      integer :: Jindex, i, j
 
      real(r8) :: cff1, cff2
      real(r8) :: tl_cff1, tl_cff2
 
      real(r8), dimension(IminS:ImaxS) :: fac1, fac2, fac3
 
# include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Use Paulson and Simpson (1977) two wavelength bands solar
!  absorption model.
!-----------------------------------------------------------------------
!
      DO j=jstr,jend
        DO i=istr,iend
          jindex=int(mixing(ng)%Jwtype(i,j))
          fac1(i)=zscale/lmd_mu1(jindex)
          fac2(i)=zscale/lmd_mu2(jindex)
          fac3(i)=lmd_r1(jindex)
        END DO
!!DIR$ VECTOR ALWAYS
        DO i=istr,iend
          cff1=exp(z(i,j)*fac1(i))
          tl_cff1=fac1(i)*tl_z(i,j)*cff1
          cff2=exp(z(i,j)*fac2(i))
          tl_cff2=fac2(i)*tl_z(i,j)*cff2
!^        swdk(i,j)=cff1*fac3(i)+                                       &
!^   &              cff2*(1.0_r8-fac3(i))
!^
          tl_swdk(i,j)=tl_cff1*fac3(i)+                                 &
     &                 tl_cff2*(1.0_r8-fac3(i))
        END DO
      END DO
      RETURN

References mod_scalars::lmd_mu1, mod_scalars::lmd_mu2, mod_scalars::lmd_r1, and mod_mixing::mixing.

Referenced by tl_pre_step3d_mod::tl_pre_step3d_tile().

Here is the caller graph for this function: