roms.h

Go to the documentation of this file.

      PROGRAM myroms
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  Regional Ocean Model System (ROMS)                                  !
!                                                                      !
!  Master program to execute  ROMS  drivers in ocean mode only         !
!  without coupling (sequential or concurrent) to  any  atmospheric    !
!  model.                                                              !
!                                                                      !
!  This ocean model solves the free surface, hydrostatic, primitive    !
!  equations  over  variable  topography  using  stretched terrain-    !
!  following coordinates in the vertical and orthogonal curvilinear    !
!  coordinates in the horizontal.                                      !
!                                                                      !
!  Nonlinear Model Developers:                                         !
!                                                                      !
!  Dr. Hernan G. Arango                                                !
!    Institute of Marine and Coastal Sciences                          !
!    Rutgers University, New Brunswick, NJ, USA                        !
!    (arango@marine.rutgers.edu)                                       !
!                                                                      !
!  Dr. Alexander F. Shchepetkin                                        !
!    Institute of Geophysics and Planetary Physics                     !
!    UCLA, Los Angeles, CA, USA                                        !
!    (alex@atmos.ucla.edu)                                             !
!                                                                      !
!  Dr. John C. Warner                                                  !
!    U.S. Geological Survey                                            !
!    Woods Hole, MA, USA                                               !
!    (jcwarner@usgs.gov)                                               !
!                                                                      !
!  Tangent linear and Adjoint Models and Algorithms Developers:        !
!                                                                      !
!    Dr. Hernan G. Arango    (arango@marine.rutgers.edu)               !
!    Dr. Bruce Cornuelle     (bcornuelle@ucsd.edu)                     !
!    Dr. Emanuele Di Lorenzo (edl@eas.gatech.edu)                      !
!    Dr. Arthur J. Miller    (ajmiller@ucsd.edu)                       !
!    Dr. Andrew M. Moore     (ammoore@ucsc.edu)                        !
!    Dr. Brian Powell        (powellb@uscs.edu)                        !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_scalars
!
      USE mod_arrays,      ONLY : roms_deallocate_arrays
!
      USE roms_kernel_mod, ONLY : roms_initialize
      USE roms_kernel_mod, ONLY : roms_run
      USE roms_kernel_mod, ONLY : roms_finalize
#if defined PIO_LIB && defined DISTRIBUTE
      USE set_pio_mod,     ONLY : finalize_pio
#endif
!
      implicit none
!
!  Local variable declarations.
!
      logical, save :: first
 
      integer :: ng, myerror, provided, required
 
#ifdef DISTRIBUTE
# ifdef MPI
!
!-----------------------------------------------------------------------
!  Initialize distributed-memory MPI configuration.
!-----------------------------------------------------------------------
!
#  ifdef MULTI_THREAD
      required=mpi_thread_multiple
      CALL mpi_init_thread (required, provided, myerror)
      IF (myerror.ne.0) THEN
        print '(/,a)',' ROMS: Unable to initialize multi-threaded MPI'
        exit_flag=6
      END IF
#  else
      CALL mpi_init (myerror)
      IF (myerror.ne.0) THEN
        print '(/,a)',' ROMS: Unable to initialize MPI'
        exit_flag=6
      END IF
#  endif
!
!  Get rank of the local process in the group associated with the
!  comunicator.
!
      CALL mpi_comm_rank (mpi_comm_world, myrank, myerror)
      IF (myerror.ne.0) THEN
        print '(/,a)',' ROMS: Unable to inquire rank of local processor'
        exit_flag=6
      END IF
# endif
#endif
!
!-----------------------------------------------------------------------
!  Initialize ocean internal and external parameters and state
!  variables for all nested grids, if applicable.
!-----------------------------------------------------------------------
!
      IF (exit_flag.eq.noerror) THEN
        first=.true.
        CALL roms_initialize (first)
      END IF
!
!-----------------------------------------------------------------------
!  Time-step ocean model over all nested grids, if applicable, by the
!  specified time interval in seconds.
!-----------------------------------------------------------------------
!
      IF (exit_flag.eq.noerror) THEN
        run_time=0.0_r8
        DO ng=1,ngrids
          run_time=max(run_time, dt(ng)*ntimes(ng))
        END DO
        CALL roms_run (run_time)
      END IF
!
!-----------------------------------------------------------------------
!  Terminate ocean model execution: flush and close all IO files.
!-----------------------------------------------------------------------
!
      CALL roms_finalize
#if defined PIO_LIB && defined DISTRIBUTE
      CALL finalize_pio
#endif
      CALL roms_deallocate_arrays
#if defined DISTRIBUTE && defined MPI
      CALL mpi_finalize (myerror)
#endif
!
!-----------------------------------------------------------------------
!  If error, issue abort signal. It is expected that the Unix or POSIX
!  environment should handle this as a return errorcode from the ROMS
!  main to abort. It facilitates error handling in scripting.
!-----------------------------------------------------------------------
!
!!    IF ((exit_flag.ne.NoError).or.(blowup.ne.0)) STOP 911   ! F-2003
      IF ((exit_flag.ne.noerror).or.(blowup.ne.0)) error stop ! F-2008
!
      END PROGRAM myroms