pert_roms.h

Go to the documentation of this file.

      MODULE roms_kernel_mod
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group            Andrew M. Moore   !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  ROMS Tangent Linear and Adjoint Models Sanity Test:                 !
!                                                                      !
!  This driver is used to test the tangent linear model and adjoint    !
!  models for ROMS.  It is used to check whether or not both models    !
!  are correct. This driver is usually run in "ensemble" mode where    !
!  each member represents a perturbed interior point in the tangent    !
!  linear and adjoint models.  There is a maximum of Lm*Mm ensemble    !
!  members. Each member is ran for few time steps.                     !
!                                                                      !
!  If each interior point is perturbed at one time,  the  resulting    !
!  tangent linear (T) and adjoint (A) M-by-N matrices yield:           !
!                                                                      !
!                T - tranpose(A) = 0    within round off               !
!                                                                      !
!  That is, their inner product give a symmetric matrix. Here, M is    !
!  the number of state points and N is the number of perturbations.    !
!  This option is activated with the INNER_PRODUCT test.               !
!                                                                      !
!  In realistic applications, it is awkward to perturb all interior    !
!  points for each state variable. Alternatively, random check at a    !
!  specified point is inexpensive. This option is activate with the    !
!  SANITY_CHECK switch.  The standard input "User" array is used to    !
!  specify such point:                                                 !
!                                                                      !
!     INT(user(1)) => state tangent variable to perturb                !
!     INT(user(2)) => state adjoint variable to perturb                !
!     INT(user(3)) => I-index of tangent variable to perturb           !
!     INT(user(4)) => I-index of adjoint variable to perturb           !
!     INT(user(5)) => J-index of tangent variable to perturb           !
!     INT(user(6)) => J-index of adjoint variable to perturb           !
!                                                                      !
!  In 3D applications:                                                 !
!                                                                      !
!     INT(user(7)) => J-index of tangent variable to perturb           !
!     INT(user(8)) => J-index of adjoint variable to perturb           !
!                                                                      !
!  The subroutines in this driver control the initialization, time-    !
!  stepping,  and  finalization of  ROMS  model following ESMF         !
!  conventions:                                                        !
!                                                                      !
!     ROMS_initialize                                                  !
!     ROMS_run                                                         !
!     ROMS_finalize                                                    !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_arrays
      USE mod_iounits
      USE mod_ncparam
      USE mod_ocean
      USE mod_scalars
      USE mod_stepping
!
      USE close_io_mod,      ONLY : close_file, close_inp, close_out
#ifdef DISTRIBUTE
      USE distribute_mod,    ONLY : mp_collect
#endif
      USE inp_par_mod,       ONLY : inp_par
#ifdef MCT_LIB
# ifdef ATM_COUPLING
      USE mct_coupler_mod,   ONLY : initialize_ocn2atm_coupling
# endif
# ifdef WAV_COUPLING
      USE mct_coupler_mod,   ONLY : initialize_ocn2wav_coupling
# endif
#endif
      USE stdout_mod,        ONLY : set_stdoutunit, stdout_unit
      USE strings_mod,       ONLY : founderror
      USE wrt_rst_mod,       ONLY : wrt_rst
!
      implicit none
!
      PUBLIC :: roms_initialize
      PUBLIC :: roms_run
      PUBLIC :: roms_finalize
!
      CONTAINS
!
      SUBROUTINE roms_initialize (first, mpiCOMM)
!
!=======================================================================
!                                                                      !
!  This routine allocates and initializes ROMS state variables         !
!  and internal and external parameters.                               !
!                                                                      !
!=======================================================================
!
!  Imported variable declarations.
!
      logical, intent(inout) :: first
!
      integer, intent(in), optional :: mpiCOMM
!
!  Local variable declarations.
!
      logical :: allocate_vars = .true.
!
#ifdef DISTRIBUTE
      integer :: MyError, MySize
#endif
      integer :: chunk_size, ng, thread
#ifdef _OPENMP
      integer :: my_threadnum
#endif
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", ROMS_initialize"
 
