nemuro.h

Go to the documentation of this file.

      MODULE biology_mod
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  Nemuro Lower Trophic Level Ecosystem Model.                         !
!                                                                      !
!  This routine computes the biological sources and sinks and adds     !
!  then the global biological fields. Currently, the ecosystem has     !
!  the following functional compartments:                              !
!                                                                      !
!    iSphy     small phytoplankton biomass, nanophytoplankton          !
!    iLphy     large phytoplankton biomass, diatoms                    !
!    iSzoo     small zooplankton biomass, microzooplankton (ciliates)  !
!    iLzoo     large zooplankton biomass, mesozooplankton (copepods)   !
!    iPzoo     predator zooplankton biomass (euphausiids, etc)         !
!    iNO3_     nitrate concentration, NO3                              !
!    iNH4_     ammonium concentration, NH4                             !
!    iPON_     particulate organic nitrogen                            !
!    iDON_     dissolved organic nitrogen                              !
!    iSiOH     silicate concentration, Si(OH)4 (silicic acid)          !
!    iopal     particulate organic silica                              !
!                                                                      !
!  Reference:                                                          !
!                                                                      !
!    Kishi, M. J., et  all, 2007: Nemuro - a lower trophic level       !
!      model for the North Pacific marine ecosystem,  Ecological       !
!      Modelling, 202, 12-25.                                          !
!                                                                      !
!=======================================================================
!
      implicit none
!
      PRIVATE
      PUBLIC  :: biology
!
      CONTAINS
!
!***********************************************************************
      SUBROUTINE biology (ng,tile)
!***********************************************************************
!
      USE mod_param
      USE mod_forces
      USE mod_grid
      USE mod_ncparam
      USE mod_ocean
      USE mod_stepping
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile
!
!  Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
#include "tile.h"
!
!  Set header file name.
!
#ifdef DISTRIBUTE
      IF (lbiofile(inlm)) THEN
#else
      IF (lbiofile(inlm).and.(tile.eq.0)) THEN
#endif
        lbiofile(inlm)=.false.
        bioname(inlm)=myfile
      END IF
!
#ifdef PROFILE
      CALL wclock_on (ng, inlm, 15, __line__, myfile)
#endif
      CALL nemuro_tile (ng, tile,                                       &
     &                  lbi, ubi, lbj, ubj, n(ng), nt(ng),              &
     &                  imins, imaxs, jmins, jmaxs,                     &
     &                  nstp(ng), nnew(ng),                             &
#ifdef MASKING
     &                  grid(ng) % rmask,                               &
#endif
     &                  grid(ng) % Hz,                                  &
     &                  grid(ng) % z_r,                                 &
     &                  grid(ng) % z_w,                                 &
     &                  forces(ng) % srflx,                             &
     &                  ocean(ng) % t)
 
#ifdef PROFILE
      CALL wclock_off (ng, inlm, 15, __line__, myfile)
#endif
!
      RETURN
      END SUBROUTINE biology
!
!-----------------------------------------------------------------------
      SUBROUTINE nemuro_tile (ng, tile,                                 &
     &                        LBi, UBi, LBj, UBj, UBk, UBt,             &
     &                        IminS, ImaxS, JminS, JmaxS,               &
     &                        nstp, nnew,                               &
#ifdef MASKING
     &                        rmask,                                    &
#endif
     &                        Hz, z_r, z_w,                             &
     &                        srflx,                                    &
     &                        t)
!-----------------------------------------------------------------------
!
      USE mod_param
      USE mod_biology
      USE mod_ncparam
      USE mod_scalars
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile
      integer, intent(in) :: LBi, UBi, LBj, UBj, UBk, UBt
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
      integer, intent(in) :: nstp, nnew
 
#ifdef ASSUMED_SHAPE
# ifdef MASKING
      real(r8), intent(in) :: rmask(LBi:,LBj:)
# endif
      real(r8), intent(in) :: Hz(LBi:,LBj:,:)
      real(r8), intent(in) :: z_r(LBi:,LBj:,:)
      real(r8), intent(in) :: z_w(LBi:,LBj:,0:)
      real(r8), intent(in) :: srflx(LBi:,LBj:)
      real(r8), intent(inout) :: t(LBi:,LBj:,:,:,:)
#else
# ifdef MASKING
      real(r8), intent(in) :: rmask(LBi:UBi,LBj:UBj)
# endif
      real(r8), intent(in) :: Hz(LBi:UBi,LBj:UBj,UBk)
      real(r8), intent(in) :: z_r(LBi:UBi,LBj:UBj,UBk)
      real(r8), intent(in) :: z_w(LBi:UBi,LBj:UBj,0:UBk)
      real(r8), intent(in) :: srflx(LBi:UBi,LBj:UBj)
      real(r8), intent(inout) :: t(LBi:UBi,LBj:UBj,UBk,3,UBt)
