yaml_parser_mod::yaml_get Interface Reference

Public Member Functions
integer function	yaml_get_i_struc (self, keystring, v)
integer function	yaml_get_l_struc (self, keystring, v)
integer function	yaml_get_r_struc (self, keystring, v)
integer function	yaml_get_s_struc (self, keystring, v)
integer function	yaml_get_ivar_0d (self, keystring, value)
integer function	yaml_get_ivar_1d (self, keystring, value)
integer function	yaml_get_lvar_0d (self, keystring, value)
integer function	yaml_get_lvar_1d (self, keystring, value)
integer function	yaml_get_rvar_0d (self, keystring, value)
integer function	yaml_get_rvar_1d (self, keystring, value)
integer function	yaml_get_svar_0d (self, keystring, value)
integer function	yaml_get_svar_1d (self, keystring, value)

Detailed Description

Definition at line 233 of file yaml_parser.F.

Member Function/Subroutine Documentation

yaml_get_i_struc()

integer function yaml_parser_mod::yaml_get::yaml_get_i_struc	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		type (yaml_ivec), dimension(:), intent(out), allocatable	v )

Definition at line 1735 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It loads a vector set of integers in YAML block-list structure,     !
!  V(1:Nitems)%vector(1:Nvalues).  If the dummy argument V structure   !
!  is allocated, it deallocates/allocates the required Nitems and      !
!  Nvalues dimensions.                                                 !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     V          Vector of integers in block list (TYPE yaml_Ivec)     !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      TYPE (yaml_Ivec), allocatable, intent(out) :: V(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: LenStr, Nitems, Nvalues, i, n
      integer :: status
!
      character (len=Lmax) :: msg
 
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_i_struc"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Allocate output structure.
!
      nitems=SIZE(s, dim=1)
      IF (ALLOCATED(v)) DEALLOCATE (v)
      ALLOCATE ( v(nitems) )
!
!  Convert string vector values to integers.
!
      DO n=1,nitems
        IF (s(n)%has_vector) THEN
          nvalues=SIZE(s(n)%vector)
          ALLOCATE ( v(n)%vector(nvalues) )
          DO i=1,nvalues
            READ (s(n)%vector(i)%value, * ,iostat=status, iomsg=msg)    &
     &           v(n)%vector(i)
            IF (yaml_error(status, noerr, __line__, myfile)) THEN
              yaml_errflag=5
              IF (yaml_master) WRITE (yaml_stdout,10) trim(keystring),  &
     &                                            s(n)%vector(i)%value, &
     &                                                trim(msg)
              RETURN
            END IF
          END DO
        END IF
      END DO
!
!  Deallocate local extraction structure.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_I_STRUC - Error while converting string to', &
     &        ' integer, key: ',a,', value = ',a,/,20x,'ErrMsg: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_ivar_0d()

integer function yaml_parser_mod::yaml_get::yaml_get_ivar_0d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		integer, intent(out)	value )

Definition at line 2061 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets scalar integer data from YAML dictionary object.            !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (integer; scalar)                          !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      integer, intent(out) :: value
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, status
!
      character (len=Lmax) :: msg
 
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_ivar_0d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string value.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s)
!
      IF (nvalues.gt.1) THEN
        status=7
        yaml_errflag=status
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            self%filename
          RETURN
        END IF
!
!  Convert string value to integer.
!
      ELSE
        READ (s(1)%value, *, iostat=status, iomsg=msg) value
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          yaml_errflag=5
          IF (yaml_master) WRITE (yaml_stdout,20) trim(keystring),      &
     &                                            s(1)%value, trim(msg)
          RETURN
        END IF
      END IF
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_IVAR_0D - Extracted value is not a scalar,', &
     &        ' key-string: ',a,/,20x,'Nvalues = ',i0,/,20x,'File: ',a)
  20  FORMAT (/,' YAML_GET_IVAR_0D - Error while converting string to', &
     &        ' integer, key: ',a,', value = ',a,/,20x,'ErrMsg: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_ivar_1d()

integer function yaml_parser_mod::yaml_get::yaml_get_ivar_1d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		integer, dimension(:), intent(out)	value )