#ifdef DISTRIBUTE
!
!-----------------------------------------------------------------------
!  Set distribute-memory (mpi) world communictor.
!-----------------------------------------------------------------------
!
      IF (PRESENT(mpicomm)) THEN
        ocn_comm_world=mpicomm
      ELSE
        ocn_comm_world=mpi_comm_world
      END IF
      CALL mpi_comm_rank (ocn_comm_world, myrank, myerror)
      CALL mpi_comm_size (ocn_comm_world, mysize, myerror)
#endif
!
!-----------------------------------------------------------------------
!  On first pass, initialize model parameters a variables for all
!  nested/composed grids.  Notice that the logical switch "first"
!  is used to allow multiple calls to this routine during ensemble
!  configurations.
!-----------------------------------------------------------------------
!
      IF (first) THEN
        first=.false.
!
!  Initialize parallel control switches. These scalars switches are
!  independent from standard input parameters.
!
        CALL initialize_parallel
!
!  Set the ROMS standard output unit to write verbose execution info.
!  Notice that the default standard out unit in Fortran is 6.
!
!  In some applications like coupling or disjointed mpi-communications,
!  it is advantageous to write standard output to a specific filename
!  instead of the default Fortran standard output unit 6. If that is
!  the case, it opens such formatted file for writing.
!
        IF (set_stdoutunit) THEN
          stdout=stdout_unit(master)
          set_stdoutunit=.false.
        END IF
!
!  Read in model tunable parameters from standard input. Allocate and
!  initialize variables in several modules after the number of nested
!  grids and dimension parameters are known.
!
        CALL inp_par (inlm)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Set domain decomposition tile partition range.  This range is
!  computed only once since the "first_tile" and "last_tile" values
!  are private for each parallel thread/node.
!
#if defined _OPENMP
      mythread=my_threadnum()
#elif defined DISTRIBUTE
      mythread=myrank
#else
      mythread=0
#endif
      DO ng=1,ngrids
        chunk_size=(ntilex(ng)*ntilee(ng)+numthreads-1)/numthreads
        first_tile(ng)=mythread*chunk_size
        last_tile(ng)=first_tile(ng)+chunk_size-1
      END DO
!
!  Initialize internal wall clocks. Notice that the timings does not
!  includes processing standard input because several parameters are
!  needed to allocate clock variables.
!
        IF (master) THEN
          WRITE (stdout,10)
 10       FORMAT (/,' Process Information:',/)
        END IF
!
        DO ng=1,ngrids
          DO thread=thread_range
            CALL wclock_on (ng, inlm, 0, __line__, myfile)
          END DO
        END DO
!
!  Allocate and initialize modules variables.
!
        CALL roms_allocate_arrays (allocate_vars)
        CALL roms_initialize_arrays
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
      END IF
 
#if defined MCT_LIB && (defined ATM_COUPLING || defined WAV_COUPLING)
!
!-----------------------------------------------------------------------
!  Initialize coupling streams between model(s).
!-----------------------------------------------------------------------
!
      DO ng=1,ngrids
# ifdef ATM_COUPLING
        CALL initialize_ocn2atm_coupling (ng, myrank)
# endif
# ifdef WAV_COUPLING
        CALL initialize_ocn2wav_coupling (ng, myrank)
# endif
      END DO
#endif
!
      RETURN
      END SUBROUTINE roms_initialize
!
      SUBROUTINE roms_run (RunInterval)
!
!=======================================================================
!                                                                      !
!  This routine time-steps ROMS tangent linear and adjoint             !
!  models.                                                             !
!                                                                      !
!=======================================================================
!
!  Imported variable declarations
!
      real(dp), intent(in) :: RunInterval            ! seconds
!
!  Local variable declarations.
!
      integer :: ng, tile
#ifdef SANITY_CHECK
      logical :: BOUNDED_AD, BOUNDED_TL, SAME_VAR
# ifdef DISTRIBUTE
      integer :: Istr, Iend, Jstr, Jend
# endif
      integer :: IperAD, JperAD, KperAD, ivarAD
      integer :: IperTL, JperTL, KperTL, ivarTL
      integer :: i