#endif
!
!  Local variable declarations.
!
      integer, parameter :: Nsink = 2
 
      integer :: Iter, ibio, indx, isink, itime, itrc, iTrcMax
      integer :: i, j, k, ks
 
      integer, dimension(Nsink) :: idsink
 
      real(r8), parameter :: MinVal = 1.0e-6_r8
 
      real(r8) :: AttL, AttS, IrrL, IrrS, KappaL, KappaS
      real(r8) :: dtdays, dz
      real(r8) :: GppAPS, GppAPL, GppNPS, GppNPL, GppPS, GppPL
      real(r8) :: GraPL2ZL, GraPL2ZP, GraPS2ZL, GraPS2ZS
      real(r8) :: GraZL2ZP, GraZS2ZL, GraZS2ZP
      real(r8) :: EgeZL, EgeZP, EgeZS
      real(r8) :: ExcPL, ExcPS, ExcZL, ExcZP, ExcZS
      real(r8) :: MorPL, MorPS
      real(r8) :: ResPL, ResPS
      real(r8) :: RnewL, RnewS
      real(r8) :: cff, cff1, cff2, cff3, cff4, cff5, cff6, cff7
      real(r8) :: fac, fac1, fac2, fac3, fac4, fac5, fac6, fac7
      real(r8) :: cffL, cffR, cu, dltL, dltR
 
      real(r8), dimension(Nsink) :: Wbio
 
      integer, dimension(IminS:ImaxS,N(ng)) :: ksource
 
      real(r8), dimension(IminS:ImaxS) :: PARsur
 
      real(r8), dimension(NT(ng),2) :: BioTrc
 
      real(r8), dimension(IminS:ImaxS,N(ng),NT(ng)) :: Bio
      real(r8), dimension(IminS:ImaxS,N(ng),NT(ng)) :: Bio_old
 
      real(r8), dimension(IminS:ImaxS,0:N(ng)) :: FC
 
      real(r8), dimension(IminS:ImaxS,N(ng)) :: Hz_inv
      real(r8), dimension(IminS:ImaxS,N(ng)) :: Hz_inv2
      real(r8), dimension(IminS:ImaxS,N(ng)) :: Hz_inv3
      real(r8), dimension(IminS:ImaxS,N(ng)) :: LightL
      real(r8), dimension(IminS:ImaxS,N(ng)) :: LightS
      real(r8), dimension(IminS:ImaxS,N(ng)) :: WL
      real(r8), dimension(IminS:ImaxS,N(ng)) :: WR
      real(r8), dimension(IminS:ImaxS,N(ng)) :: bL
      real(r8), dimension(IminS:ImaxS,N(ng)) :: bR
      real(r8), dimension(IminS:ImaxS,N(ng)) :: qc
 
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Add biological Source/Sink terms.
!-----------------------------------------------------------------------
!
!  Avoid computing source/sink terms if no biological iterations.
!
      IF (bioiter(ng).le.0) RETURN
!
!  Set time-stepping size (days) according to the number of iterations.
!
      dtdays=dt(ng)*sec2day/real(bioiter(ng),r8)
!
!  Set vertical sinking indentification vector.
!
      idsink(1)=ipon_                 ! particulate organic nitrogen
      idsink(2)=iopal                 ! particulate organic silica
!
!  Set vertical sinking velocity vector in the same order as the
!  identification vector, IDSINK.
!
      wbio(1)=setvpon(ng)             ! particulate organic nitrogen
      wbio(2)=setvopal(ng)            ! particulate organic silica
!
!  Compute inverse thickness to avoid repeated divisions.
!
      j_loop : DO j=jstr,jend
        DO k=1,n(ng)
          DO i=istr,iend
            hz_inv(i,k)=1.0_r8/hz(i,j,k)
          END DO
        END DO
        DO k=1,n(ng)-1
          DO i=istr,iend
            hz_inv2(i,k)=1.0_r8/(hz(i,j,k)+hz(i,j,k+1))
          END DO
        END DO
        DO k=2,n(ng)-1
          DO i=istr,iend
            hz_inv3(i,k)=1.0_r8/(hz(i,j,k-1)+hz(i,j,k)+hz(i,j,k+1))
          END DO
        END DO
!
!  Extract biological variables from tracer arrays, place them into
!  scratch arrays, and restrict their values to be positive definite.
!  At input, all tracers (index nnew) from predictor step have
!  transport units (m Tunits) since we do not have yet the new
!  values for zeta and Hz. These are known after the 2D barotropic
!  time-stepping.
!
        DO itrc=1,nbt
          ibio=idbio(itrc)
          DO k=1,n(ng)
            DO i=istr,iend
              bio_old(i,k,ibio)=max(0.0_r8,t(i,j,k,nstp,ibio))
              bio(i,k,ibio)=bio_old(i,k,ibio)
            END DO
          END DO
        END DO
!
!  Extract potential temperature and salinity.
!
        DO k=1,n(ng)
          DO i=istr,iend
            bio(i,k,itemp)=t(i,j,k,nstp,itemp)
          END DO
        END DO
!
!  Calculate surface Photosynthetically Available Radiation (PAR).  The
!  net shortwave radiation is scaled back to Watts/m2 and multiplied by
!  the fraction that is photosynthetically available, PARfrac.
!
        DO i=istr,iend
          parsur(i)=parfrac(ng)*srflx(i,j)*rho0*cp
        END DO
!
!=======================================================================
!  Start internal iterations to achieve convergence of the nonlinear
!  backward-implicit solution.
!=======================================================================
!
!  During the iterative procedure a series of fractional time steps are
!  performed in a chained mode (splitting by different biological
!  conversion processes) in sequence of the main food chain.  In all
!  stages the concentration of the component being consumed is treated
!  in a fully implicit manner, so the algorithm guarantees non-negative
!  values, no matter how strong the concentration of active consuming
!  component (Phytoplankton or Zooplankton).  The overall algorithm,
!  as well as any stage of it, is formulated in conservative form
!  (except explicit sinking) in sense that the sum of concentration of
!  all components is conserved.
!
!  In the implicit algorithm, we have for example (N: nutrient,
!                                                  P: phytoplankton),
!
!     N(new) = N(old) - uptake * P(old)     uptake = mu * N / (Kn + N)
!                                                    {Michaelis-Menten}
!  below, we set
!                                           The N in the numerator of
!     cff = mu * P(old) / (Kn + N(old))     uptake is treated implicitly
!                                           as N(new)
!
!  so the time-stepping of the equations becomes:
!
!     N(new) = N(old) / (1 + cff)     (1) when substracting a sink term,
!                                         consuming, divide by (1 + cff)
!  and
!
!     P(new) = P(old) + cff * N(new)  (2) when adding a source term,
!                                         growing, add (cff * source)
!
!  Notice that if you substitute (1) in (2), you will get:
!
!     P(new) = P(old) + cff * N(old) / (1 + cff)    (3)
!
!  If you add (1) and (3), you get
!
!     N(new) + P(new) = N(old) + P(old)
!
!  implying conservation regardless how "cff" is computed. Therefore,
!  this scheme is unconditionally stable regardless of the conversion
!  rate. It does not generate negative values since the constituent
!  to be consumed is always treated implicitly. It is also biased
!  toward damping oscillations.
!
!  The iterative loop below is to iterate toward an universal Backward-
!  Euler treatment of all terms. So if there are oscillations in the
!  system, they are only physical oscillations. These iterations,
!  however, do not improve the accuaracy of the solution.
!
        iter_loop: DO iter=1,bioiter(ng)
