propagator_so.h

Go to the documentation of this file.

      MODULE propagator_mod
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group            Andrew M. Moore   !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  Stochastic Optimals Propagator for white noise forcing.             !
!                                                                      !
!   Reference:                                                         !
!                                                                      !
!     Moore, A.M. et al., 2004: A comprehensive ocean prediction and   !
!       analysis system based on the tangent linear and adjoint of a   !
!       regional ocean model, Ocean Modelling, 7, 227-258.             !
!                                                                      !
!=======================================================================
!
      USE mod_kinds
!
      implicit none
!
      PRIVATE
      PUBLIC  :: propagator_so
!
      CONTAINS
!
!***********************************************************************
      SUBROUTINE propagator_so (RunInterval, Iter, state, ad_state)
!***********************************************************************
!
      USE mod_param
      USE mod_parallel
      USE mod_netcdf
#ifdef SOLVE3D
      USE mod_coupling
#endif
      USE mod_iounits
      USE mod_ocean
      USE mod_scalars
      USE mod_stepping
!
      USE close_io_mod,   ONLY : close_inp
      USE dotproduct_mod, ONLY : tl_statenorm
      USE ini_adjust_mod, ONLY : ad_ini_perturb
      USE mod_forces,     ONLY : initialize_forces
#ifdef STOCH_OPT_WHITE
      USE packing_mod,    ONLY : ad_so_pack, tl_unpack
#else
      USE packing_mod,    ONLY : ad_so_pack_red, tl_unpack
#endif
#ifdef SOLVE3D
      USE set_depth_mod,  ONLY : set_depth
#endif
      USE strings_mod,    ONLY : founderror
!
!  Imported variable declarations.
!
      integer :: iter
!
      real(dp), intent(in) :: runinterval
!
      TYPE (t_gst), intent(in) :: state(ngrids)
      TYPE (t_gst), intent(inout) :: ad_state(ngrids)
!
!  Local variable declarations.
!
      logical :: soruntl
#ifdef STOCH_OPT_WHITE
      logical :: sorunad
#endif
!
      integer :: ng, tile
      integer :: ktmp, ntmp
      integer :: kout, nout
      integer :: fcount, interval, inttrap
!
      real(r8) :: statenorm(ngrids)
      real(r8) :: so_run_time
!
      character (len=*), parameter :: myfile =                          &
     &  __FILE__
!
!=======================================================================
!  Forward integration of the tangent linear model.
!=======================================================================
!
      nrun=nrun+1
      IF (master) THEN
        DO ng=1,ngrids
          WRITE (stdout,10) ' PROPAGATOR - Grid: ', ng,                 &
     &                      ',  Iteration: ', nrun,                     &
     &                      ',  number converged RITZ values: ',        &
     &                      nconv(ng)
        END DO
      END IF
!
!  Loop over the required numger if trapezoidal intervals in time.
!
      interval_loop : DO interval=1,nintervals+1
 
        soruntl=.true.
#ifdef STOCH_OPT_WHITE
        sorunad=.true.
#endif
        IF (interval.eq.nintervals+1) THEN
          soruntl=.false.
#ifdef STOCH_OPT_WHITE
          sorunad=.false.
#endif
        END IF
        inttrap=interval
!
        IF (master) THEN
          WRITE (stdout,20) ' Stochastic Optimals Time Interval = ',    &
     &                      interval
        END IF
!
!  Initialize time stepping indices and counters.
!
        DO ng=1,ngrids
#ifndef STOCH_OPT_WHITE
          IF (interval.eq.1) THEN
            soinitial(ng)=.true.
          ELSE
            soinitial(ng)=.false.
          END IF
#endif
          IF (interval.eq.1) THEN
            lwrttlm(ng)=.true.
          ELSE
            lwrttlm(ng)=.false.
          END IF
          iif(ng)=1
          indx1(ng)=1
          kstp(ng)=1
          krhs(ng)=1
          knew(ng)=1
          predictor_2d_step(ng)=.false.
!
          iic(ng)=0
          nstp(ng)=1
          nrhs(ng)=1
          nnew(ng)=1
!
          synchro_flag(ng)=.true.
          tdays(ng)=dstart+real(ntimes(ng),r8)*real(interval-1,r8)*     &
     &                     dt(ng)*sec2day/real(nintervals,r8)
          time(ng)=tdays(ng)*day2sec
          ntstart(ng)=int((time(ng)-dstart*day2sec)/dt(ng))+1
          ntend(ng)=ntimes(ng)
          ntfirst(ng)=ntstart(ng)
          so_run_time=dt(ng)*real(ntend(ng)-ntstart(ng)+1,r8)
        END DO