!
      real(r8) :: IniVal = 0.0_r8
 
      real(r8), dimension(4,Ngrids) :: val
#endif
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", ROMS_run"
!
!=======================================================================
!  Run model for all nested grids, if any.
!=======================================================================
!
#ifdef INNER_PRODUCT
!
!  Set end of pertubation loos as the total number of state variables
!  interior points. Is not possible to run the inner product test over
!  nested grids. If nested grids, run each grid separately.
!
      IF (ngrids.gt.1) THEN
        WRITE (stdout,10) 'Nested grids are not allowed, Ngrids = ',    &
                          ngrids
        stop
      END IF
      ng=1
# ifdef SOLVE3D
      erend=(lm(ng)-1)*mm(ng)+                                          &
     &       lm(ng)*(mm(ng)-1)+                                         &
     &       lm(ng)*mm(ng)+                                             &
     &       (lm(ng)-1)*mm(ng)*n(ng)+                                   &
     &       lm(ng)*(mm(ng)-1)*n(ng)+                                   &
     &       lm(ng)*mm(ng)*n(ng)*nat
# else
      erend=(lm(ng)-1)*mm(ng)+                                          &
     &       lm(ng)*(mm(ng)-1)+                                         &
     &       lm(ng)*mm(ng)
# endif
#endif
#ifdef SANITY_CHECK
!
!  Set tangent and adjoint variable and random point to perturb.
!
      ivartl=int(user(1))
      ivarad=int(user(2))
      ipertl=int(user(3))
      iperad=int(user(4))
      jpertl=int(user(5))
      jperad=int(user(6))
# ifdef SOLVE3D
      kpertl=int(user(7))
      kperad=int(user(8))
      same_var=(ivartl.eq.ivarad).and.                                  &
     &         (ipertl.eq.iperad).and.                                  &
     &         (jpertl.eq.jperad).and.                                  &
     &         (kpertl.eq.kperad)
# else
      same_var=(ivartl.eq.ivarad).and.                                  &
     &         (ipertl.eq.iperad).and.                                  &
     &         (jpertl.eq.jperad)
# endif
#endif
!
!  Set relevant IO switches.
!
      DO ng=1,ngrids
        IF (ntlm(ng).gt.0) ldeftlm(ng)=.true.
        IF (nadj(ng).gt.0) ldefadj(ng)=.true.
        lreadfwd(ng)=.true.
      END DO
      lstiffness=.false.
 
#ifdef FORWARD_FLUXES
!
!  Set the BLK structure to contain the nonlinear model surface fluxes
!  needed by the tangent linear and adjoint models. Also, set switches
!  to process that structure in routine "check_multifile". Notice that
!  it is possible to split the solution into multiple NetCDF files to
!  reduce their size.
!
!  The switch LreadFRC is deactivated because all the atmospheric
!  forcing, including shortwave radiation, is read from the NLM
!  surface fluxes or is assigned during ESM coupling.  Such fluxes
!  are available from the QCK structure. There is no need for reading
!  and processing from the FRC structure input forcing-files.
 
      CALL edit_multifile ('QCK2BLK')
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      DO ng=1,ngrids
        lreadblk(ng)=.true.
        lreadfrc(ng)=.false.
      END DO
#endif
!
!=======================================================================
!  Perturbation loop.
!=======================================================================
!
      pert_loop : DO nrun=erstr,erend
!
!-----------------------------------------------------------------------
!  Time step tangent linear model.
!-----------------------------------------------------------------------
!
        tlmodel=.true.
        admodel=.false.
        DO ng=1,ngrids
          CALL tl_initial (ng)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
          IF (master) THEN
            WRITE (stdout,10) 'TL', ng, ntstart(ng), ntend(ng)
          END IF
        END DO
!
#ifdef SOLVE3D
        CALL tl_main3d (runinterval)
#else
        CALL tl_main2d (runinterval)
#endif
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#ifdef SANITY_CHECK
!
!  Get check value for tangent linear state variable.
!
        DO ng=1,ngrids
