set_ngfld.F

Go to the documentation of this file.

#include "cppdefs.h"
      SUBROUTINE set_ngfld (ng, model, ifield,                          &
     &                      LBi, UBi, UBj, Istr, Iend, Jrec,            &
     &                      Finp, Fout, update)
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine time-interpolates requested non-grided field from      !
!  time snapshots of input data.                                       !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng         Nested grid number.                                   !
!     model      Calling model identifier.                             !
!     ifield     Field ID.                                             !
!     LBi        Finp/Fout 1st dimension lower-bound value.            !
!     UBi        Finp/Fout 1st dimension upper-bound value.            !
!     UBj        Finp/Fout 2nd dimension upper-bound value, if any.    !
!                  Otherwise, a value of one is expected.              !
!     Istr       Starting location to process in the 1st dimension.    !
!     Iend       Ending location to process in the 1st dimension.      !
!     Jrec       Number of records to process in the 2nd dimenision,   !
!                  if any, Otherwise, a value of one is expected.      !
!     Finp       Latest two-snapshopts of field to interpolate.        !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     Fout       Interpolated field.                                   !
!     update     Switch indicating successful interpolation.           !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      implicit none
!
!  Imported variable declarations.
!
      logical, intent(out) :: update
 
      integer, intent(in) :: ng, model, ifield
      integer, intent(in) :: LBi, UBi, UBj, Istr, Iend, Jrec
 
      real(r8), intent(in) :: Finp(LBi:UBi,UBj,2)
 
      real(r8), intent(out) :: Fout(LBi:UBi,UBj)
!
!  Local variable declarations.
!
      logical :: Lonerec
 
      integer :: Tindex, i, it1, it2, j
 
      real(dp) :: SecScale, fac, fac1, fac2
!
!----------------------------------------------------------------------
!  Set up requested field from data snapshots.
!----------------------------------------------------------------------
!
!  Get requested field information from global storage.
!
      lonerec=linfo(3,ifield,ng)
      tindex=iinfo(8,ifield,ng)
      update=.true.
!
!  Set linear, time interpolation factors. Fractional seconds are
!  rounded to the nearest milliseconds integer towards zero in the
!  time interpolation weights.
!
      secscale=1000.0_dp              ! seconds to milliseconds
      it1=3-tindex
      it2=tindex
      fac1=anint((tintrp(it2,ifield,ng)-time(ng))*secscale,dp)
      fac2=anint((time(ng)-tintrp(it1,ifield,ng))*secscale,dp)
!
!  Load time-invariant data. Time interpolation is not necessary.
!
      IF (lonerec) THEN
        DO j=1,jrec
          DO i=istr,iend
            fout(i,j)=finp(i,j,tindex)
          END DO
        END DO
!
!  Time-interpolate.
!
      ELSE IF (((fac1*fac2).ge.0.0_dp).and.(fac1+fac2).gt.0.0_dp) THEN
        fac=1.0_dp/(fac1+fac2)
        fac1=fac*fac1                             ! nondimensional
        fac2=fac*fac2                             ! nondimensional
        DO j=1,jrec
          DO i=istr,iend
            fout(i,j)=fac1*finp(i,j,it1)+fac2*finp(i,j,it2)
          END DO
        END DO
!
!  Activate synchronization flag if a new time record needs to be
!  read in at the next time step.
!
        IF ((time(ng)+dt(ng)).gt.tintrp(it2,ifield,ng)) THEN
          synchro_flag(ng)=.true.
        END IF
!
!  Unable to interpolate field.  Activate error flag to quit.
!
      ELSE
        IF (master) THEN
          WRITE (stdout,10) trim(vname(1,ifield)), tdays(ng),           &
     &                      finfo(1,ifield,ng), finfo(2,ifield,ng),     &
     &                      finfo(3,ifield,ng), finfo(4,ifield,ng),     &
     &                      tintrp(it1,ifield,ng)*sec2day,              &
     &                      tintrp(it2,ifield,ng)*sec2day,              &
     &                      fac1*sec2day/secscale,                      &
     &                      fac2*sec2day/secscale
        END IF
  10    FORMAT (/,' SET_NGFLD  - current model time',                   &
     &          ' exceeds ending value for variable: ',a,               &
     &          /,14x,'TDAYS     = ',f15.4,                             &
     &          /,14x,'Data Tmin = ',f15.4,2x,'Data Tmax = ',f15.4,     &
     &          /,14x,'Data Tstr = ',f15.4,2x,'Data Tend = ',f15.4,     &
     &          /,14x,'TINTRP1   = ',f15.4,2x,'TINTRP2   = ',f15.4,     &
     &          /,14x,'FAC1      = ',f15.4,2x,'FAC2      = ',f15.4)
        exit_flag=2
        update=.false.
      END IF
      RETURN
      END SUBROUTINE set_ngfld