ice_enthalpy.F

Go to the documentation of this file.

#include "cppdefs.h"
      MODULE ice_enthalpy_mod
 
#ifdef ICE_MODEL
!
!git $Id$
!=======================================================================
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license           W. Paul Budgell    !
!    See License_ROMS.md                            Katherine Hedstrom !
!================================================== Hernan G. Arango ===
!                                                                      !
!  This routine computes the ice enthalpy (ti*hi) prior to advection.  !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_ice
      USE mod_scalars
!
      USE exchange_2d_mod, ONLY : exchange_r2d_tile
#ifdef DISTRIBUTE
      USE mp_exchange_mod, ONLY : mp_exchange2d
#endif
!
      implicit none
!
      PRIVATE
      PUBLIC  ice_enthalpy
!
      CONTAINS
!
!***********************************************************************
      SUBROUTINE ice_enthalpy (ng, tile, model)
!***********************************************************************
!
      USE mod_stepping
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
!
!  Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
#include "tile.h"
!
# ifdef PROFILE
      CALL wclock_on (ng, model, 42, __line__, myfile)
# endif
      CALL ice_enthalpy_tile (ng, tile, model,                          &
     &                        lbi, ubi, lbj, ubj,                       &
     &                        imins, imaxs, jmins, jmaxs,               &
     &                        liold(ng), linew(ng),                     &
     &                        ice(ng)%Si)
# ifdef PROFILE
      CALL wclock_off (ng, model, 42, __line__, myfile)
# endif
!
      RETURN
      END SUBROUTINE ice_enthalpy
!
!***********************************************************************
      SUBROUTINE ice_enthalpy_tile (ng, tile, model,                    &
     &                              LBi, UBi, LBj, UBj,                 &
     &                              IminS, ImaxS, JminS, JmaxS,         &
     &                              liold, linew,                       &
     &                              Si)
!***********************************************************************
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
      integer, intent(in) :: liold, linew
!
#ifdef ASSUMED_SHAPE
      real(r8), intent(inout) :: Si(LBi:,LBj:,:,:)
#else
      real(r8), intent(inout) :: Si(LBi:UBi,LBj:UBj,2,nIceS)
#endif
!
!  Local variables
!
      integer :: i, j
 
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Computes the ice enthalpy.
!-----------------------------------------------------------------------
!
      DO j=jstrt,jendt
        DO i=istrt,iendt
          si(i,j,liold,isenth)=si(i,j,liold,ishice)*                    &
     &                         si(i,j,liold,istice)
          si(i,j,linew,isenth)=si(i,j,linew,ishice)*                    &
     &                         si(i,j,linew,istice)
          IF(si(i,j,liold,ishice).le.min_hi(ng)) THEN
            si(i,j,liold,isenth)=0.0_r8
          END IF
        END DO
      END DO
!
!  Exchange boundary data.
!
      IF (ewperiodic(ng).or.nsperiodic(ng)) THEN
        CALL exchange_r2d_tile (ng, tile,                               &
     &                          lbi, ubi, lbj, ubj,                     &
     &                          si(:,:,liold,isenth))
 
        CALL exchange_r2d_tile (ng, tile,                               &
     &                          lbi, ubi, lbj, ubj,                     &
     &                          si(:,:,linew,isenth))
      END IF
 
# ifdef DISTRIBUTE
!
      CALL mp_exchange2d (ng, tile, model, 2,                           &
     &                    lbi, ubi, lbj, ubj,                           &
     &                    nghostpoints, ewperiodic(ng), nsperiodic(ng), &
     &                    si(:,:,liold,isenth),                         &
     &                    si(:,:,linew,isenth))
# endif
!
      RETURN
      END SUBROUTINE ice_enthalpy_tile
#endif
      END MODULE ice_enthalpy_mod