!
!  Compute light attenuation as function of depth.
!
          cff1=1.0/vmaxs(ng)
          cff2=1.0/vmaxl(ng)
          DO i=istr,iend
            atts=parsur(i)
            attl=parsur(i)
            IF (parsur(i).gt.0.0_r8) THEN              ! day time
              DO k=n(ng),1,-1
!
!  Attenuate the light to the center of the grid cell using the
!  Platt et al. (1980) photoinhibition formulation. Here, AttSW is
!  the light attenuation due to seawater and AttPS and AttPL is the
!  attenuation due to Small and Large Phytoplankton (self-shading
!  coefficient).
!
                dz=0.5_r8*(z_w(i,j,k)-z_w(i,j,k-1))
                kappas=attsw(ng)+                                       &
     &                 attps(ng)*(bio(i,k,isphy)+bio(i,k,ilphy))
                kappal=attsw(ng)+                                       &
     &                 attpl(ng)*(bio(i,k,isphy)+bio(i,k,ilphy))
                irrs=exp(-kappas*dz)
                irrl=exp(-kappal*dz)
                atts=atts*irrs
                attl=attl*irrl
                lights(i,k)=(1.0_r8-exp(-alphaps(ng)*atts*cff1))*       &
     &                      exp(-betaps(ng)*atts*cff1)
                lightl(i,k)=(1.0_r8-exp(-alphapl(ng)*attl*cff2))*       &
     &                      exp(-betapl(ng)*attl*cff2)
!
!  Attenuate the light to the bottom of the grid cell.
!
                atts=atts*irrs
                attl=attl*irrl
              END DO
            ELSE                                       ! night time
              DO k=1,n(ng)
                lights(i,k)=0.0_r8
                lightl(i,k)=0.0_r8
              END DO
            END IF
          END DO
!
!-----------------------------------------------------------------------
!  Phytoplankton primary productivity.
!-----------------------------------------------------------------------
!
!  Gross primary production of Small Phytoplankton consisting of
!  nutrient uptake (NO3 and NH4) terms, temperature-dependend term,
!  and light limitation term. The Michaelis-Menten curve is used to
!  describe the change in uptake rate as a function of nutrient
!  concentration.
!
          cff=dtdays*vmaxs(ng)
          DO k=1,n(ng)
            DO i=istr,iend
!
!  Small Phytoplankton gross primary productivity, GppPS.
!
              cff1=cff*exp(kgpps(ng)*bio(i,k,itemp))*lights(i,k)*       &
     &             bio(i,k,isphy)
              cff2=cff1*exp(-pusais(ng)*bio(i,k,inh4_))/                &
     &             (kno3s(ng)+bio(i,k,ino3_))
              cff3=cff1/(knh4s(ng)+bio(i,k,inh4_))
              bio(i,k,ino3_)=bio(i,k,ino3_)/(1.0_r8+cff2)
              bio(i,k,inh4_)=bio(i,k,inh4_)/(1.0_r8+cff3)
              gppnps=bio(i,k,ino3_)*cff2
              gppaps=bio(i,k,inh4_)*cff3
              gppps=gppnps+gppaps
              bio(i,k,isphy)=bio(i,k,isphy)+gppps
!
!  Small Phytoplankton respiration rate, ResPS, assumed to be
!  proportional to biomass. Use ratio of NO3 uptake to total update
!  (NO3 + NH4) to compute respiration contributions.
!
              rnews=gppnps/max(minval,gppps)
              cff4=dtdays*resps0(ng)*exp(kresps(ng)*bio(i,k,itemp))
              bio(i,k,isphy)=bio(i,k,isphy)/(1.0_r8+cff4)
              resps=bio(i,k,isphy)*cff4
              bio(i,k,ino3_)=bio(i,k,ino3_)+resps*rnews
              bio(i,k,inh4_)=bio(i,k,inh4_)+resps*(1.0_r8-rnews)
!
!  Small Phytoplankton extracellular excrection rate, ExcPS, assumed to
!  be proportional to production.
!
              excps=gppps*gammas(ng)
              bio(i,k,isphy)=bio(i,k,isphy)-excps
              bio(i,k,idon_)=bio(i,k,idon_)+excps
            END DO
          END DO
!
!  Gross primary production of Large Phytoplankton consisting of
!  nutrient uptake (NO3, NH4, Silicate) terms, temperature-dependend
!  term, and light limitation term. Notice that there is a silicate
!  limiting term (which complicates the implicit algorithm). Again,
!  the Michaelis-Menten curve is used to describe the change in
!  uptake rate as a function of nutrient concentration.
!
          cff=dtdays*vmaxl(ng)
          fac1=1.0/rsin(ng)
          fac2=dtdays*respl0(ng)
          DO k=1,n(ng)
            DO i=istr,iend
!
!  Large Phytoplankton gross primary productivity, GppPL. Notice that
!  the primary productivity is limited by previous time-step silicate
!  concentration.
!
              cff1=cff*exp(kgppl(ng)*bio(i,k,itemp))*lightl(i,k)*       &
     &             bio(i,k,ilphy)
              cff2=exp(-pusail(ng)*bio(i,k,inh4_))/                     &
     &             (kno3l(ng)+bio(i,k,ino3_))
              cff3=1.0_r8/(knh4l(ng)+bio(i,k,inh4_))
              cff4=cff2*bio(i,k,ino3_)
              cff5=cff3*bio(i,k,inh4_)
              cff6=bio(i,k,isioh)/(ksil(ng)+bio(i,k,isioh))
              cff7=cff6/max(minval,cff4+cff5)
              cff4=cff1*cff2*min(1.0_r8,cff7)     ! Si limitation on N03
              cff5=cff1*cff3*min(1.0_r8,cff7)     ! Si limitation on NH4
              bio(i,k,ino3_)=bio(i,k,ino3_)/(1.0_r8+cff4)
              bio(i,k,inh4_)=bio(i,k,inh4_)/(1.0_r8+cff5)
              gppnpl=bio(i,k,ino3_)*cff4
              gppapl=bio(i,k,inh4_)*cff5
              gpppl=gppnpl+gppapl
              bio(i,k,ilphy)=bio(i,k,ilphy)+gpppl
              bio(i,k,isioh)=bio(i,k,isioh)-gpppl*rsin(ng)
