obs_read.F

Go to the documentation of this file.

#include "cppdefs.h"
      MODULE obs_read_mod
#if (defined FOUR_DVAR || defined VERIFICATION) && defined OBSERVATIONS
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This module reads in observations data when appropriate from the    !
!  input file using the standard NetCDF library or the Parallel-IO     !
!  (PIO) library.                                                      !
!                                                                      !
!  The observations data is stored for use elsewhere.                  !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_fourdvar
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE dateclock_mod, ONLY : time_string
      USE strings_mod,   ONLY : founderror
!
      implicit none
!
      PUBLIC  :: obs_read
      PRIVATE :: obs_read_nf90
# if defined PIO_LIB && defined DISTRIBUTE
      PRIVATE :: obs_read_pio
# endif
!
      CONTAINS
!
!***********************************************************************
      SUBROUTINE obs_read (ng, model, backward)
!***********************************************************************
!
!  Imported variable declarations.
!
      logical, intent(in) :: backward
!
      integer, intent(in) :: ng, model
!
!  Local variable declarations.
!
      character (len=*), parameter :: myfile =                          &
     &  __FILE__
!
!-----------------------------------------------------------------------
!  Write out time-averaged fields according to IO type.
!-----------------------------------------------------------------------
!
      SELECT CASE (obs(ng)%IOtype)
        CASE (io_nf90)
          CALL obs_read_nf90 (ng, model, backward)
 
# if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL obs_read_pio (ng, model, backward)
# endif
        CASE DEFAULT
          IF (master) WRITE (stdout,10) obs(ng)%IOtype
          exit_flag=2
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END SELECT
!
  10  FORMAT (' OBS_READ - Illegal input file type, io_type = ',i0,     &
     &        /,12x,'Check KeyWord ''INP_LIB'' in ''roms.in''.')
!
      RETURN
      END SUBROUTINE obs_read
!
!***********************************************************************
      SUBROUTINE obs_read_nf90 (ng, model, backward)
!***********************************************************************
!
      USE mod_netcdf
!
!  Imported variable declarations.
!
      logical, intent(in) :: backward
!
      integer, intent(in) :: ng, model
!
!  Local variable declarations.
!
      logical :: readnlmod, readtlmod
!
      integer :: mstr, mend
      integer :: i, iobs, itrc, status
!
      character (len=22) :: t_code
 
      character (len=*), parameter :: myfile =                          &
     &  __FILE__//", obs_read_nf90"
!
      sourcefile=myfile
!
!---------------------------------------------------------------------
!  Read observation variables needed for interpolating the model
!  state at the observation locations.
!---------------------------------------------------------------------
!
      IF (processobs(ng)) THEN
# if defined TLM_OBS
#  if defined I4DVAR_ANA_SENSITIVITY
        readnlmod=.false.
#  else
        readnlmod=.true.
#  endif
        readtlmod=.true.
# else
        readnlmod=.false.
        readtlmod=.false.
# endif
!
!  Initialize observations processing counters.
!
        DO i=1,nobsvar(ng)
          fourdvar(ng)%ObsCount(i)=0
          fourdvar(ng)%ObsReject(i)=0
        END DO
        IF (backward) THEN
          obssurvey(ng)=obssurvey(ng)-1
        ELSE
          obssurvey(ng)=obssurvey(ng)+1
        END IF
!
!  Set number of observations to process.
!
        nobs(ng)=fourdvar(ng)%NobsSurvey(obssurvey(ng))
!
!  Set number of datum to process at current time-step.
!
        IF (backward) THEN
          nendobs(ng)=nstrobs(ng)-1
          nstrobs(ng)=nstrobs(ng)-nobs(ng)
        ELSE
          nstrobs(ng)=nendobs(ng)+1
          nendobs(ng)=nstrobs(ng)+nobs(ng)-1
        END IF