# ifdef DISTRIBUTE
          istr=bounds(ng)%Istr(myrank)
          iend=bounds(ng)%Iend(myrank)
          jstr=bounds(ng)%Jstr(myrank)
          jend=bounds(ng)%Jend(myrank)
          bounded_tl=((istr.le.ipertl).and.(ipertl.le.iend)).and.       &
     &               ((jstr.le.jpertl).and.(jpertl.le.jend))
          bounded_ad=((istr.le.iperad).and.(iperad.le.iend)).and.       &
     &               ((jstr.le.jperad).and.(jperad.le.jend))
# else
          bounded_tl=.true.
          bounded_ad=.true.
# endif
          DO i=1,4
            val(i,ng)=inival
          END DO
          IF (bounded_tl) THEN
# ifdef SOLVE3D
            IF (ivartl.eq.isubar) THEN
              val(1,ng)=ocean(ng)%tl_ubar(ipertl,jpertl,knew(ng))
            ELSE IF (ivartl.eq.isvbar) THEN
              val(1,ng)=ocean(ng)%tl_vbar(ipertl,jpertl,knew(ng))
            ELSE IF (ivartl.eq.isfsur) THEN
              val(1,ng)=ocean(ng)%tl_zeta(ipertl,jpertl,knew(ng))
            ELSE IF (ivartl.eq.isuvel) THEN
              val(1,ng)=ocean(ng)%tl_u(ipertl,jpertl,kpertl,nstp(ng))
            ELSE IF (ivartl.eq.isvvel) THEN
              val(1,ng)=ocean(ng)%tl_v(ipertl,jpertl,kpertl,nstp(ng))
            ELSE
              DO i=1,nt(ng)
                IF (ivartl.eq.istvar(i)) THEN
                  val(1,ng)=ocean(ng)%tl_t(ipertl,jpertl,kpertl,        &
     &                                     nstp(ng),i)
                END IF
              END DO
            END IF
# else
            IF (ivartl.eq.isubar) THEN
              val(1,ng)=ocean(ng)%tl_ubar(ipertl,jpertl,knew(ng))
            ELSE IF (ivartl.eq.isvbar) THEN
              val(1,ng)=ocean(ng)%tl_vbar(ipertl,jpertl,knew(ng))
            ELSE IF (ivartl.eq.isfsur) THEN
              val(1,ng)=ocean(ng)%tl_zeta(ipertl,jpertl,knew(ng))
            END IF
# endif
          END IF
 
          IF (bounded_ad) THEN
# ifdef SOLVE3D
            IF (ivarad.eq.isubar) THEN
              val(3,ng)=ocean(ng)%tl_ubar(iperad,jperad,knew(ng))
            ELSE IF (ivarad.eq.isvbar) THEN
              val(3,ng)=ocean(ng)%tl_vbar(iperad,jperad,knew(ng))
            ELSE IF (ivarad.eq.isfsur) THEN
              val(3,ng)=ocean(ng)%tl_zeta(iperad,jperad,knew(ng))
            ELSE IF (ivarad.eq.isuvel) THEN
              val(3,ng)=ocean(ng)%tl_u(iperad,jperad,kperad,nstp(ng))
            ELSE IF (ivarad.eq.isvvel) THEN
              val(3,ng)=ocean(ng)%tl_v(iperad,jperad,kperad,nstp(ng))
            ELSE
              DO i=1,nt(ng)
                IF (ivarad.eq.istvar(i)) THEN
                  val(3,ng)=ocean(ng)%tl_t(iperad,jperad,kperad,        &
     &                                     nstp(ng),i)
                END IF
              END DO
            END IF
# else
            IF (ivarad.eq.isubar) THEN
              val(3,ng)=ocean(ng)%tl_ubar(iperad,jperad,knew(ng))
            ELSE IF (ivarad.eq.isvbar) THEN
              val(3,ng)=ocean(ng)%tl_vbar(iperad,jperad,knew(ng))
            ELSE IF (ivarad.eq.isfsur) THEN
              val(3,ng)=ocean(ng)%tl_zeta(iperad,jperad,knew(ng))
            END IF
# endif
          END IF
        END DO