Definition at line 2142 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets 1D integer data from YAML dictionary object.                !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (integer; 1D-array)                        !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      integer, intent(out) :: value(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, i, status
!
      character (len=Lmax) :: msg
 
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_ivar_1d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s, dim=1)
!
      IF (SIZE(value, dim=1).lt.nvalues) THEN
        status=7
        yaml_errflag=status
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            SIZE(value, dim=1),   &
     &                                            self%filename
          RETURN
        END IF
      END IF
!
!  Convert string values to integers.
!
      DO i=1,nvalues
        READ (s(i)%value, *, iostat=status, iomsg=msg) value(i)
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          yaml_errflag=5
          IF (yaml_master) WRITE (yaml_stdout,20) trim(keystring),      &
     &                                            s(i)%value, trim(msg)
          RETURN
        END IF
      END DO
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_IVAR_1D - Inconsistent number of values,',   &
     &        ' key-string: ',a,/,20x,'YAML size = ',i0,                &
     &        ', Variable size = ',i0,/,20x,'File: ',a)
  20  FORMAT (/,' YAML_GET_IVAR_1D - Error while converting string to', &
     &        ' integer, key: ',a,', value = ',a,/,20x,'ErrMsg: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_l_struc()

integer function yaml_parser_mod::yaml_get::yaml_get_l_struc	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		type (yaml_lvec), dimension(:), intent(out), allocatable	v )

Definition at line 1819 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It loads a vector set of logicals in YAML block-list structure,     !
!  V(1:Nitems)%vector(1:Nvalues).  If the dummy argument V structure   !
!  is allocated, it deallocates/allocates the required Nitems and      !
!  Nvalues dimensions.                                                 !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     V          Vector of logicals in block list (TYPE yaml_Lvec)     !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      TYPE (yaml_Lvec), allocatable, intent(out) :: V(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nitems, Nvalues, n, i
      integer :: status
!
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_l_struc"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Allocate output structure.
!
      nitems=SIZE(s, dim=1)
      IF (ALLOCATED(v)) DEALLOCATE (v)
      ALLOCATE ( v(nitems) )
!
!  Convert string vector values to logicals.
!
      DO n=1,nitems
        IF (s(n)%has_vector) THEN
          nvalues=SIZE(s(n)%vector)
          ALLOCATE ( v(n)%vector(nvalues) )
          DO i=1,nvalues
            IF (yaml_uppercase(s(n)%vector(i)%value(1:1)).eq.'T') THEN
              v(n)%vector(i)=.true.
            ELSE
              v(n)%vector(i)=.false.
            END IF
          END DO
        END IF
      END DO
!
!  Deallocate local extraction structure.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
      RETURN

References yaml_parser_mod::noerr, yaml_parser_mod::yaml_error(), and yaml_parser_mod::yaml_uppercase().

Here is the call graph for this function:

yaml_get_lvar_0d()

integer function yaml_parser_mod::yaml_get::yaml_get_lvar_0d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		logical, intent(out)	value )

Definition at line 2226 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets scalar logical data from YAML disctionary object.           !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (logical; scalar)                          !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      logical, intent(out) :: value
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, status
!
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_lvar_0d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string value.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s)
!
      IF (nvalues.gt.1) THEN
        status=7
        yaml_errflag=status
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            self%filename
          RETURN
        END IF
!
!  Convert string value to logical.
!
      ELSE
        IF (yaml_uppercase(s(1)%value(1:1)).eq.'T') THEN
          value=.true.
        ELSE
          value=.false.
        END IF
      END IF
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_LVAR_0D - Extracted value is not a scalar,', &
     &        ' key-string: ',a,/,20x,'Nvalues = ',i0,/,20x,'File: ',a)
