set_2dfldr.F

Go to the documentation of this file.

#include "cppdefs.h"
      MODULE set_2dfldr_mod
#ifdef ADJOINT
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine time-interpolates backwards in time requested 2D field !
!  from snapshots of input data.                                       !
!                                                                      !
!=======================================================================
!
      implicit none
 
      CONTAINS
!
!***********************************************************************
      SUBROUTINE set_2dfldr_tile (ng, tile, model, ifield,              &
     &                            LBi, UBi, LBj, UBj,                   &
     &                            Finp, Fout, update,                   &
     &                            SetBC)
!***********************************************************************
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE exchange_2d_mod
# ifdef DISTRIBUTE
      USE mp_exchange_mod, ONLY : mp_exchange2d
# endif
!
!  Imported variable declarations.
!
      logical, intent(in), optional :: SetBC
 
      logical, intent(out) :: update
 
      integer, intent(in) :: ng, tile, model, ifield
      integer, intent(in) :: LBi, UBi, LBj, UBj
!
# ifdef ASSUMED_SHAPE
      real(r8), intent(in) :: Finp(LBi:,LBj:,:)
      real(r8), intent(out) :: Fout(LBi:,LBj:)
# else
      real(r8), intent(in) :: Finp(LBi:UBi,LBj:UBj,2)
      real(r8), intent(out) :: Fout(LBi:UBi,LBj:UBj)
# endif
!
!  Local variable declarations.
!
      logical :: LapplyBC, Lgrided, Lonerec
 
      integer :: Tindex, gtype, i, it1, it2, j
 
      real(dp) :: SecScale, fac, fac1, fac2
      real(r8) :: Fval
 
# include "set_bounds.h"
!
!----------------------------------------------------------------------
!  Set-up requested field for current tile.
!----------------------------------------------------------------------
!
!  Set switch to apply boundary conditions.
!
      IF (PRESENT(setbc)) THEN
        lapplybc=setbc
      ELSE
        lapplybc=.true.
      END IF
!
!  Get requested field information from global storage.
!
      lgrided=linfo(1,ifield,ng)
      lonerec=linfo(3,ifield,ng)
      gtype  =iinfo(1,ifield,ng)
      tindex =iinfo(8,ifield,ng)
      update=.true.
!
!  Set linear, time interpolation factors. Fractional seconds are
!  rounded to the nearest milliseconds integer towards zero in the
!  time interpolation weights.
!
      secscale=1000.0_dp              ! seconds to milliseconds
      it1=3-tindex
      it2=tindex
      fac1=anint((time(ng)-tintrp(it2,ifield,ng))*secscale,dp)
      fac2=anint((tintrp(it1,ifield,ng)-time(ng))*secscale,dp)
!
!  Load time-invariant data. Time interpolation is not necessary.
!
      IF (lonerec) THEN
        IF (lgrided) THEN
          DO j=jstrr,jendr
            DO i=istrr,iendr
              fout(i,j)=finp(i,j,tindex)
            END DO
          END DO
        ELSE
          fval=fpoint(tindex,ifield,ng)
          DO j=jstrr,jendr
            DO i=istrr,iendr
              fout(i,j)=fval
            END DO
          END DO
        END IF
!
!  Time-interpolate from gridded or point data.
!
      ELSE IF (((fac1*fac2).ge.0.0_dp).and.                             &
     &        ((fac1+fac2).gt.0.0_dp)) THEN
        fac=1.0_dp/(fac1+fac2)
        fac1=fac*fac1                             ! nondimensional
        fac2=fac*fac2                             ! nondimensional
        IF (lgrided) THEN
          DO j=jstrr,jendr
            DO i=istrr,iendr
              fout(i,j)=fac1*finp(i,j,it1)+fac2*finp(i,j,it2)
            END DO
          END DO
        ELSE
          fval=fac1*fpoint(it1,ifield,ng)+fac2*fpoint(it2,ifield,ng)
          DO j=jstrr,jendr
            DO i=istrr,iendr
              fout(i,j)=fval
            END DO
          END DO
        END IF
!
!  Activate synchronization flag if a new time record needs to be
!  read in at the next time step.
!
        IF ((time(ng)-dt(ng)).lt.tintrp(it2,ifield,ng)) THEN
          IF (domain(ng)%SouthWest_Test(tile)) synchro_flag(ng)=.true.
        END IF
!
!  Unable to set-up requested field.  Activate error flag to quit.
!
      ELSE
        IF (domain(ng)%SouthWest_Test(tile)) THEN
          IF (master) THEN
            WRITE (stdout,10) trim(vname(1,ifield)), tdays(ng),         &
     &                        finfo(1,ifield,ng), finfo(2,ifield,ng),   &
     &                        finfo(3,ifield,ng), finfo(4,ifield,ng),   &
     &                        tintrp(it1,ifield,ng)*sec2day,            &
     &                        tintrp(it2,ifield,ng)*sec2day,            &
     &                        fac1*sec2day/secscale,                    &
     &                        fac2*sec2day/secscale
          END IF
  10      FORMAT (/,' SET_2DFLDR - current model time',                 &
     &            ' exceeds ending value for variable: ',a,             &
     &            /,14x,'TDAYS     = ',f15.4,                           &
     &            /,14x,'Data Tmin = ',f15.4,2x,'Data Tmax = ',f15.4,   &
     &            /,14x,'Data Tstr = ',f15.4,2x,'Data Tend = ',f15.4,   &
     &            /,14x,'TINTRP1   = ',f15.4,2x,'TINTRP2   = ',f15.4,   &
     &            /,14x,'FAC1      = ',f15.4,2x,'FAC2      = ',f15.4)
          exit_flag=2
          update=.false.
        END IF
      END IF
!
!  Exchange boundary data.
!
      IF (update) THEN
        IF (lapplybc.and.(ewperiodic(ng).or.nsperiodic(ng))) THEN
          IF (gtype.eq.r2dvar) THEN
            CALL exchange_r2d_tile (ng, tile,                           &
     &                              lbi, ubi, lbj, ubj,                 &
     &                              fout)
          ELSE IF (gtype.eq.u2dvar) THEN
            CALL exchange_u2d_tile (ng, tile,                           &
     &                              lbi, ubi, lbj, ubj,                 &
     &                              fout)
          ELSE IF (gtype.eq.v2dvar) THEN
            CALL exchange_v2d_tile (ng, tile,                           &
     &                              lbi, ubi, lbj, ubj,                 &
     &                              fout)
          END IF
        END IF
 
# ifdef DISTRIBUTE
        IF (.not.lapplybc) THEN
          CALL mp_exchange2d (ng, tile, model, 1,                       &
     &                        lbi, ubi, lbj, ubj,                       &
     &                        nghostpoints,                             &
     &                        .false., .false.,                         &
     &                        fout)
        ELSE
          CALL mp_exchange2d (ng, tile, model, 1,                       &
     &                        lbi, ubi, lbj, ubj,                       &
     &                        nghostpoints,                             &
     &                        ewperiodic(ng), nsperiodic(ng),           &
     &                        fout)
        END IF
# endif
      END IF
 
      RETURN
      END SUBROUTINE set_2dfldr_tile
#endif
      END MODULE set_2dfldr_mod