!
!  Large Phytoplankton respiration rate, ResPL, assumed to be
!  proportional to biomass. Use ratio of NO3 uptake to total update
!  (NO3 + NH4) to compute respiration contributions. Use Si:N ratio to
!  compute SiOH4 contribution.
!
              rnewl=gppnpl/max(minval,gpppl)
              cff7=fac2*exp(krespl(ng)*bio(i,k,itemp))
              bio(i,k,ilphy)=bio(i,k,ilphy)/(1.0_r8+cff7)
              respl=bio(i,k,ilphy)*cff7
              bio(i,k,ino3_)=bio(i,k,ino3_)+respl*rnewl
              bio(i,k,inh4_)=bio(i,k,inh4_)+respl*(1.0_r8-rnewl)
              bio(i,k,isioh)=bio(i,k,isioh)+respl*rsin(ng)
!
!  Large Phytoplankton extracellular excrection rate, ExcPL, assumed to
!  be proportional to production.
!
              excpl=gpppl*gammal(ng)
              bio(i,k,ilphy)=bio(i,k,ilphy)-excpl
              bio(i,k,idon_)=bio(i,k,idon_)+excpl
              bio(i,k,isioh)=bio(i,k,isioh)+excpl*rsin(ng)
            END DO
          END DO
!
!-----------------------------------------------------------------------
!  Phytoplankton mortality to particulate organic nitrogen.
!-----------------------------------------------------------------------
!
          fac1=dtdays*morps0(ng)
          fac2=dtdays*morpl0(ng)
          DO k=1,n(ng)
            DO i=istr,iend
              cff1=fac1*bio(i,k,isphy)*exp(kmorps(ng)*bio(i,k,itemp))
              cff2=fac2*bio(i,k,ilphy)*exp(kmorpl(ng)*bio(i,k,itemp))
              bio(i,k,isphy)=bio(i,k,isphy)/(1.0_r8+cff1)
              bio(i,k,ilphy)=bio(i,k,ilphy)/(1.0_r8+cff2)
              morps=bio(i,k,isphy)*cff1
              morpl=bio(i,k,ilphy)*cff2
              bio(i,k,ipon_)=bio(i,k,ipon_)+morps+morpl
              bio(i,k,iopal)=bio(i,k,iopal)+morpl*rsin(ng)
            END DO
          END DO
!
!-----------------------------------------------------------------------
!  Zooplankton grazing, egestion and excretion.
!-----------------------------------------------------------------------
 
#if defined IVLEV_EXPLICIT
!
!  The rate of grazing by the zooplankton is modeled using an Ivlev
!  equation with a feeding threshold using an explicit (non-conserving)
!  algorithm to the original formulation. Notice that term is forced to
!  be positive using a MAX function.
!
#elif defined HOLLING_GRAZING
!
!  The rate of grazing by the zooplankton is modeled using a Holling-
!  type s-shaped curve. It is known to be numerically more stable and
!  allows an implicit discretization.
!
!    P(new) = P(old) - dt*mu*[P(old)/(Kp + P(old)^2)]*P(new)*Z(old)
!
!  The implicit grazing term is then:
!
!    P(new) = P(old) / (1 + G)
!
!  were the grazing rate, G, is:
!
!    G = dt * mu * [P(old)/(Kp + P(old)^2)] * Z(old)
!
#else
# define IVLEV_IMPLICIT
!
!  The rate of grazing by the zooplankton is modeled using an Ivlev
!  equation with a feeding threshold. An implicit algorithm is
!  achieved by multiplying grazing term by a unity factor, alpha:
!
!    alpha = 1 = P(new)/(P(old)+deltaP)
!
!  where
!
!    deltaP = P(new) - P(old) = - dt*mu*[1-EXP(lambda*P(old))]
!
!  The factor alpha can be approximated using Taylor series to:
!
!    alpha = [P(new) / P(old)] * [1 - deltaP/P(old)]
!
!  The discretized grazing term is then:
!
!    P(new) = P(old) - dt*mu*[1-EXP(lambda*P)] * alpha * Z(old)
!
!  Which can be approximated with an implicit algorithm to:
!
!    P(new) = P(old) / (1 + G)
!
!  were the grazing rate, G, is:
!
!    G = [1 + P(old)/(dt*mu*(1 - EXP(lambda*P(old))))] * Z(old)
!
#endif
          fac1=dtdays*grmaxsps(ng)
          fac2=dtdays*grmaxlps(ng)
          fac3=dtdays*grmaxlpl(ng)
          fac4=dtdays*grmaxlzs(ng)
          fac5=dtdays*grmaxppl(ng)
          fac6=dtdays*grmaxpzs(ng)
          fac7=dtdays*grmaxpzl(ng)
          DO k=1,n(ng)
            DO i=istr,iend
!
!  Temperature-dependent term (Q10).
!
              cff1=exp(kgras(ng)*bio(i,k,itemp))
              cff2=exp(kgral(ng)*bio(i,k,itemp))
              cff3=exp(kgrap(ng)*bio(i,k,itemp))