!
!  Set starting index of obervation vectors for reading.  In weak
!  constraint, the entire observation data is loaded. Otherwise,
!  only the observartion for the current time window are loaded
!  and started from vector index one.
!
# ifdef WEAK_CONSTRAINT
        mstr=nstrobs(ng)
        mend=nendobs(ng)
# else
        mstr=1
        mend=nobs(ng)
# endif
!
!  Read in observation type identifier.
!
        CALL netcdf_get_ivar (ng, model, obs(ng)%name, vname(1,idotyp), &
     &                        obstype(mstr:),                           &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation provenance identifier.
!
        CALL netcdf_get_ivar (ng, model, obs(ng)%name, vname(1,idopro), &
     &                        obsprov(mstr:),                           &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation time (days).
!
        CALL netcdf_get_time (ng, model, obs(ng)%name, vname(1,idobst), &
     &                        rclock%DateNumber, tobs(mstr:),           &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation X-location (grid units).
!
        CALL netcdf_get_fvar (ng, model, obs(ng)%name, vname(1,idobsx), &
     &                        xobs(mstr:),                              &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation Y-location (grid units).
!
        CALL netcdf_get_fvar (ng, model, obs(ng)%name, vname(1,idobsy), &
     &                        yobs(mstr:),                              &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
# ifdef SOLVE3D
!
!  Read in observation depth, Zobs.  If negative, depth is meter. If
!  greater than zero, Zobs is in model fractional vertical levels
!  (1 <= Zobs <= N). If Zobs < 0, its fractional level value is
!  computed in routine "extract_obs3d" and over-written so it can
!  be written into the observation NetCDF file for latter use.
!
        IF (wrote_zobs(ng)) THEN
          CALL netcdf_get_fvar (ng, model, obs(ng)%name,                &
     &                          vname(1,idobsz),                        &
     &                          zobs(mstr:),                            &
     &                          ncid = obs(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        ELSE
          CALL netcdf_get_fvar (ng, model, obs(ng)%name,                &
     &                          vname(1,idobsd),                        &
     &                          zobs(mstr:),                            &
     &                          ncid = obs(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
        load_zobs(ng)=.false.
        IF ((minval(zobs).lt.0.0_r8).or.                                &
     &      (maxval(zobs).lt.0.0_r8)) THEN
          load_zobs(ng)=.true.
        END IF
 
#  ifdef DISTRIBUTE
!
!  If distributed-memory and SOME or ALL observations have Zobs in
!  meters (Zobs < 0), zero-out Zobs values in all nodes but itself
!  to facilitate exchages between tiles latter before writting into
!  observation NetCDF file.
!
        IF (.not.wrote_zobs(ng).and.load_zobs(ng)) THEN
          CALL obs_depth (ng, myrank, model)
        END IF
#  endif
# endif
!
!  Read in observation values.
!
        CALL netcdf_get_fvar (ng, model, obs(ng)%name, vname(1,idoval), &
     &                        obsval(mstr:),                            &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  If appropriate, read in observation meta values.
!
        IF (haveobsmeta(ng)) THEN
          CALL netcdf_get_fvar (ng, model, obs(ng)%name,                &
     &                          vname(1,idomet),                        &
     &                          obsmeta(mstr:),                         &
     &                          ncid = obs(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
!
# ifdef WEAK_CONSTRAINT
!  Read in observation error covariance.
# else
!  Read in observation error covariance. To avoid successive divisions,
!  convert to inverse observation error covariance.
# endif
!
        CALL netcdf_get_fvar (ng, model, obs(ng)%name, vname(1,idoerr), &
     &                        obserr(mstr:),                            &
     &                        ncid = obs(ng)%ncid,                      &
     &                        start = (/nstrobs(ng)/),                  &
     &                        total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
# ifndef WEAK_CONSTRAINT
        DO iobs=1,nobs(ng)
          obserr(iobs)=1.0_r8/obserr(iobs)
        END DO
# endif
!
!  Read in nonlinear model values at observation locations.
!
        IF (readnlmod.and.havenlmod(ng)) THEN
# if defined VERIFICATION || defined TLM_CHECK
          CALL netcdf_get_fvar (ng, model, dav(ng)%name,                &
     &                          vname(1,idnlmo),                        &
     &                          nlmodval(mstr:),                        &
     &                          ncid = dav(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
# else
          CALL netcdf_get_fvar (ng, model, dav(ng)%name,                &
     &                          vname(1,idnlmo),                        &
     &                          nlmodval(mstr:),                        &
     &                          ncid = dav(ng)%ncid,                    &
     &                          start = (/nstrobs(ng),outer/),          &
     &                          total = (/nobs(ng),1/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
# endif
# ifdef BGQC_NOT_NEEDED
          CALL netcdf_get_fvar (ng, model, dav(ng)%name,                &
     &                          vname(1,idbger),                        &
     &                          bgerr(mstr:),                           &
     &                          ncid = dav(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          CALL netcdf_get_fvar (ng, model, dav(ng)%name,                &
     &                          vname(1,idobss),                        &
     &                          obsscale(mstr:),                        &
     &                          ncid = dav(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
# endif
        END IF
 
# if defined TLM_OBS && !defined WEAK_CONSTRAINT
!
!  If adjoint pass and incremental 4DVar, read in tangent linear model
!  values at observation locations.
!
        IF (readtlmod.and.havetlmod(ng)) THEN
          CALL netcdf_get_fvar (ng, model, dav(ng)%name,                &
     &                          vname(1,idtlmo),                        &
     &                          tlmodval(mstr:),                        &
     &                          ncid = dav(ng)%ncid,                    &
     &                          start = (/nstrobs(ng)/),                &
     &                          total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#  if defined I4DVAR
!
!  Reset TLM values to zero at the first pass of the inner loop.
!
          IF (inner.eq.0) THEN
            DO iobs=1,mobs
              tlmodval(iobs)=0.0_r8
            END DO
          END IF
#  endif
        END IF
# endif
!
!-----------------------------------------------------------------------
!  Set counters for number of observations to processed for each state
!  variable.
!-----------------------------------------------------------------------
!
        DO iobs=mstr,mend
          IF  (obstype(iobs).eq.obsstate2type(isfsur)) THEN
            fourdvar(ng)%ObsCount(isfsur)=                              &
     &                           fourdvar(ng)%ObsCount(isfsur)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isubar)) THEN
            fourdvar(ng)%ObsCount(isubar)=                              &
     &                           fourdvar(ng)%ObsCount(isubar)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isvbar)) THEN
            fourdvar(ng)%ObsCount(isvbar)=                              &
     &                           fourdvar(ng)%ObsCount(isvbar)+1
# ifdef SOLVE3D
          ELSE IF (obstype(iobs).eq.obsstate2type(isuvel)) THEN
            fourdvar(ng)%ObsCount(isuvel)=                              &
     &                           fourdvar(ng)%ObsCount(isuvel)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isvvel)) THEN
            fourdvar(ng)%ObsCount(isvvel)=                              &
     &                           fourdvar(ng)%ObsCount(isvvel)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isradial)) THEN
            haveobsmeta(ng)=.true.
            fourdvar(ng)%ObsCount(isradial)=                            &
     &                           fourdvar(ng)%ObsCount(isradial)+1
          ELSE
            DO itrc=1,nt(ng)
              IF (obstype(iobs).eq.obsstate2type(istvar(itrc))) THEN
                i=istvar(itrc)
                fourdvar(ng)%ObsCount(i)=fourdvar(ng)%ObsCount(i)+1
              END IF
            END DO
# endif
          END IF
        END DO
!
!-----------------------------------------------------------------------
!  If applicable, set next observation survey time to process.
!-----------------------------------------------------------------------
!
        IF (master) THEN
          CALL time_string (obstime(ng), t_code)
          WRITE (stdout,10) obstime(ng)*sec2day, t_code
        END IF
        IF (backward) THEN
          IF ((obssurvey(ng)-1).ge.1) THEN
            obstime(ng)=fourdvar(ng)%SurveyTime(obssurvey(ng)-1)*day2sec
          END IF
        ELSE
          IF ((obssurvey(ng)+1).le.nsurvey(ng)) THEN
            obstime(ng)=fourdvar(ng)%SurveyTime(obssurvey(ng)+1)*day2sec
          END IF
        END IF
      END IF
!
  10  FORMAT (/,' Number of State Observations Processed:',2x,          &
     &        'ObsTime = ',f12.4,',',t68,a,/,/,                         &
     &        10x,'Variable',10x,'IstrObs',4x,'IendObs',6x,'Count',     &
     &        3x,'Rejected',/)
!
      RETURN
      END SUBROUTINE obs_read_nf90
 
# if defined PIO_LIB && defined DISTRIBUTE
!
!***********************************************************************
      SUBROUTINE obs_read_pio (ng, model, backward)
!***********************************************************************
!
      USE mod_pio_netcdf
!
!  Imported variable declarations.
!
      logical, intent(in) :: backward
!
      integer, intent(in) :: ng, model
!
!  Local variable declarations.
!
      logical :: readnlmod, readtlmod
!
      integer :: mstr, mend
      integer :: i, iobs, itrc, status
!
      character (len=22) :: t_code
 
      character (len=*), parameter :: myfile =                          &
     &  __FILE__//", obs_read_pio"
!
      sourcefile=myfile
!
!---------------------------------------------------------------------
!  Read observation variables needed for interpolating the model
!  state at the observation locations.
!---------------------------------------------------------------------
!
      IF (processobs(ng)) THEN
#  if defined TLM_OBS
#   if defined I4DVAR_ANA_SENSITIVITY
        readnlmod=.false.
#   else
        readnlmod=.true.
#   endif
        readtlmod=.true.
#  else
        readnlmod=.false.
        readtlmod=.false.
#  endif
!
!  Initialize observations processing counters.
!
        DO i=1,nobsvar(ng)
          fourdvar(ng)%ObsCount(i)=0
          fourdvar(ng)%ObsReject(i)=0
        END DO
        IF (backward) THEN
          obssurvey(ng)=obssurvey(ng)-1
        ELSE
          obssurvey(ng)=obssurvey(ng)+1
        END IF
!
!  Set number of observations to process.
!
        nobs(ng)=fourdvar(ng)%NobsSurvey(obssurvey(ng))
!
!  Set number of datum to process at current time-step.
!
        IF (backward) THEN
          nendobs(ng)=nstrobs(ng)-1
          nstrobs(ng)=nstrobs(ng)-nobs(ng)
        ELSE
          nstrobs(ng)=nendobs(ng)+1
          nendobs(ng)=nstrobs(ng)+nobs(ng)-1
        END IF
!
!  Set starting index of obervation vectors for reading.  In weak
!  constraint, the entire observation data is loaded. Otherwise,
!  only the observartion for the current time window are loaded
!  and started from vector index one.
!
#  ifdef WEAK_CONSTRAINT
        mstr=nstrobs(ng)
        mend=nendobs(ng)
#  else
        mstr=1
        mend=nobs(ng)
#  endif
!
!  Read in observation type identifier.
!
        CALL pio_netcdf_get_ivar (ng, model, obs(ng)%name,              &
     &                            vname(1,idotyp),                      &
     &                            obstype(mstr:),                       &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation provenance identifier.
!
        CALL pio_netcdf_get_ivar (ng, model, obs(ng)%name,              &
     &                            vname(1,idopro),                      &
     &                            obsprov(mstr:),                       &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation time (days).
!
        CALL pio_netcdf_get_time (ng, model, obs(ng)%name,              &
     &                            vname(1,idobst),                      &
     &                            rclock%DateNumber, tobs(mstr:),       &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation X-location (grid units).
!
        CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,              &
     &                            vname(1,idobsx),                      &
     &                            xobs(mstr:),                          &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Read in observation Y-location (grid units).
!
        CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,              &
     &                            vname(1,idobsy),                      &
     &                            yobs(mstr:),                          &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#  ifdef SOLVE3D
!
!  Read in observation depth, Zobs.  If negative, depth is meter. If
!  greater than zero, Zobs is in model fractional vertical levels
!  (1 <= Zobs <= N). If Zobs < 0, its fractional level value is
!  computed in routine "extract_obs3d" and over-written so it can
!  be written into the observation NetCDF file for latter use.
!
        IF (wrote_zobs(ng)) THEN
          CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,            &
     &                              vname(1,idobsz),                    &
     &                              zobs(mstr:),                        &
     &                              piofile = obs(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        ELSE
          CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,            &
     &                              vname(1,idobsd),                    &
     &                              zobs(mstr:),                        &
     &                              piofile = obs(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
        load_zobs(ng)=.false.
        IF ((minval(zobs).lt.0.0_r8).or.                                &
     &      (maxval(zobs).lt.0.0_r8)) THEN
          load_zobs(ng)=.true.
        END IF
!
!  If distributed-memory and SOME or ALL observations have Zobs in
!  meters (Zobs < 0), zero-out Zobs values in all nodes but itself
!  to facilitate exchages between tiles latter before writting into
!  observation NetCDF file.
!
        IF (.not.wrote_zobs(ng).and.load_zobs(ng)) THEN
          CALL obs_depth (ng, myrank, model)
        END IF
#  endif
!
!  Read in observation values.
!
        CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,              &
     &                            vname(1,idoval),                      &
     &                            obsval(mstr:),                        &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  If appropriate, read in observation meta values.
!
        IF (haveobsmeta(ng)) THEN
          CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,            &
     &                              vname(1,idomet),                    &
     &                              obsmeta(mstr:),                     &
     &                              piofile = obs(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
!
#  ifdef WEAK_CONSTRAINT
!  Read in observation error covariance.
#  else
!  Read in observation error covariance. To avoid successive divisions,
!  convert to inverse observation error covariance.
#  endif
!
        CALL pio_netcdf_get_fvar (ng, model, obs(ng)%name,              &
     &                            vname(1,idoerr),                      &
     &                            obserr(mstr:),                        &
     &                            piofile = obs(ng)%pioFile,            &
     &                            start = (/nstrobs(ng)/),              &
     &                            total = (/nobs(ng)/))
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#  ifndef WEAK_CONSTRAINT
        DO iobs=1,nobs(ng)
          obserr(iobs)=1.0_r8/obserr(iobs)
        END DO
#  endif
!
!  Read in nonlinear model values at observation locations.
!
        IF (readnlmod.and.havenlmod(ng)) THEN
#  ifdef VERIFICATION
          CALL pio_netcdf_get_fvar (ng, model, dav(ng)%name,            &
     &                              vname(1,idnlmo),                    &
     &                              nlmodval(mstr:),                    &
     &                              piofile = dav(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#  else
          CALL pio_netcdf_get_fvar (ng, model, dav(ng)%name,            &
     &                              vname(1,idnlmo),                    &
     &                              nlmodval(mstr:),                    &
     &                              piofile = dav(ng)%pioFile,          &
     &                              start = (/nstrobs(ng),outer/),      &
     &                              total = (/nobs(ng),1/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#  endif
#  ifdef BGQC_NOT_NEEDED
          CALL pio_netcdf_get_fvar (ng, model, dav(ng)%name,            &
     &                              vname(1,idbger),                    &
     &                              bgerr(mstr:),                       &
     &                              piofile = dav(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
          CALL pio_netcdf_get_fvar (ng, model, dav(ng)%name,            &
     &                              vname(1,idobss),                    &
     &                              obsscale(mstr:),                    &
     &                              piofile = dav(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#  endif
        END IF
 
#  if defined TLM_OBS && !defined WEAK_CONSTRAINT
!
!  If adjoint pass and incremental 4DVar, read in tangent linear model
!  values at observation locations.
!
        IF (readtlmod.and.havetlmod(ng)) THEN
          CALL pio_netcdf_get_fvar (ng, model, dav(ng)%name,            &
     &                              vname(1,idtlmo),                    &
     &                              tlmodval(mstr:),                    &
     &                              piofile = dav(ng)%pioFile,          &
     &                              start = (/nstrobs(ng)/),            &
     &                              total = (/nobs(ng)/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#   if defined I4DVAR
!
!  Reset TLM values to zero at the first pass of the inner loop.
!
          IF (inner.eq.0) THEN
            DO iobs=1,mobs
              tlmodval(iobs)=0.0_r8
            END DO
          END IF
#   endif
        END IF
#  endif
!
!-----------------------------------------------------------------------
!  Set counters for number of observations to processed for each state
!  variable.
!-----------------------------------------------------------------------
!
        DO iobs=mstr,mend
          IF  (obstype(iobs).eq.obsstate2type(isfsur)) THEN
            fourdvar(ng)%ObsCount(isfsur)=                              &
     &                           fourdvar(ng)%ObsCount(isfsur)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isubar)) THEN
            fourdvar(ng)%ObsCount(isubar)=                              &
     &                           fourdvar(ng)%ObsCount(isubar)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isvbar)) THEN
            fourdvar(ng)%ObsCount(isvbar)=                              &
     &                           fourdvar(ng)%ObsCount(isvbar)+1
#  ifdef SOLVE3D
          ELSE IF (obstype(iobs).eq.obsstate2type(isuvel)) THEN
            fourdvar(ng)%ObsCount(isuvel)=                              &
     &                           fourdvar(ng)%ObsCount(isuvel)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isvvel)) THEN
            fourdvar(ng)%ObsCount(isvvel)=                              &
     &                           fourdvar(ng)%ObsCount(isvvel)+1
          ELSE IF (obstype(iobs).eq.obsstate2type(isradial)) THEN
            haveobsmeta(ng)=.true.
            fourdvar(ng)%ObsCount(isradial)=                            &
     &                           fourdvar(ng)%ObsCount(isradial)+1
          ELSE
            DO itrc=1,nt(ng)
              IF (obstype(iobs).eq.obsstate2type(istvar(itrc))) THEN
                i=istvar(itrc)
                fourdvar(ng)%ObsCount(i)=fourdvar(ng)%ObsCount(i)+1
              END IF
            END DO
#  endif
          END IF
        END DO
!
!-----------------------------------------------------------------------
!  If applicable, set next observation survey time to process.
!-----------------------------------------------------------------------
!
        IF (master) THEN
          CALL time_string (obstime(ng), t_code)
          WRITE (stdout,10) obstime(ng)*sec2day, t_code
        END IF
        IF (backward) THEN
          IF ((obssurvey(ng)-1).ge.1) THEN
            obstime(ng)=fourdvar(ng)%SurveyTime(obssurvey(ng)-1)*day2sec
          END IF
        ELSE
          IF ((obssurvey(ng)+1).le.nsurvey(ng)) THEN
            obstime(ng)=fourdvar(ng)%SurveyTime(obssurvey(ng)+1)*day2sec
          END IF
        END IF
      END IF
!
  10  FORMAT (/,' Number of State Observations Processed:',2x,          &
     &        'ObsTime = ',f12.4,',',t68,a,/,/,                         &
     &        10x,'Variable',10x,'IstrObs',4x,'IendObs',6x,'Count',     &
     &        3x,'Rejected',/)
!
      RETURN
      END SUBROUTINE obs_read_pio
# endif
#endif
      END MODULE obs_read_mod