!
      RETURN

References yaml_parser_mod::noerr, yaml_parser_mod::yaml_error(), and yaml_parser_mod::yaml_uppercase().

Here is the call graph for this function:

yaml_get_lvar_1d()

integer function yaml_parser_mod::yaml_get::yaml_get_lvar_1d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		logical, dimension(:), intent(out)	value )

Definition at line 2300 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets 1D logical data from YAML dictionary object.                !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (logical; 1D-array)                        !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      logical, intent(out) :: value(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, i, status
!
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_lvar_1d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s, dim=1)
!
      IF (SIZE(value, dim=1).lt.nvalues) THEN
        yaml_errflag=7
        status=yaml_errflag
        IF (yaml_error(yaml_errflag, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            SIZE(value, dim=1),   &
     &                                            self%filename
          RETURN
        END IF
      END IF
!
!  Convert string values to logicals.
!
      DO i=1,nvalues
        IF (yaml_uppercase(s(i)%value(1:1)).eq.'T') THEN
          value(i)=.true.
        ELSE
          value(i)=.false.
        END IF
      END DO
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_LVAR_1D - Inconsistent number of values,',   &
     &        ' key-string: ',a,/,20x,'YAML size = ',i0,                &
     &        ', Variable size = ',i0,/,20x,'File: ',a)
!
      RETURN

References yaml_parser_mod::noerr, yaml_parser_mod::yaml_error(), and yaml_parser_mod::yaml_uppercase().

Here is the call graph for this function:

yaml_get_r_struc()

integer function yaml_parser_mod::yaml_get::yaml_get_r_struc	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		type (yaml_rvec), dimension(:), intent(out), allocatable	v )

Definition at line 1894 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It loads a vector set of real values in YAML block-list structure,  !
!  V(1:Nitems)%vector(1:Nvalues).  If the dummy argument V structure   !
!  is allocated, it deallocates/allocates the required Nitems and      !
!  Nvalues dimensions.                                                 !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     V          Vector of reals in block list (TYPE yaml_Rvec)        !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      TYPE (yaml_Rvec), allocatable, intent(out) :: V(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nitems, Nvalues, i, n
      integer :: status
!
      character (len=Lmax) :: msg
 
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_r_struc"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Allocate output structure.
!
      nitems=SIZE(s, dim=1)
      IF (ALLOCATED(v)) DEALLOCATE (v)
      ALLOCATE ( v(nitems) )
!
!  Convert string vector values to floating-point.
!
      DO n=1,nitems
        IF (s(n)%has_vector) THEN
          nvalues=SIZE(s(n)%vector)
          ALLOCATE ( v(n)%vector(nvalues) )
          DO i=1,nvalues
            READ (s(n)%vector(i)%value, * ,iostat=status, iomsg=msg)    &
     &           v(n)%vector(i)
            IF (yaml_error(status, noerr, __line__, myfile)) THEN
              yaml_errflag=5
              IF (yaml_master) WRITE (yaml_stdout,10) trim(keystring),  &
     &                                            s(n)%vector(i)%value, &
     &                                                trim(msg)
              RETURN
            END IF
          END DO
        ELSE
          READ (s(n)%value, * ,iostat=status, iomsg=msg)                &
     &         v(n)%vector(i)
          IF (yaml_error(status, noerr, __line__, myfile)) THEN
            yaml_errflag=5
            IF (yaml_master) WRITE (yaml_stdout,10) trim(keystring),    &
     &                                              s(n)%value,         &
     &                                              trim(msg)
            RETURN
          END IF
        END IF
      END DO
!
!  Deallocate local extraction structure.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_R_STRUC - Error while converting string to', &
     &        ' real, key: ',a,', value = ',a,/,20x,'ErrMsg: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_rvar_0d()

integer function yaml_parser_mod::yaml_get::yaml_get_rvar_0d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		real (kind_real), intent(out)	value )