!
!  Small Zooplankton grazing on Small Phytoplankton, GraPS2ZS.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(lams(ng)*(ps2zsstar(ng)-bio(i,k,isphy)))
              graps2zs=fac1*cff1*max(0.0_r8,cff4)*bio(i,k,iszoo)
              bio(i,k,isphy)=bio(i,k,isphy)-graps2zs
              bio(i,k,iszoo)=bio(i,k,iszoo)+graps2zs
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kps2zs(ng)+bio(i,k,isphy)*bio(i,k,isphy))
              cff=fac1*cff1*cff4*bio(i,k,iszoo)*bio(i,k,isphy)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(lams(ng)*(ps2zsstar(ng)-bio(i,k,isphy)))
              cff5=1.0_r8/(fac1*cff4)
              cff=(1.0_r8+bio(i,k,isphy)*cff5)*cff1*bio(i,k,iszoo)
# endif
              bio(i,k,isphy)=bio(i,k,isphy)/(1.0_r8+cff)
              graps2zs=cff*bio(i,k,isphy)
              bio(i,k,iszoo)=bio(i,k,iszoo)+graps2zs
#endif
!
!  Large Zooplankton grazing on Small Phytoplankton, GraPS2ZL.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(laml(ng)*(ps2zlstar(ng)-bio(i,k,isphy)))
              graps2zl=fac2*cff2*max(0.0_r8,cff4)*bio(i,k,ilzoo)
              bio(i,k,isphy)=bio(i,k,isphy)-graps2zl
              bio(i,k,ilzoo)=bio(i,k,ilzoo)+graps2zl
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kps2zl(ng)+bio(i,k,isphy)*bio(i,k,isphy))
              cff=fac2*cff2*cff4*bio(i,k,ilzoo)*bio(i,k,isphy)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(laml(ng)*(ps2zlstar(ng)-bio(i,k,isphy)))
              cff5=1.0_r8/(fac2*cff4)
              cff=(1.0_r8+bio(i,k,isphy)*cff5)*cff2*bio(i,k,ilzoo)
# endif
              bio(i,k,isphy)=bio(i,k,isphy)/(1.0_r8+cff)
              graps2zl=cff*bio(i,k,isphy)
              bio(i,k,ilzoo)=bio(i,k,ilzoo)+graps2zl
#endif
!
!  Large Zooplankton grazing on Large Phytoplankton, GraPL2ZL.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(laml(ng)*(pl2zlstar(ng)-bio(i,k,ilphy)))
              grapl2zl=fac3*cff2*max(0.0_r8,cff4)*bio(i,k,ilzoo)
              bio(i,k,ilphy)=bio(i,k,ilphy)-grapl2zl
              bio(i,k,ilzoo)=bio(i,k,ilzoo)+grapl2zl
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kpl2zl(ng)+bio(i,k,ilphy)*bio(i,k,ilphy))
              cff=fac3*cff2*cff4*bio(i,k,ilzoo)*bio(i,k,ilphy)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(laml(ng)*(pl2zlstar(ng)-bio(i,k,ilphy)))
              cff5=1.0_r8/(fac3*cff4)
              cff=(1.0_r8+bio(i,k,ilphy)*cff5)*cff2*bio(i,k,ilzoo)
# endif
              bio(i,k,ilphy)=bio(i,k,ilphy)/(1.0_r8+cff)
              grapl2zl=cff*bio(i,k,ilphy)
              bio(i,k,ilzoo)=bio(i,k,ilzoo)+grapl2zl
#endif
!
!  Large Zooplankton grazing on Small Zooplankton, GraZS2ZL.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(laml(ng)*(zs2zlstar(ng)-bio(i,k,iszoo)))
              grazs2zl=fac4*cff2*max(0.0_r8,cff4)*bio(i,k,ilzoo)
              bio(i,k,iszoo)=bio(i,k,iszoo)-grazs2zl
              bio(i,k,ilzoo)=bio(i,k,ilzoo)+grazs2zl
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kzs2zl(ng)+bio(i,k,iszoo)*bio(i,k,iszoo))
              cff=fac4*cff2*cff4*bio(i,k,ilzoo)*bio(i,k,iszoo)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(laml(ng)*(zs2zlstar(ng)-bio(i,k,iszoo)))
              cff5=1.0_r8/(fac4*cff4)
              cff=(1.0_r8+bio(i,k,isphy)*cff5)*cff2*bio(i,k,ilzoo)
# endif
              bio(i,k,iszoo)=bio(i,k,iszoo)/(1.0_r8+cff)
              grazs2zl=cff*bio(i,k,iszoo)
              bio(i,k,ilzoo)=bio(i,k,ilzoo)+grazs2zl
#endif
!
!  Predactor Zooplankton grazing on Large Phytoplankton, GraPL2ZP.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(lamp(ng)*(pl2zpstar(ng)-bio(i,k,ilphy)))
              cff5=exp(-pusaipl(ng)*(bio(i,k,ilzoo)+bio(i,k,iszoo)))
              grapl2zp=fac5*cff3*cff5*max(0.0_r8,cff4)*bio(i,k,ipzoo)
              bio(i,k,ilphy)=bio(i,k,ilphy)-grapl2zp
              bio(i,k,ipzoo)=bio(i,k,ipzoo)+grapl2zp
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kpl2zp(ng)+bio(i,k,ilphy)*bio(i,k,ilphy))
              cff5=exp(-pusaipl(ng)*(bio(i,k,ilzoo)+bio(i,k,iszoo)))
              cff=fac5*cff3*cff4*cff5*bio(i,k,ipzoo)*bio(i,k,ilphy)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(lamp(ng)*(pl2zpstar(ng)-bio(i,k,ilphy)))
              cff5=exp(-pusaipl(ng)*(bio(i,k,ilzoo)+bio(i,k,iszoo)))
              cff6=1.0_r8/(fac5*cff4)
              cff=(1.0_r8+bio(i,k,ilphy)*cff6)*cff3*cff5*bio(i,k,ipzoo)
# endif
              bio(i,k,ilphy)=bio(i,k,ilphy)/(1.0_r8+cff)
              grapl2zp=cff*bio(i,k,ilphy)
              bio(i,k,ipzoo)=bio(i,k,ipzoo)+grapl2zp
