def_dim.F

Go to the documentation of this file.

#include "cppdefs.h"
      MODULE def_dim_mod
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This module defines the requested NetCDF dimension.                 !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_scalars
!
      USE strings_mod, ONLY : founderror
!
      implicit none
!
      INTERFACE def_dim
        MODULE PROCEDURE def_dim_nf90
#if defined PIO_LIB && defined DISTRIBUTE
        MODULE PROCEDURE def_dim_pio
#endif
      END INTERFACE def_dim
!
      CONTAINS
!
!***********************************************************************
      FUNCTION def_dim_nf90 (ng, model, ncid, ncname,                   &
     &                       DimName, DimSize, DimID) RESULT (status)
!***********************************************************************
!                                                                      !
!  This function defines the requested NetCDF dimension when using the !
!  standard NetCDF-3 or NetCDF-4 library.                              !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng       Nested grid number (integer)                            !
!     model    Calling model identifier (integer)                      !
!     ncid     NetCDF file ID (integer)                                !
!     ncname   NetCDF filename (string)                                !
!     DimName  Dimension name (string)                                 !
!     DimSize  Dimension size (integer)                                !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     status   NetCDF error flag (integer)                             !
!     DimId    NetCDF dimension ID (integer)                           !
!                                                                      !
!***********************************************************************
!
      USE mod_netcdf
 
#if !defined PARALLEL_IO  && defined DISTRIBUTE
!
      USE distribute_mod, ONLY : mp_bcasti
#endif
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent (in)  :: ng, model, ncid
      integer, intent (in)  :: dimsize
      integer, intent (out) :: dimid
!
      character (len=*), intent(in) :: ncname
      character (len=*), intent(in) :: dimname
!
!  Local variable declarations.
!
      integer :: status
 
#if !defined PARALLEL_IO  && defined DISTRIBUTE
      integer, dimension(3) :: ibuffer
#endif
!
      character (len=*), parameter :: myfile =                          &
     &  __FILE__//", def_dim_nf90"
!
      sourcefile=myfile
!
!-----------------------------------------------------------------------
!  Define requested NetCDF dimension.
!-----------------------------------------------------------------------
!
      status=nf90_noerr
!
      IF (outthread) THEN
        status=nf90_def_dim(ncid, trim(dimname), dimsize, dimid)
        IF (founderror(status, nf90_noerr, __line__, myfile)) THEN
          IF (master) WRITE (stdout,10) trim(dimname), trim(ncname)
          exit_flag=3
          ioerror=status
        END IF
      END IF
 
#if !defined PARALLEL_IO  && defined DISTRIBUTE
!
!  Broadcast information to all threads in the group.
!
      ibuffer(1)=dimid
      ibuffer(2)=status
      ibuffer(3)=exit_flag
      CALL mp_bcasti (ng, model, ibuffer)
      dimid=ibuffer(1)
      status=ibuffer(2)
      exit_flag=ibuffer(3)
#endif
!
 10   FORMAT (/,' DEF_DIM_NF90 - error while defining dimension: ',a,   &
     &        /,16x,'in file: ',a)
!
      RETURN
      END FUNCTION def_dim_nf90
 
#if defined PIO_LIB && defined DISTRIBUTE
!
!***********************************************************************
      FUNCTION def_dim_pio (ng, model, pioFile, ncname,                 &
     &                      DimName, DimSize, DimId) RESULT (status)
!***********************************************************************
!                                                                      !
!  This function defines the requested NetCDF dimension when using the !
!  NCAR Parallel-IO library.                                           !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng       Nested grid number (integer)                            !
!     model    Calling model identifier (integer)                      !
!     pioFile  PIO file descriptor structure, TYPE(file_desc_t)        !
!                pioFile%fh         file handler                       !
!                pioFile%iosystem   IO system descriptor (struct)      !
!     ncname   PIO filename (string)                                   !
!     DimName  Dimension name (string)                                 !
!     DimSize  Dimension size (integer)                                !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     status   PIO error flag (integer)                                !
!     DimId    PIO dimension ID (integer)                              !
!                                                                      !
!***********************************************************************
!
      USE pio
!
!  Imported variable declarations.
!
      integer, intent (in)  :: ng, model
      integer, intent (in)  :: dimsize
      integer, intent (out) :: dimid
!
      character (len=*), intent(in) :: ncname
      character (len=*), intent(in) :: dimname
!
      TYPE (file_desc_t), intent(in) :: piofile
!
!  Local variable declarations.
!
      integer :: status
!
      character (len=*), parameter :: myfile =                          &
     &  __FILE__//", def_dim_pio"
!
      sourcefile=myfile
!
!-----------------------------------------------------------------------
!  Define requested PIO dimension.
!-----------------------------------------------------------------------
!
      status=pio_noerr
!
      status=pio_def_dim(piofile, trim(dimname), dimsize, dimid)
      IF (founderror(status, pio_noerr, __line__,                       &
     &                 __file__)) THEN
        IF (master) WRITE (stdout,10) trim(dimname), trim(ncname)
        exit_flag=3
        ioerror=status
      END IF
!
 10   FORMAT (/,' DEF_DIM_PIO - error while defining dimension: ',a,    &
     &        /,15x,'in file: ',a)
!
      RETURN
      END FUNCTION def_dim_pio
#endif
      END MODULE def_dim_mod