!
!  Set switches and counters to manage output adjoint and tangent linear
!  history NetCDF files.
!
        DO ng=1,ngrids
          IF (iter.gt.0) THEN                ! Arnoldi iteration loop
            IF ((iter.eq.1).and.(interval.eq.1)) THEN
              ldefadj(ng)=.true.
              ldeftlm(ng)=.true.             ! NetCDF files are created
            ELSE                             ! on the first pass
              ldefadj(ng)=.false.
              ldeftlm(ng)=.false.
            END IF
            fcount=adm(ng)%load
            adm(ng)%Nrec(fcount)=0
            adm(ng)%Rindex=0
            fcount=tlm(ng)%load
            tlm(ng)%Nrec(fcount)=0
            tlm(ng)%Rindex=0
          ELSE                               ! Computing eigenvectors
            IF (lmultigst.and.(interval.eq.1)) THEN
              ldeftlm(ng)=.true.
            ELSE
              ldeftlm(ng)=.false.
            END IF
#ifdef STOCH_OPT_WHITE
            IF (interval.le.nintervals) THEN
              fcount=adm(ng)%load
              adm(ng)%Nrec(fcount)=0
              adm(ng)%Rindex=0
            END IF
#else
            fcount=adm(ng)%load
            adm(ng)%Nrec(fcount)=0
            adm(ng)%Rindex=0
#endif
            IF ((lmultigst.or.(abs(iter).eq.1)).and.                    &
     &          (interval.eq.1)) THEN
              fcount=tlm(ng)%load
              tlm(ng)%Nrec(fcount)=0
              tlm(ng)%Rindex=0
            END IF
          END IF
        END DO
!
!-----------------------------------------------------------------------
!  Clear tangent linear state variables. There is not need to clean
!  the basic state arrays since they were zeroth out at initialization
!  and bottom of previous iteration.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL initialize_ocean (ng, tile, itlm)
          END DO
        END DO
 
#ifdef SOLVE3D
!
!-----------------------------------------------------------------------
!  Compute basic state initial level thicknesses used for state norm
!  scaling. It uses zero time-averaged free-surface (rest state).
!  Therefore, the norm scaling is time invariant.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=last_tile(ng),first_tile(ng),-1
            CALL set_depth (ng, tile, itlm)
          END DO
        END DO
#endif
!
!-----------------------------------------------------------------------
!  Unpack tangent linear initial conditions from state vector.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL tl_unpack (ng, tile, nstr(ng), nend(ng),               &
     &                      state(ng)%vector)
          END DO
        END DO
!
!-----------------------------------------------------------------------
!  Compute initial tangent linear state dot product norm.
!-----------------------------------------------------------------------
!
        IF (interval.eq.nintervals+1) THEN
          DO ng=1,ngrids
            DO tile=last_tile(ng),first_tile(ng),-1
              CALL tl_statenorm (ng, tile, kstp(ng), nstp(ng),          &
     &                           statenorm(ng))
            END DO
            IF (master) THEN
              WRITE (stdout,30) ' PROPAGATOR - Grid: ', ng,             &
     &                          ',  Tangent Initial Norm: ',            &
     &                          statenorm(ng)
            END IF
          END DO
        END IF
!
!-----------------------------------------------------------------------
!  Read in initial forcing, climatology and assimilation data from
!  input NetCDF files.  It loads the first relevant data record for
!  the time-interpolation between snapshots.
!-----------------------------------------------------------------------
!
        IF (soruntl) THEN              ! do not run TLM on last interval
          DO ng=1,ngrids
            CALL close_inp (ng, itlm)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
            CALL tl_get_idata (ng)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
            CALL tl_get_data (ng)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END DO
!
!-----------------------------------------------------------------------
!  Time-step the tangent linear model.
!-----------------------------------------------------------------------
!
          DO ng=1,ngrids
            IF (master) THEN
              WRITE (stdout,40) 'TL', ng, ntstart(ng), ntend(ng)
            END IF
            time(ng)=time(ng)-dt(ng)
            iic(ng)=ntstart(ng)-1
          END DO
 
#ifdef SOLVE3D
          CALL tl_main3d (so_run_time)
#else
          CALL tl_main2d (so_run_time)
#endif
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
!
!-----------------------------------------------------------------------
!  Clear nonlinear (basic state) and adjoint state variables.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL initialize_ocean (ng, tile, inlm)
            CALL initialize_ocean (ng, tile, iadm)
#ifdef SOLVE3D
            CALL initialize_coupling (ng, tile, 0)
#endif
          END DO
        END DO
 
#ifdef SOLVE3D
!
!-----------------------------------------------------------------------
!  Compute basic state final level thicknesses used for state norm
!  scaling. It uses zero time-averaged free-surface (rest state).
!  Therefore, the norm scaling is time invariant.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=last_tile(ng),first_tile(ng),-1
            CALL set_depth (ng, tile, itlm)
          END DO
        END DO
#endif
!
!-----------------------------------------------------------------------
!  Compute final tangent linear state dot product norm.
!-----------------------------------------------------------------------
!
        IF (interval.eq.nintervals+1) THEN
          DO ng=1,ngrids
            DO tile=first_tile(ng),last_tile(ng),+1
              CALL tl_statenorm (ng, tile, kstp(ng), nstp(ng),          &
     &                           statenorm(ng))
            END DO
            IF (master) THEN
              WRITE (stdout,30) ' PROPAGATOR - Grid: ', ng,             &
     &                          ',  Tangent   Final Norm: ',            &
     &                          statenorm(ng)
            END IF
          END DO
        END IF