#endif
!
!  Predactory Zooplankton grazing on Small Zooplankton, GraZS2ZP.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(lamp(ng)*(zs2zpstar(ng)-bio(i,k,iszoo)))
              cff5=exp(-pusaizs(ng)*bio(i,k,ilzoo))
              grazs2zp=fac6*cff3*cff5*max(0.0_r8,cff4)*bio(i,k,ipzoo)
              bio(i,k,iszoo)=bio(i,k,iszoo)-grazs2zp
              bio(i,k,ipzoo)=bio(i,k,ipzoo)+grazs2zp
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kzs2zp(ng)+bio(i,k,iszoo)*bio(i,k,iszoo))
              cff5=exp(-pusaizs(ng)*bio(i,k,ilzoo))
              cff=fac6*cff3*cff4*cff5*bio(i,k,ipzoo)*bio(i,k,iszoo)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(lamp(ng)*(zs2zpstar(ng)-bio(i,k,iszoo)))
              cff5=exp(-pusaizs(ng)*bio(i,k,ilzoo))
              cff6=1.0_r8/(fac6*cff4)
              cff=(1.0_r8+bio(i,k,iszoo)*cff6)*cff3*cff5*bio(i,k,ipzoo)
# endif
              bio(i,k,iszoo)=bio(i,k,iszoo)/(1.0_r8+cff)
              grazs2zp=cff*bio(i,k,iszoo)
              bio(i,k,ipzoo)=bio(i,k,ipzoo)+grazs2zp
#endif
!
!  Predactory Zooplankton grazing on Large Zooplankton, GraZL2ZP.
!
#if defined IVLEV_EXPLICIT
              cff4=1.0_r8-exp(lamp(ng)*(zl2zpstar(ng)-bio(i,k,ilzoo)))
              grazl2zp=fac7*cff3*max(0.0_r8,cff4)*bio(i,k,ipzoo)
              bio(i,k,ilzoo)=bio(i,k,ilzoo)-grazl2zp
              bio(i,k,ipzoo)=bio(i,k,ipzoo)+grazl2zp
#else
# ifdef HOLLING_GRAZING
              cff4=1.0_r8/(kzl2zp(ng)+bio(i,k,ilzoo)*bio(i,k,ilzoo))
              cff=fac7*cff3*cff4*bio(i,k,ipzoo)*bio(i,k,ilzoo)
# elif defined IVLEV_IMPLICIT
              cff4=1.0_r8-exp(lamp(ng)*(zl2zpstar(ng)-bio(i,k,ilzoo)))
              cff5=1.0_r8/(fac7*cff4)
              cff=(1.0_r8+bio(i,k,ilzoo)*cff5)*cff3*bio(i,k,ipzoo)
# endif
              bio(i,k,ilzoo)=bio(i,k,ilzoo)/(1.0_r8+cff)
              grazl2zp=cff*bio(i,k,ilzoo)
              bio(i,k,ipzoo)=bio(i,k,ipzoo)+grazl2zp
#endif
!
!  Zooplankton egestion to Particulate Organic Nitrogen (PON) and
!  Particulate Organic Silica (opal).
!
              egezs=(1.0_r8-alphazs(ng))*                               &
     &              graps2zs
              egezl=(1.0_r8-alphazl(ng))*                               &
     &              (graps2zl+grapl2zl+grazs2zl)
              egezp=(1.0_r8-alphazp(ng))*                               &
     &              (grapl2zp+grazs2zp+grazl2zp)
              bio(i,k,iszoo)=bio(i,k,iszoo)-egezs
              bio(i,k,ilzoo)=bio(i,k,ilzoo)-egezl
              bio(i,k,ipzoo)=bio(i,k,ipzoo)-egezp
              bio(i,k,ipon_)=bio(i,k,ipon_)+egezs+egezl+egezp
              bio(i,k,iopal)=bio(i,k,iopal)+(grapl2zl+grapl2zp)*rsin(ng)
!
!  Zooplankton excretion to NH4.
!
              exczs=(alphazs(ng)-betazs(ng))*                           &
     &              graps2zs
              exczl=(alphazl(ng)-betazl(ng))*                           &
     &              (graps2zl+grapl2zl+grazs2zl)
              exczp=(alphazp(ng)-betazp(ng))*                           &
     &              (grapl2zp+grazs2zp+grazl2zp)
              bio(i,k,iszoo)=bio(i,k,iszoo)-exczs
              bio(i,k,ilzoo)=bio(i,k,ilzoo)-exczl
              bio(i,k,ipzoo)=bio(i,k,ipzoo)-exczp
              bio(i,k,inh4_)=bio(i,k,inh4_)+exczs+exczl+exczp
            END DO
          END DO
!
!-----------------------------------------------------------------------
!  Zooplankton motality to particulate organic nitrogen.
!-----------------------------------------------------------------------
!
          fac1=dtdays*morzs0(ng)
          fac2=dtdays*morzl0(ng)
          fac3=dtdays*morzp0(ng)
          DO k=1,n(ng)
            DO i=istr,iend
              cff1=fac1*bio(i,k,iszoo)*exp(kmorzs(ng)*bio(i,k,itemp))
              cff2=fac2*bio(i,k,ilzoo)*exp(kmorzl(ng)*bio(i,k,itemp))
              cff3=fac3*bio(i,k,ipzoo)*exp(kmorzp(ng)*bio(i,k,itemp))
              bio(i,k,iszoo)=bio(i,k,iszoo)/(1.0_r8+cff1)
              bio(i,k,ilzoo)=bio(i,k,ilzoo)/(1.0_r8+cff2)
              bio(i,k,ipzoo)=bio(i,k,ipzoo)/(1.0_r8+cff3)
              bio(i,k,ipon_)=bio(i,k,ipon_)+                            &
     &                       bio(i,k,iszoo)*cff1+                       &
     &                       bio(i,k,ilzoo)*cff2+                       &
     &                       bio(i,k,ipzoo)*cff3
            END DO
          END DO
