get_env_mod::get_env Interface Reference

Public Member Functions
integer function	get_env_i (name, value)
integer function	get_env_l (name, value)
integer function	get_env_s (name, value)

Detailed Description

Definition at line 22 of file get_env.F.

Member Function/Subroutine Documentation

get_env_i()

integer function get_env_mod::get_env::get_env_i	(	character (len=*), intent(in)	name,
		integer, intent(out)	value )

Definition at line 30 of file get_env.F.

!
!***********************************************************************
!                                                                      !
!  Reads and decodes environmental variable with an integer value.     !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      integer,           intent(out) :: value
      character (len=*), intent(in ) :: name
!
!  Local variable declaration.
!
      integer                        :: Lstr, status
      character (len=40)             :: string
      character (len=512)            :: msg
!
!-----------------------------------------------------------------------
!  Read and decode environmental variable. Return "value=-1" if not
!  found.
!-----------------------------------------------------------------------
!
      CALL get_environment_variable (name, string, lstr, status)
!
!  Convert to integer.
!
      IF ((lstr.gt.0).and.(status.eq.0)) THEN
        READ (string, *, iostat=status, iomsg=msg) value
        IF (master.and.(status.ne.0)) THEN
          WRITE (stdout,10) trim(name), trim(string), trim(msg)
        END IF
      ELSE
        status=1
        value=-1
        IF (master) THEN
          WRITE (stdout,20) trim(name)
        END IF
      END IF
!
  10  FORMAT (/,' GET_ENV_I - Error while converting string to',        &
     &        ' integer, name = ',a,', value = ',a,/,13x,'ErrMsg: ',a)
  20  FORMAT (/,' GET_ENV_I - Cannot find environmental variable',      &
     &        ', name = ',a)
!
      RETURN

References mod_parallel::master, and mod_iounits::stdout.

get_env_l()

integer function get_env_mod::get_env::get_env_l	(	character (len=*), intent(in)	name,
		logical, intent(out)	value )

Definition at line 79 of file get_env.F.

!
!***********************************************************************
!                                                                      !
!  Reads and decodes environmental variable with an logical value.     !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      logical,           intent(out) :: value
      character (len=*), intent(in ) :: name
!
!  Local variable declaration.
!
      integer                        :: Lstr, status
      character (len=40)             :: string
!
!-----------------------------------------------------------------------
!  Read and decode environmental variable. Return value=.FALSE. if not
!  found.
!-----------------------------------------------------------------------
!
      CALL get_environment_variable (name, string, lstr, status)
!
!  Convert to logical.
!
      value=.false.
!
      IF ((lstr.gt.0).and.(status.eq.0)) THEN
        IF ((string(1:1).eq.'0') .or.                                   &
     &      (string(1:1).eq.'F') .or.                                   &
     &      (string(1:1).eq.'f')) THEN
          value=.false.
        ELSE
          value=.true.
        END IF
      END IF
!
      RETURN

get_env_s()

integer function get_env_mod::get_env::get_env_s	(	character (len=*), intent(in)	name,
		character (len=*), intent(out)	value )

Definition at line 121 of file get_env.F.

!
!***********************************************************************
!                                                                      !
!  Reads string environmental variable.                                !
!                                                                      !
!***********************************************************************
!
!  Imported variable declarations.
!
      character (len=*), intent(in)  :: name
      character (len=*), intent(out) :: value
!
!  Local variable declaration.
!
      integer                        :: Lstr1, Lstr2, status
      character (len=1024)           :: string
!
!-----------------------------------------------------------------------
!  Read environmental variable. Return a blank space, value=CHAR(32),
!  if not found.
!-----------------------------------------------------------------------
!
      CALL get_environment_variable (name, string, lstr1, status)
!
!  Load string value.
!
      lstr2=len(value)
!
      IF (lstr1.gt.lstr2) THEN
        value=string(1:lstr2)
        IF (master) THEN
          WRITE (stdout,10) trim(name), trim(string), lstr2, lstr1
        END IF
      ELSE
        value=string(1:lstr1)
      END IF
!
  10  FORMAT (/,' GET_ENV_S - Error while retrieving enviromental ',    &
     &        'variable, name = ',a,/,13x,"string = '",a,"'",/,13x,     &
     &        'value variable length = ',i0,                            &
     &        ' is less than the required length = ',i0)
!
      RETURN

References mod_parallel::master, and mod_iounits::stdout.

---

The documentation for this interface was generated from the following file:

• ROMS/Utility/get_env.F