!
!=======================================================================
!  Backward integration with the adjoint model.
!=======================================================================
!
!  Initialize time stepping indices and counters.
!
        DO ng=1,ngrids
#ifndef STOCH_OPT_WHITE
          lwrtstate2d(ng)=.false.
          lwrtstate3d(ng)=.false.
#endif
          iif(ng)=1
          indx1(ng)=1
          ktmp=knew(ng)
          IF (inttrap.eq.nintervals+1) THEN
            ktmp=kstp(ng)
          END IF
          kstp(ng)=1
          krhs(ng)=3
          knew(ng)=2
          kout=knew(ng)
#ifdef STOCH_OPT_WHITE
          IF (inttrap.eq.nintervals+1) THEN
            kout=kstp(ng)
          END IF
#endif
          predictor_2d_step(ng)=.false.
!
          iic(ng)=0
          ntmp=nstp(ng)
          nstp(ng)=1
          nrhs(ng)=1
          nnew(ng)=2
!
          synchro_flag(ng)=.true.
          tdays(ng)=dstart+dt(ng)*real(ntimes(ng),r8)*sec2day
          time(ng)=tdays(ng)*day2sec
          ntstart(ng)=ntimes(ng)+1
# ifdef STOCH_OPT_WHITE
          ntend(ng)=1+(interval-1)*ntimes(ng)/nintervals
# else
          ntend(ng)=1
# endif
          ntfirst(ng)=ntend(ng)
        END DO
!
!-----------------------------------------------------------------------
!  Initialize adjoint model with the final tangent linear solution
!  scaled by the energy norm.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=last_tile(ng),first_tile(ng),-1
            CALL ad_ini_perturb (ng, tile,                              &
     &                           ktmp, kout, ntmp, nstp(ng))
          END DO
        END DO
!
!-----------------------------------------------------------------------
!  Read in initial forcing, climatology and assimilation data from
!  input NetCDF files.  It loads the first relevant data record for
!  the time-interpolation between snapshots.
!-----------------------------------------------------------------------
!
#ifdef STOCH_OPT_WHITE
        IF (sorunad) THEN              ! do not run ADM on last interval
#endif
          DO ng=1,ngrids
            CALL close_inp (ng, iadm)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
            CALL ad_get_idata (ng)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
            CALL ad_get_data (ng)
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END DO
!
!-----------------------------------------------------------------------
!  Time-step the adjoint model backwards.
!-----------------------------------------------------------------------
!
          DO ng=1,ngrids
            IF (master) THEN
              WRITE (stdout,40) 'AD', ng, ntstart(ng), ntend(ng)
            END IF
            time(ng)=time(ng)+dt(ng)
            iic(ng)=ntstart(ng)+1
          END DO
 
#ifdef SOLVE3D
# ifdef STOCH_OPT_WHITE
          CALL ad_main3d (so_run_time)
# else
          CALL ad_main3d (runinterval)
# endif
#else
# ifdef STOCH_OPT_WHITE
          CALL ad_main2d (so_run_time)
# else
          CALL ad_main2d (runinterval)
# endif
#endif
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#ifdef STOCH_OPT_WHITE
        END IF
#endif
!
!-----------------------------------------------------------------------
!  Clear nonlinear state (basic state) variables for next iteration
!  and to insure a rest state time averaged free-surface before adjoint
!  state norm scaling.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL initialize_ocean (ng, tile, inlm)
#ifdef SOLVE3D
            CALL initialize_coupling (ng, tile, 0)
#endif
          END DO
        END DO
 
#ifdef SOLVE3D
!
!-----------------------------------------------------------------------
!  Compute basic state initial level thicknesses used for state norm
!  scaling. It uses zero free-surface (rest state).  Therefore, the
!  norm scaling is time invariant.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=last_tile(ng),first_tile(ng),-1
            CALL set_depth (ng, tile, iadm)
          END DO
        END DO
#endif
!
!-----------------------------------------------------------------------
!  Pack final adjoint solution into adjoint state vector.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
# ifdef STOCH_OPT_WHITE
            CALL ad_so_pack (ng, tile, nstr(ng), nend(ng), inttrap,     &
     &                       ad_state(ng)%vector)
# else
            CALL ad_so_pack_red (ng, tile, nstr(ng), nend(ng),          &
     &                           inttrap, ad_state(ng)%vector)
# endif
          END DO
        END DO
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!-----------------------------------------------------------------------
!  Clear forcing variables for next iteration.
!-----------------------------------------------------------------------
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL initialize_forces (ng, tile, itlm)
            CALL initialize_forces (ng, tile, iadm)
          END DO
        END DO
 
      END DO interval_loop
!
 10   FORMAT (/,a,i2.2,a,i3.3,a,i3.3/)
 20   FORMAT (/,a,i2.2)
 30   FORMAT (/,a,i2.2,a,1p,e15.6,/)
 40   FORMAT (/,1x,a,1x,'ROMS: started time-stepping:',                 &
     &        ' (Grid: ',i2.2,' TimeSteps: ',i8.8,' - ',i8.8,')')
!
      RETURN
      END SUBROUTINE propagator_so
 
      END MODULE propagator_mod