!
!-----------------------------------------------------------------------
!  Nutrient decomposition.
!-----------------------------------------------------------------------
!
          fac1=dtdays*nit0(ng)
          fac2=dtdays*vp2n0(ng)
          fac3=dtdays*vp2d0(ng)
          fac4=dtdays*vd2n0(ng)
          fac5=dtdays*vo2s0(ng)
          DO k=1,n(ng)
            DO i=istr,iend
!
!  Nitrification: NH4 to NO3.
!
              cff1=fac1*exp(knit(ng)*bio(i,k,itemp))
              bio(i,k,inh4_)=bio(i,k,inh4_)/(1.0_r8+cff1)
              bio(i,k,ino3_)=bio(i,k,ino3_)+                            &
     &                       bio(i,k,inh4_)*cff1
!
!  Decomposition: PON to NH4.
!
              cff2=fac2*exp(kp2n(ng)*bio(i,k,itemp))
              bio(i,k,ipon_)=bio(i,k,ipon_)/(1.0_r8+cff2)
              bio(i,k,inh4_)=bio(i,k,inh4_)+                            &
     &                       bio(i,k,ipon_)*cff2
!
!  Decomposition: PON to DON.
!
              cff3=fac3*exp(kp2d(ng)*bio(i,k,itemp))
              bio(i,k,ipon_)=bio(i,k,ipon_)/(1.0_r8+cff3)
              bio(i,k,idon_)=bio(i,k,idon_)+                            &
     &                       bio(i,k,ipon_)*cff3
!
!  Decomposition: DON to NH4.
!
              cff4=fac4*exp(kd2n(ng)*bio(i,k,itemp))
              bio(i,k,idon_)=bio(i,k,idon_)/(1.0_r8+cff4)
              bio(i,k,inh4_)=bio(i,k,inh4_)+                            &
     &                       bio(i,k,idon_)*cff4
!
!  Decomposition: Opal to SiOH4.
!
              cff5=fac5*exp(ko2s(ng)*bio(i,k,itemp))
              bio(i,k,iopal)=bio(i,k,iopal)/(1.0_r8+cff5)
              bio(i,k,isioh)=bio(i,k,isioh)+                            &
     &                       bio(i,k,iopal)*cff5
            END DO
          END DO
!
!-----------------------------------------------------------------------
!  Vertical sinking terms: PON and Opal.
!-----------------------------------------------------------------------
!
!  Reconstruct vertical profile of selected biological constituents
!  "Bio(:,:,isink)" in terms of a set of parabolic segments within each
!  grid box. Then, compute semi-Lagrangian flux due to sinking.
!
          sink_loop: DO isink=1,nsink
            ibio=idsink(isink)
!
!  Copy concentration of biological particulates into scratch array
!  "qc" (q-central, restrict it to be positive) which is hereafter
!  interpreted as a set of grid-box averaged values for biogeochemical
!  constituent concentration.
!
            DO k=1,n(ng)
              DO i=istr,iend
                qc(i,k)=bio(i,k,ibio)
              END DO
            END DO
!
            DO k=n(ng)-1,1,-1
              DO i=istr,iend
                fc(i,k)=(qc(i,k+1)-qc(i,k))*hz_inv2(i,k)
              END DO
            END DO
            DO k=2,n(ng)-1
              DO i=istr,iend
                dltr=hz(i,j,k)*fc(i,k)
                dltl=hz(i,j,k)*fc(i,k-1)
                cff=hz(i,j,k-1)+2.0_r8*hz(i,j,k)+hz(i,j,k+1)
                cffr=cff*fc(i,k)
                cffl=cff*fc(i,k-1)
!
!  Apply PPM monotonicity constraint to prevent oscillations within the
!  grid box.
!
                IF ((dltr*dltl).le.0.0_r8) THEN
                  dltr=0.0_r8
                  dltl=0.0_r8
                ELSE IF (abs(dltr).gt.abs(cffl)) THEN
                  dltr=cffl
                ELSE IF (abs(dltl).gt.abs(cffr)) THEN
                  dltl=cffr
                END IF
!
!  Compute right and left side values (bR,bL) of parabolic segments
!  within grid box Hz(k); (WR,WL) are measures of quadratic variations.
!
!  NOTE: Although each parabolic segment is monotonic within its grid
!        box, monotonicity of the whole profile is not guaranteed,
!        because bL(k+1)-bR(k) may still have different sign than
!        qc(i,k+1)-qc(i,k).  This possibility is excluded,
!        after bL and bR are reconciled using WENO procedure.
!
                cff=(dltr-dltl)*hz_inv3(i,k)
                dltr=dltr-cff*hz(i,j,k+1)
                dltl=dltl+cff*hz(i,j,k-1)
                br(i,k)=qc(i,k)+dltr
                bl(i,k)=qc(i,k)-dltl
                wr(i,k)=(2.0_r8*dltr-dltl)**2
                wl(i,k)=(dltr-2.0_r8*dltl)**2
              END DO
            END DO
            cff=1.0e-14_r8
            DO k=2,n(ng)-2
              DO i=istr,iend
                dltl=max(cff,wl(i,k  ))
                dltr=max(cff,wr(i,k+1))
                br(i,k)=(dltr*br(i,k)+dltl*bl(i,k+1))/(dltr+dltl)
                bl(i,k+1)=br(i,k)
              END DO
            END DO
            DO i=istr,iend
              fc(i,n(ng))=0.0_r8            ! NO-flux boundary condition
#if defined LINEAR_CONTINUATION
              bl(i,n(ng))=br(i,n(ng)-1)
              br(i,n(ng))=2.0_r8*qc(i,n(ng))-bl(i,n(ng))
#elif defined NEUMANN
              bl(i,n(ng))=br(i,n(ng)-1)
              br(i,n(ng))=1.5_r8*qc(i,n(ng))-0.5_r8*bl(i,n(ng))
#else
              br(i,n(ng))=qc(i,n(ng))       ! default strictly monotonic
              bl(i,n(ng))=qc(i,n(ng))       ! conditions
              br(i,n(ng)-1)=qc(i,n(ng))
#endif
#if defined LINEAR_CONTINUATION
              br(i,1)=bl(i,2)
              bl(i,1)=2.0_r8*qc(i,1)-br(i,1)