Definition at line 2378 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets scalar floating-point data from YAML dictionary object.     !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (real; scalar)                             !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      real (kind_real), intent(out) :: value
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, ie, status
!
      character (len=Lmax) :: msg
 
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_rvar_0d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string value.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s)
!
      IF (nvalues.gt.1) THEN
        yaml_errflag=7
        status=yaml_errflag
        IF (yaml_error(yaml_errflag, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            self%filename
          RETURN
        END IF
!
!  Convert string value to real.
!
      ELSE
        s(1)%value=adjustl(s(1)%value)
        ie=len_trim(s(1)%value)
        READ (s(1)%value(1:ie), *, iostat=status, iomsg=msg) value
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          yaml_errflag=5
          IF (yaml_master) WRITE (yaml_stdout,20) trim(keystring),      &
     &                                            s(1)%value, trim(msg)
          RETURN
        END IF
      END IF
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_RVAR_0D - Extracted value is not a scalar,', &
     &        ' key-string: ',a,/,20x,'Nvalues = ',i0,/,20x,'File: ',a)
  20  FORMAT (/,' YAML_GET_RVAR_0D - Error while converting string to', &
     &        ' integer, key: ',a,', value = ',a,/,20x,'ErrMsg: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_rvar_1d()

integer function yaml_parser_mod::yaml_get::yaml_get_rvar_1d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		real (kind_real), dimension(:), intent(out)	value )

Definition at line 2461 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets 1D floating-point data from YAML dictionary object.         !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (real; 1D-array)                           !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      real (kind_real), intent(out) :: value(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, i, ie, status
!
      character (len=Lmax) :: msg
 
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_rvar_1d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s, dim=1)
!
      IF (SIZE(value, dim=1).lt.nvalues) THEN
        yaml_errflag=7
        status=yaml_errflag
        IF (yaml_error(yaml_errflag, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            SIZE(value, dim=1),   &
     &                                            self%filename
          RETURN
        END IF
      END IF
!
!  Convert string values to reals.
!
      DO i=1,nvalues
        s(i)%value=adjustl(s(i)%value)
        ie=len_trim(s(i)%value)
        READ (s(i)%value(1:ie), *, iostat=status, iomsg=msg) value(i)
        IF (yaml_error(status, noerr, __line__, myfile)) THEN
          yaml_errflag=5
          IF (yaml_master) WRITE (yaml_stdout,20) trim(keystring),      &
     &                                            s(i)%value, trim(msg)
          RETURN
        END IF
      END DO
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_RVAR_1D - Inconsistent number of values,',   &
     &        ' key-string: ',a,/,20x,'YAML size = ',i0,                &
     &        ', Variable size = ',i0,/,20x,'File: ',a)
  20  FORMAT (/,' YAML_GET_RVAR_1D - Error while converting string to', &
     &        ' real, key: ',a,', value = ',a,/,20x,'ErrMsg: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_s_struc()

integer function yaml_parser_mod::yaml_get::yaml_get_s_struc	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		type (yaml_svec), dimension(:), intent(out), allocatable	v )

Definition at line 1988 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It loads a vector set of strings in YAML block-list structure,      !
!  V(1:Nitems)%vector(1:Nvalues)%value.  If the dummy argument V       !
!  structure is allocated, it deallocates/allocates the required       !
!  Nitems and Nvalues dimensions.                                      !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     V          Vector of strings in block list (TYPE yaml_Svec)      !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in) :: self
      character (len=*), intent(in) :: keystring
      TYPE (yaml_Svec), allocatable, intent(out) :: V(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nitems, Nvalues, n, i
      integer :: status
!
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_s_struc"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Allocate output structure.
!
      nitems=SIZE(s, dim=1)
      IF (ALLOCATED(v)) DEALLOCATE (v)
      ALLOCATE ( v(nitems) )
!
!  Load string vector values to output structure.
!
      DO n=1,nitems
        IF (s(n)%has_vector) THEN
          nvalues=SIZE(s(n)%vector)
          ALLOCATE ( v(n)%vector(nvalues) )
          DO i=1,nvalues
            v(n)%vector(i)%value=s(n)%vector(i)%value
          END DO
        ELSE
          v(n)%value=s(n)%value
        END IF
      END DO
!
!  Deallocate local extraction structure.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_svar_0d()

integer function yaml_parser_mod::yaml_get::yaml_get_svar_0d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		character (len=*), intent(out)	value )

Definition at line 2547 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets scalar string data from YAML dictionary object.             !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (string; scalar)                           !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in ) :: self
      character (len=*), intent(in ) :: keystring
      character (len=*), intent(out) :: value
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, status
!
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_lvar_0d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string value.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s)
!
      IF (nvalues.gt.1) THEN
        yaml_errflag=7
        status=yaml_errflag
        IF (yaml_error(yaml_errflag, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            self%filename
          RETURN
        END IF
!
!  Load string value.
!
      ELSE
        value=s(1)%value
      END IF
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_SVAR_0D - Extracted value is not a scalar,', &
     &        ' key-string: ',a,/,20x,'Nvalues = ',i0,/,20x,'File: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

yaml_get_svar_1d()

integer function yaml_parser_mod::yaml_get::yaml_get_svar_1d	(	class (yaml_tree), intent(in)	self,
		character (len=*), intent(in)	keystring,
		character (len=*), dimension(:), intent(out)	value )

Definition at line 2618 of file yaml_parser.F.

!
!***********************************************************************
!                                                                      !
!  It gets 1D string data from YAML dictionary object.                 !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     self       YAML tree dictionary object (CLASS yaml_tree)         !
!     keystring  YAML tree aggregated keys (string)                    !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     value      YAML value (string; 1D-array)                         !
!     status     Error code (integer)                                  !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      class(yaml_tree), intent(in ) :: self
      character (len=*), intent(in ) :: keystring
      character (len=*), intent(out) :: value(:)
!
!  Local variable declarations.
!
      TYPE (yaml_extract), allocatable :: S(:)
!
      integer :: Nvalues, i, status
!
      character (len=*), parameter :: MyFile =                          &
     &   __FILE__//", yaml_Get_lvar_1d"
!
!-----------------------------------------------------------------------
!  Extract requested key-string values.
!-----------------------------------------------------------------------
!
      status=noerr
!
      IF (yaml_error(self%extract(keystring, s),                        &
     &               noerr, __line__, myfile)) RETURN
!
!  Make sure that extracted value is a scalar.
!
      nvalues=SIZE(s, dim=1)
!
      IF (SIZE(value, dim=1).lt.nvalues) THEN
        yaml_errflag=7
        status=yaml_errflag
        IF (yaml_error(yaml_errflag, noerr, __line__, myfile)) THEN
          IF (yaml_master) WRITE (yaml_stdout,10) keystring, nvalues,   &
     &                                            SIZE(value, dim=1),   &
     &                                            self%filename
          RETURN
        END IF
      END IF
!
!  Load string values.
!
      DO i=1,nvalues
        value(i)=s(i)%value
      END DO
!
!  Deallocate.
!
      IF (ALLOCATED(s)) DEALLOCATE (s)
!
  10  FORMAT (/,' YAML_GET_SVAR_1D - Inconsistent number of values,',   &
     &        ' key-string: ',a,/,20x,'YAML size = ',i0,                &
     &        ', Variable size = ',i0,/,20x,'File: ',a)
!
      RETURN

References yaml_parser_mod::noerr, and yaml_parser_mod::yaml_error().

Here is the call graph for this function:

---

The documentation for this interface was generated from the following file:

• ROMS/Utility/yaml_parser.F