#endif
!
!  Clear all model state arrays arrays.
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL initialize_ocean (ng, tile, 0)
          END DO
        END DO
!
!-----------------------------------------------------------------------
!  Time step adjoint model backwards.
!-----------------------------------------------------------------------
!
        tlmodel=.false.
        admodel=.true.
        DO ng=1,ngrids
          CALL ad_initial (ng)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
          IF (master) THEN
            WRITE (stdout,10) 'AD', ng, ntstart(ng), ntend(ng)
          END IF
        END DO
!
#ifdef SOLVE3D
        CALL ad_main3d (runinterval)
#else
        CALL ad_main2d (runinterval)
#endif
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#ifdef SANITY_CHECK
!
!  Get check value for adjoint state variable.
!
        DO ng=1,ngrids
# ifdef DISTRIBUTE
          istr=bounds(ng)%Istr(myrank)
          iend=bounds(ng)%Iend(myrank)
          jstr=bounds(ng)%Jstr(myrank)
          jend=bounds(ng)%Jend(myrank)
          bounded_ad=((istr.le.iperad).and.(iperad.le.iend)).and.       &
     &               ((jstr.le.jperad).and.(jperad.le.jend))
          bounded_tl=((istr.le.ipertl).and.(ipertl.le.iend)).and.       &
     &               ((jstr.le.jpertl).and.(jpertl.le.jend))
# else
          bounded_ad=.true.
          bounded_tl=.true.
# endif
          IF (bounded_ad) THEN
# ifdef SOLVE3D
            IF (ivarad.eq.isubar) THEN
              val(2,ng)=ocean(ng)%ad_ubar(iperad,jperad,kstp(ng))
            ELSE IF (ivarad.eq.isvbar) THEN
              val(2,ng)=ocean(ng)%ad_vbar(iperad,jperad,kstp(ng))
            ELSE IF (ivarad.eq.isfsur) THEN
              val(2,ng)=ocean(ng)%ad_zeta(iperad,jperad,kstp(ng))
            ELSE IF (ivarad.eq.isuvel) THEN
              val(2,ng)=ocean(ng)%ad_u(iperad,jperad,kperad,nstp(ng))
            ELSE IF (ivarad.eq.isvvel) THEN
              val(2,ng)=ocean(ng)%ad_v(iperad,jperad,kperad,nstp(ng))
            ELSE
              DO i=1,nt(ng)
                IF (ivarad.eq.istvar(i)) THEN
                  val(2,ng)=ocean(ng)%ad_t(iperad,jperad,kperad,        &
     &                                     nstp(ng),i)
                END IF
              END DO
            END IF
# else
            IF (ivarad.eq.isubar) THEN
              val(2,ng)=ocean(ng)%ad_ubar(iperad,jperad,kstp(ng))
            ELSE IF (ivarad.eq.isvbar) THEN
              val(2,ng)=ocean(ng)%ad_vbar(iperad,jperad,kstp(ng))
            ELSE IF (ivarad.eq.isfsur) THEN
              val(2,ng)=ocean(ng)%ad_zeta(iperad,jperad,kstp(ng))
            END IF
# endif
          END IF
 
          IF (bounded_tl) THEN
# ifdef SOLVE3D
            IF (ivartl.eq.isubar) THEN
              val(4,ng)=ocean(ng)%ad_ubar(ipertl,jpertl,kstp(ng))
            ELSE IF (ivartl.eq.isvbar) THEN
              val(4,ng)=ocean(ng)%ad_vbar(ipertl,jpertl,kstp(ng))
            ELSE IF (ivartl.eq.isfsur) THEN
              val(4,ng)=ocean(ng)%ad_zeta(ipertl,jpertl,kstp(ng))
            ELSE IF (ivartl.eq.isuvel) THEN
              val(4,ng)=ocean(ng)%ad_u(ipertl,jpertl,kpertl,nstp(ng))
            ELSE IF (ivartl.eq.isvvel) THEN
              val(4,ng)=ocean(ng)%ad_v(ipertl,jpertl,kpertl,nstp(ng))
            ELSE
              DO i=1,nt(ng)
                IF (ivartl.eq.istvar(i)) THEN
                  val(4,ng)=ocean(ng)%ad_t(ipertl,jpertl,kpertl,        &
     &                                     nstp(ng),i)
                END IF
              END DO
            END IF