#elif defined NEUMANN
              br(i,1)=bl(i,2)
              bl(i,1)=1.5_r8*qc(i,1)-0.5_r8*br(i,1)
#else
              bl(i,2)=qc(i,1)               ! bottom grid boxes are
              br(i,1)=qc(i,1)               ! re-assumed to be
              bl(i,1)=qc(i,1)               ! piecewise constant.
#endif
            END DO
!
!  Apply monotonicity constraint again, since the reconciled interfacial
!  values may cause a non-monotonic behavior of the parabolic segments
!  inside the grid box.
!
            DO k=1,n(ng)
              DO i=istr,iend
                dltr=br(i,k)-qc(i,k)
                dltl=qc(i,k)-bl(i,k)
                cffr=2.0_r8*dltr
                cffl=2.0_r8*dltl
                IF ((dltr*dltl).lt.0.0_r8) THEN
                  dltr=0.0_r8
                  dltl=0.0_r8
                ELSE IF (abs(dltr).gt.abs(cffl)) THEN
                  dltr=cffl
                ELSE IF (abs(dltl).gt.abs(cffr)) THEN
                  dltl=cffr
                END IF
                br(i,k)=qc(i,k)+dltr
                bl(i,k)=qc(i,k)-dltl
              END DO
            END DO
!
!  After this moment reconstruction is considered complete. The next
!  stage is to compute vertical advective fluxes, FC. It is expected
!  that sinking may occurs relatively fast, the algorithm is designed
!  to be free of CFL criterion, which is achieved by allowing
!  integration bounds for semi-Lagrangian advective flux to use as
!  many grid boxes in upstream direction as necessary.
!
!  In the two code segments below, WL is the z-coordinate of the
!  departure point for grid box interface z_w with the same indices;
!  FC is the finite volume flux; ksource(:,k) is index of vertical
!  grid box which contains the departure point (restricted by N(ng)).
!  During the search: also add in content of whole grid boxes
!  participating in FC.
!
            cff=dtdays*abs(wbio(isink))
            DO k=1,n(ng)
              DO i=istr,iend
                fc(i,k-1)=0.0_r8
                wl(i,k)=z_w(i,j,k-1)+cff
                wr(i,k)=hz(i,j,k)*qc(i,k)
                ksource(i,k)=k
              END DO
            END DO
            DO k=1,n(ng)
              DO ks=k,n(ng)-1
                DO i=istr,iend
                  IF (wl(i,k).gt.z_w(i,j,ks)) THEN
                    ksource(i,k)=ks+1
                    fc(i,k-1)=fc(i,k-1)+wr(i,ks)
                  END IF
                END DO
              END DO
            END DO
!
!  Finalize computation of flux: add fractional part.
!
            DO k=1,n(ng)
              DO i=istr,iend
                ks=ksource(i,k)
                cu=min(1.0_r8,(wl(i,k)-z_w(i,j,ks-1))*hz_inv(i,ks))
                fc(i,k-1)=fc(i,k-1)+                                    &
     &                    hz(i,j,ks)*cu*                                &
     &                    (bl(i,ks)+                                    &
     &                     cu*(0.5_r8*(br(i,ks)-bl(i,ks))-              &
     &                         (1.5_r8-cu)*                             &
     &                         (br(i,ks)+bl(i,ks)-                      &
     &                          2.0_r8*qc(i,ks))))
              END DO
            END DO
            DO k=1,n(ng)
              DO i=istr,iend
                bio(i,k,ibio)=qc(i,k)+(fc(i,k)-fc(i,k-1))*hz_inv(i,k)
              END DO
            END DO
 
#ifdef BIO_SEDIMENT
!
!  Particulate fluxes reaching the seafloor are remineralized and returned
!  to the dissolved nutrient pool. Without this conversion, particulate
!  material falls out of the system. This is a temporary fix to restore
!  total nutrient conservation. This may require a time delay
!  remineralization in the future.
!
!  HGA: The original Nemuro model has a restoring upwelling rate (UPW).
!       The code below is an interpretation in terms of the semi-
!       Lagrangian algorithm. What is the correct nutrient path from
!       the benthos to the water column?  NH4 to NO3?
!
            IF (ibio.eq.ipon_) THEN
              DO i=istr,iend
                cff1=fc(i,0)*hz_inv(i,1)
                bio(i,1,ino3_)=bio(i,1,ino3_)+cff1
              END DO
            ELSE IF (ibio.eq.iopal) THEN
              DO i=istr,iend
                cff1=fc(i,0)*hz_inv(i,1)
                bio(i,1,isioh)=bio(i,1,isioh)+cff1
              END DO
            END IF
#endif
 
          END DO sink_loop
        END DO iter_loop
!
!-----------------------------------------------------------------------
!  Update global tracer variables: Add increment due to BGC processes
!  to tracer array in time index "nnew". Index "nnew" is solution after
!  advection and mixing and has transport units (m Tunits) hence the
!  increment is multiplied by Hz.  Notice that we need to subtract
!  original values "Bio_old" at the top of the routine to just account
!  for the concentractions affected by BGC processes. This also takes
!  into account any constraints (non-negative concentrations, carbon
!  concentration range) specified before entering BGC kernel. If "Bio"
!  were unchanged by BGC processes, the increment would be exactly
!  zero. Notice that final tracer values, t(:,:,:,nnew,:) are not
!  bounded >=0 so that we can preserve total inventory of nutrients
!  when advection causes tracer concentration to go negative.
!-----------------------------------------------------------------------
!
        DO itrc=1,nbt
          ibio=idbio(itrc)
          DO k=1,n(ng)
            DO i=istr,iend
              cff=bio(i,k,ibio)-bio_old(i,k,ibio)
              t(i,j,k,nnew,ibio)=t(i,j,k,nnew,ibio)+cff*hz(i,j,k)
            END DO
          END DO
        END DO
 
      END DO j_loop
!
      RETURN
      END SUBROUTINE nemuro_tile
 
      END MODULE biology_mod