# else
            IF (ivartl.eq.isubar) THEN
              val(4,ng)=ocean(ng)%ad_ubar(ipertl,jpertl,kstp(ng))
            ELSE IF (ivartl.eq.isvbar) THEN
              val(4,ng)=ocean(ng)%ad_vbar(ipertl,jpertl,kstp(ng))
            ELSE IF (ivartl.eq.isfsur) THEN
              val(4,ng)=ocean(ng)%ad_zeta(ipertl,jpertl,kstp(ng))
            END IF
# endif
          END IF
!
!  Report sanity check values.
!
# ifdef DISTRIBUTE
          CALL mp_collect (ng, itlm, 4, inival, val(:,ng))
# endif
          IF (master) THEN
            IF (same_var) THEN
              WRITE (stdout,20) 'Perturbing',                           &
     &                          trim(vname(1,idsvar(ivartl)))
              IF (ivartl.le.3) THEN
                WRITE (stdout,30) 'Tangent:    ', val(1,ng),            &
     &                                            ipertl,jpertl
                WRITE (stdout,30) 'Adjoint:    ', val(2,ng),            &
     &                                            iperad, jperad
                WRITE (stdout,30) 'Difference: ', val(2,ng)-val(1,ng),  &
     &                                            ipertl,jpertl
              ELSE
                WRITE (stdout,40) 'Tangent:    ', val(1,ng),            &
     &                                            ipertl,jpertl,kpertl
                WRITE (stdout,40) 'Adjoint:    ', val(2,ng),            &
     &                                            iperad,jperad,kperad
                WRITE (stdout,40) 'Difference: ', val(2,ng)-val(1,ng),  &
     &                                            ipertl,jpertl,kpertl
              END IF
            ELSE
              IF (ivartl.le.3) THEN
                WRITE (stdout,50) 'Tangent, Perturbing: ',              &
     &                            trim(vname(1,idsvar(ivartl))),        &
     &                            ipertl,jpertl
                WRITE (stdout,60) trim(vname(1,idsvar(ivartl))),        &
     &                            val(1,ng),ipertl,jpertl
              ELSE
                WRITE (stdout,70) 'Tangent, Perturbing: ',              &
     &                            trim(vname(1,idsvar(ivartl))),        &
     &                            ipertl,jpertl,kpertl
                WRITE (stdout,80) trim(vname(1,idsvar(ivartl))),        &
     &                            val(1,ng),ipertl,jpertl,kpertl
              END IF
              IF (ivarad.le.3) THEN
                WRITE (stdout,60) trim(vname(1,idsvar(ivarad))),        &
     &                            val(3,ng),iperad,jperad
              ELSE
                WRITE (stdout,80) trim(vname(1,idsvar(ivarad))),        &
     &                            val(3,ng),iperad,jperad,kperad
              END IF
!
              IF (ivarad.le.3) THEN
                WRITE (stdout,50) 'Adjoint, Perturbing: ',              &
     &                            trim(vname(1,idsvar(ivarad))),        &
     &                            iperad,jperad
                WRITE (stdout,60) trim(vname(1,idsvar(ivarad))),        &
     &                            val(2,ng),iperad,jperad
              ELSE
                WRITE (stdout,70) 'Adjoint, Perturbing: ',              &
     &                            trim(vname(1,idsvar(ivarad))),        &
     &                            iperad,jperad,kperad
                WRITE (stdout,80) trim(vname(1,idsvar(ivarad))),        &
     &                            val(2,ng),iperad,jperad,kperad
              END IF
              IF (ivartl.le.3) THEN
                WRITE (stdout,60) trim(vname(1,idsvar(ivartl))),        &
     &                            val(4,ng),ipertl,jpertl
              ELSE
                WRITE (stdout,80) trim(vname(1,idsvar(ivartl))),        &
     &                            val(4,ng),ipertl,jpertl,kpertl
              END IF
              WRITE (stdout,90) val(3,ng)-val(4,ng)
            END IF
          END IF
        END DO
#endif
!
!  Clear model state arrays arrays.
!
        DO ng=1,ngrids
          DO tile=first_tile(ng),last_tile(ng),+1
            CALL initialize_ocean (ng, tile, 0)
          END DO
        END DO
!
!  Close current forward NetCDF file.
!
        sourcefile=myfile
        DO ng=1,ngrids
          CALL close_file (ng, itlm, fwd(ng), fwd(ng)%name)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END DO
 
      END DO pert_loop
!
 10   FORMAT (/,1x,a,1x,'ROMS: started time-stepping:',                 &
     &        ' (Grid: ',i2.2,' TimeSteps: ',i8.8,' - ',i8.8,')',/)
#ifdef SANITY_CHECK
 20   FORMAT (/,' Sanity Check - ',a,' variable: ',a,t60)
 30   FORMAT (' Sanity Check - ', a, 1p,e19.12,                         &
     &        3x, 'at (i,j)   ',2i4)
 40   FORMAT (' Sanity Check - ', a, 1p,e19.12,                         &
     &        3x, 'at (i,j,k) ',3i4)
 50   FORMAT (/,' Sanity Check - ',a, a, t52, 'at (i,j)   ', 2i4)
 60   FORMAT (' Sanity Check - ', a, ' =', t30, 1p,e19.12,              &
     &        t52, 'at (i,j)   ',2i4)
 70   FORMAT (/,' Sanity Check - ',a, a, t52, 'at (i,j,k) ', 3i4)
 80   FORMAT (' Sanity Check - ', a, ' =', t30, 1p,e19.12,              &
     &        t52, 'at (i,j,k) ',3i4)
 90   FORMAT (/,' Sanity Check - Difference = ', 1p,e19.12)
#endif
!
      RETURN
      END SUBROUTINE roms_run
!
      SUBROUTINE roms_finalize
!
!=======================================================================
!                                                                      !
!  This routine terminates ROMS tangent linear and adjoint             !
!  models execution.                                                   !
!                                                                      !
!=======================================================================
!
!  Local variable declarations.
!
      integer :: Fcount, ng, thread
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", ROMS_finalize"
!
!-----------------------------------------------------------------------
!  If blowing-up, save latest model state into RESTART NetCDF file.
!-----------------------------------------------------------------------
!
!  If cycling restart records, write solution into the next record.
!
      IF (exit_flag.eq.1) THEN
        DO ng=1,ngrids
          IF (lwrtrst(ng)) THEN
            IF (master) WRITE (stdout,10)
 10         FORMAT (/,' Blowing-up: Saving latest model state into ',   &
     &                ' RESTART file',/)
            fcount=rst(ng)%load
            IF (lcyclerst(ng).and.(rst(ng)%Nrec(fcount).ge.2)) THEN
              rst(ng)%Rindex=2
              lcyclerst(ng)=.false.
            END IF
            blowup=exit_flag
            exit_flag=noerror
#ifdef DISTRIBUTE
            CALL wrt_rst (ng, myrank)
#else
            CALL wrt_rst (ng, -1)
#endif
          END IF
        END DO
      END IF
!
!-----------------------------------------------------------------------
!  Stop model and time profiling clocks, report memory requirements, and
!  close output NetCDF files.
!-----------------------------------------------------------------------
!
!  Stop time clocks.
!
      IF (master) THEN
        WRITE (stdout,20)
 20     FORMAT (/,'Elapsed wall CPU time for each process (seconds):',/)
      END IF
!
      DO ng=1,ngrids
        DO thread=thread_range
          CALL wclock_off (ng, inlm, 0, __line__, myfile)
        END DO
      END DO
!
!  Report dynamic memory and automatic memory requirements.
!
      CALL memory
!
!  Close IO files.
!
      DO ng=1,ngrids
        CALL close_inp (ng, inlm)
      END DO
      CALL close_out
!
      RETURN
      END SUBROUTINE roms_finalize
 
      END MODULE roms_kernel_mod