check_multifile.F

Go to the documentation of this file.

#include "cppdefs.h"
      SUBROUTINE check_multifile (ng, model)
!
!git $Id$
!================================================== Hernan G. Arango ===
!  Copyright (c) 2002-2025 The ROMS Group                              !
!    Licensed under a MIT/X style license                              !
!    See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  If applicable, this routine checks input NetCDF multi-files and     !
!  sets several parameters in the file information structure so the    !
!  appropriate file is selected during initialization or restart.      !
!                                                                      !
!  Multi-files are allowed for several input fields. That is, the      !
!  time records for a particular input field can be split into         !
!  several NetCDF files.                                               !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE dateclock_mod, ONLY : time_string
      USE strings_mod,   ONLY : founderror
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, model
!
!  Local variable declarations.
!
      integer :: i, max_files
!
      real(dp) :: Tfinal
!
      character (len= 1), parameter :: blank = ' '
      character (len=40) :: file_type
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
      sourcefile=myfile
!
!=======================================================================
!  If applicable, initialize parameters for input multi-files.
!=======================================================================
!
!  Initialize I/O information variables to facilitate to reset the
!  values in iterative algorithms that call the NLM, TLM, RPM, and
!  ADM kernels repetitevely.  Notice that Iinfo(1,:,:) is not reset
!  because it is part of the metadata.
!
      DO i=1,nv
        cinfo(i,ng)=blank
        linfo(1,i,ng)=.false.
        linfo(2,i,ng)=.false.
        linfo(3,i,ng)=.false.
        linfo(4,i,ng)=.false.
        linfo(5,i,ng)=.false.
        linfo(6,i,ng)=.false.
        iinfo(2,i,ng)=-1
        iinfo(3,i,ng)=-1
        iinfo(4,i,ng)=0
        iinfo(5,i,ng)=0
        iinfo(6,i,ng)=0
        iinfo(7,i,ng)=0
        iinfo(8,i,ng)=2
        iinfo(9,i,ng)=0
        iinfo(10,i,ng)=0
        finfo(1,i,ng)=0.0_r8
        finfo(2,i,ng)=0.0_r8
        finfo(3,i,ng)=0.0_r8
        finfo(5,i,ng)=0.0_r8
        finfo(6,i,ng)=0.0_r8
        finfo(7,i,ng)=0.0_r8
        finfo(10,i,ng)=1.0_r8
        fpoint(1,i,ng)=0.0_r8
        fpoint(2,i,ng)=0.0_r8
        tintrp(1,i,ng)=0.0_r8
        tintrp(2,i,ng)=0.0_r8
        vtime(1,i,ng)=0.0_r8
        vtime(2,i,ng)=0.0_r8
        frcncid(i,ng)=-1
      END DO
!
!  Get initialization time string.
!
      CALL time_string (time(ng), i_code)
!
!  Get final time string for simulation.
!
      IF (model.eq.iadm) THEN
        tfinal=time(ng)-ntimes(ng)*dt(ng)
      ELSE
        tfinal=time(ng)+ntimes(ng)*dt(ng)
      END IF
      CALL time_string (tfinal, f_code)
!
!-----------------------------------------------------------------------
!  Input lateral boundary conditions data.
!-----------------------------------------------------------------------
!
      IF (obcdata(ng)) THEN
        file_type='Lateral Boundary'
        max_files=nbcfiles(ng)
        CALL multifile_info_s2d (ng, model, file_type, nbcfiles,        &
     &                           max_files, bry)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
!
!-----------------------------------------------------------------------
!  Input climatology data.
!-----------------------------------------------------------------------
!
      IF (clm_file(ng)) THEN
        file_type='Climatology'
        max_files=nclmfiles(ng)
        CALL multifile_info_s2d (ng, model, file_type, nclmfiles,       &
     &                           max_files, clm)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
 
#ifdef FORWARD_READ
!
!-----------------------------------------------------------------------
!  Nonlinear model forward trajectory data.
!-----------------------------------------------------------------------
!
      IF (lreadfwd(ng)) THEN
        CALL multifile_info_s1d (ng, model, 'Forward', fwd)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
#endif
 
#if defined TANGENT || defined TL_IOMS
!
!-----------------------------------------------------------------------
!  Adjoint model trajectory data.
!-----------------------------------------------------------------------
!
      IF (lreadtlm(ng)) THEN
        CALL multifile_info_s1d (ng, model, 'Tangent Linear', tlm)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
#endif
 
#ifdef FORWARD_FLUXES
!
!-----------------------------------------------------------------------
!  Nonlinear model surface fluxes data.
!-----------------------------------------------------------------------
!
      IF (lreadblk(ng)) THEN
        CALL multifile_info_s1d (ng, model, 'Nonlinear Fluxes', blk)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
#endif
 
#ifndef ANA_PSOURCE
!
!-----------------------------------------------------------------------
!  Input Source/Sink data (river runoff).
!-----------------------------------------------------------------------
!
      IF (luvsrc(ng).or.lwsrc(ng)) THEN
        file_type='Sources/Sinks Data'
        CALL multifile_info_s1d (ng, model, file_type, ssf)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
#endif
 
#ifdef FRC_FILE
!
!-----------------------------------------------------------------------
!  Input forcing data.
!-----------------------------------------------------------------------
!
      IF (lreadfrc(ng)) THEN
        file_type='Forcing'
        max_files=maxval(nffiles)
        CALL multifile_info_s2d (ng, model, file_type, nffiles,         &
     &                           max_files, frc)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
#endif
!
      RETURN
      END SUBROUTINE check_multifile
!
      SUBROUTINE multifile_info_s1d (ng, model, file_type, S)
!
!=======================================================================
!                                                                      !
!  Updates multi-file information for the given 1D file structure, S.  !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng         Nested grid number (integer)                          !
!     model      Calling model identifier (integer)                    !
!     file_type  File structure indentifier (string)                   !
!     S          2D Derived type structure, TYPE(T_IO)                 !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE dateclock_mod, ONLY : time_string
      USE strings_mod,   ONLY : founderror, lowercase
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, model
!
      character (len=*), intent(in) :: file_type
!
      TYPE(t_io), intent(inout) :: S(Ngrids)
!
!  Local variable declarations.
!
      logical :: Lcheck, foundit
      logical :: check_file
!
      integer :: Fcount, Nfiles, i, ifile
!
      real(dp) :: Tfinal, Tmax, Tmin, Tscale
!
      character (len= 22) :: Tmin_code, Tmax_code
      character (len=256) :: ncname
 
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", multifile_info_s1d"
!
      sourcefile=myfile
!
!-----------------------------------------------------------------------
!  Update file structure parameters.
!-----------------------------------------------------------------------
!
!  Set final time of simulation.
!
      IF (model.eq.iadm) THEN
        tfinal=time(ng)-ntimes(ng)*dt(ng)
      ELSE
        tfinal=time(ng)+ntimes(ng)*dt(ng)
      END IF
!
!  Set minimum and maximum time values.
!
      nfiles=s(ng)%Nfiles
      DO ifile=1,nfiles
        ncname=trim(s(ng)%files(ifile))
        foundit=check_file(ng, model, nfiles, ncname, s(ng)%IOtype,     &
     &                     tmin, tmax, tscale,  lcheck)
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        s(ng)%time_min(ifile)=tmin
        s(ng)%time_max(ifile)=tmax
      END DO
!
!  Set the appropriate file counter to use during initialization or
!  restart.
!
      fcount=0
      IF (lcheck) THEN
        IF (model.eq.iadm) THEN
          DO ifile=nfiles,1,-1
            tmax=tscale*s(ng)%time_max(ifile)
            IF (time(ng).le.tmax) THEN
              fcount=ifile
            END IF
          END DO
        ELSE
          DO ifile=1,nfiles
            tmin=tscale*s(ng)%time_min(ifile)
            IF (time(ng).ge.tmin) THEN
              fcount=ifile
            END IF
          END DO
        END IF
      ELSE
        fcount=1
      END IF
!
!  Initialize other structure parameters or issue an error if data does
!  not include initalization time.
!
      IF (fcount.gt.0) THEN
        s(ng)%Fcount=fcount
        ncname=s(ng)%files(fcount)
        s(ng)%name=trim(ncname)
      ELSE
        IF (master.and.lcheck) THEN
          WRITE (stdout,10) trim(lowercase(file_type)), i_code
          DO ifile=1,nfiles
            tmin=tscale*s(ng)%time_min(ifile)
            tmax=tscale*s(ng)%time_max(ifile)
            CALL time_string (tmin, tmin_code)
            CALL time_string (tmax, tmax_code)
            WRITE (stdout,20) tmin_code, tmax_code,                     &
     &                        trim(s(ng)%files(ifile))
          END DO
        END IF
        exit_flag=4
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
!
!  Check if there is data up to the end of the simulation.
!
      IF (lcheck) THEN
        IF (model.eq.iadm) THEN
          tmin=tscale*s(ng)%time_min(1)
          IF (tfinal.lt.tmin) THEN
            CALL time_string (tmin, tmin_code)
            IF (master) THEN
              WRITE (stdout,30) trim(file_type)//' (adjoint)',          &
     &                          trim(s(ng)%files(1)),                   &
     &                          'first ', tmin_code, f_code
            END IF
            exit_flag=4
            IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          END IF
        ELSE
          tmax=tscale*s(ng)%time_max(nfiles)
          IF (tfinal.gt.tmax) THEN
            CALL time_string (tmax, tmax_code)
            IF (master) THEN
              WRITE (stdout,30) trim(file_type),                        &
     &                          trim(s(ng)%files(nfiles)),              &
     &                          'last  ', tmax_code, f_code
            END IF
            exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
          END IF
        END IF
      END IF
!
 10   FORMAT (/,' MULTIFILE_INFO_S1D - Error while processing ', a,     &
     &        ' multi-files: ',/,22x,'data does not include',           &
     &        ' initialization time = ', a,/)
 20   FORMAT (3x,a,2x,a,5x,a)
 30   FORMAT (/,' MULTIFILE_INFO_S1D - Error while checking input ', a, &
     &        ' file:',/,22x,a,/,22x,                                   &
     &        a,'data time record available is for day: ',a,/,22x,      &
     &        'but data is needed to finish run until day: ',a)
!
      RETURN
      END SUBROUTINE multifile_info_s1d
!
      SUBROUTINE multifile_info_s2d (ng, model, file_type, InpFiles,    &
     &                               idim, S)
!
!=======================================================================
!                                                                      !
!  Updates multi-file information for the given 2D file structure, S.  !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng         Nested grid number (integer)                          !
!     model      Calling model identifier (integer)                    !
!     file_type  File structure indentifier (string)                   !
!     InpFiles   Number of source input files per grid (integer vector)!
!     idim       Size of structure inner dimension (integer):          !
!                  idim=MAXVAL(InpFiles) in calling routine            !
!     S          2D Derived type structure, TYPE(T_IO)                 !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_scalars
!
      USE dateclock_mod, ONLY : time_string
      USE strings_mod,   ONLY : founderror, lowercase
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, model, idim
      integer, intent(in) :: InpFiles(Ngrids)
!
      character (len=*), intent(in) :: file_type
!
      TYPE(t_io), intent(inout) :: S(idim,Ngrids)
!
!  Local variable declarations.
!
      logical :: Lcheck, foundit
      logical :: check_file
!
      integer :: Fcount, Nfiles, i, ifile
!
      real(dp) :: Tfinal, Tmax, Tmin, Tscale
!
      character (len= 22) :: Tmin_code, Tmax_code
      character (len=256) :: ncname
 
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__//", multifile_info_s2d"
!
      sourcefile=myfile
!
!-----------------------------------------------------------------------
!  Update file structure parameters.
!-----------------------------------------------------------------------
!
!  Set final time of simulation.
!
      IF (model.eq.iadm) THEN
        tfinal=time(ng)-ntimes(ng)*dt(ng)
      ELSE
        tfinal=time(ng)+ntimes(ng)*dt(ng)
      END IF
!
!  Set minimum and maximum time values.
!
      DO i=1,inpfiles(ng)
        nfiles=s(i,ng)%Nfiles
        DO ifile=1,nfiles
          ncname=trim(s(i,ng)%files(ifile))
          foundit=check_file(ng, model, nfiles, ncname, s(i,ng)%IOtype, &
     &                       tmin, tmax, tscale, lcheck)
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
          s(i,ng)%time_min(ifile)=tmin
          s(i,ng)%time_max(ifile)=tmax
        END DO
!
!  Set the appropriate file counter to use during initialization or
!  restart.
!
        fcount=0
        IF (lcheck) THEN
          IF (model.eq.iadm) THEN
            DO ifile=nfiles,1,-1
              tmax=tscale*s(i,ng)%time_max(ifile)
              IF (time(ng).le.tmax) THEN
                fcount=ifile
              END IF
            END DO
          ELSE
            DO ifile=1,nfiles
              tmin=tscale*s(i,ng)%time_min(ifile)
              IF (time(ng).ge.tmin) THEN
                fcount=ifile
              END IF
            END DO
          END IF
        ELSE
          fcount=1
        END IF
!
!  Initialize other structure parameters or issue an error if data does
!  not include initalization time.
!
        IF (fcount.gt.0) THEN
          s(i,ng)%Fcount=fcount
          ncname=s(i,ng)%files(fcount)
          s(i,ng)%name=trim(ncname)
        ELSE
          IF (master.and.lcheck) THEN
            WRITE (stdout,10) trim(lowercase(file_type)), i_code
            DO ifile=1,nfiles
              tmin=tscale*s(i,ng)%time_min(ifile)
              tmax=tscale*s(i,ng)%time_max(ifile)
              CALL time_string (tmin, tmin_code)
              CALL time_string (tmax, tmax_code)
              WRITE (stdout,20) tmin_code, tmax_code,                   &
     &                          trim(s(i,ng)%files(ifile))
            END DO
          END IF
          exit_flag=4
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
        END IF
!
!  Check if there is data up to the end of the simulation.
!
        IF (lcheck) THEN
          IF (model.eq.iadm) THEN
            tmin=tscale*s(i,ng)%time_min(1)
            IF (tfinal.lt.tmin) THEN
              CALL time_string (tmin, tmin_code)
              IF (master) THEN
                WRITE (stdout,30) trim(file_type)//' (adjoint)',        &
     &                            trim(s(i,ng)%files(1)),               &
     &                            'first ', tmin_code, f_code
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
          ELSE
            tmax=tscale*s(i,ng)%time_max(nfiles)
            IF (tfinal.gt.tmax) THEN
              CALL time_string (tmax, tmax_code)
              IF (master) THEN
                WRITE (stdout,30) trim(file_type),                      &
     &                            trim(s(i,ng)%files(nfiles)),          &
     &                            'last  ', tmax_code, f_code
              END IF
              exit_flag=4
              IF (founderror(exit_flag, noerror,                        &
     &                       __line__, myfile)) RETURN
            END IF
          END IF
        END IF
      END DO
!
 10   FORMAT (/,' MULTIFILE_INFO_S2D - Error while processing ', a,     &
     &        ' multi-files: ',/,22x,'data does not include',           &
     &        ' initialization time = ', a,/)
 20   FORMAT (3x,a,2x,a,5x,a)
 30   FORMAT (/,' MULTIFILE_INFO_S2D - Error while checking input ', a, &
     &        ' file:',/,22x,a,/,22x,                                   &
     &        a,'data time record available is for day: ',a,/,22x,      &
     &        'but data is needed to finish run until day: ',a)
!
      RETURN
      END SUBROUTINE multifile_info_s2d
!
      FUNCTION check_file (ng, model, Nfiles, ncname, IOtype,           &
     &                     Tmin, Tmax, Tscale, Lcheck) RESULT (foundit)
!
!=======================================================================
!                                                                      !
!  This logical function scans the variables of the provided input     !
!  NetCDF for the time record variable and gets its range of values.   !
!  It used elsewhere to determine which input NetCDF multi-file is     !
!  needed for initialization or restart.                               !
!                                                                      !
!  On Input:                                                           !
!                                                                      !
!     ng           Nested grid number.                                 !
!     model        Calling model identifier.                           !
!     Nfiles       Number of multi-files.                              !
!     ncname       NetCDF file name to process (string).               !
!     IOtype       I/O processing library (integer):                   !
!                     io_nf90    Standard NetCDF libray                !
!                     io_pio     Parallel I/O library                  !
!                                                                      !
!  On Output:                                                          !
!                                                                      !
!     Tmin         Available minimum time variable value.              !
!     Tmax         Available maximum time variable value.              !
!     Tscale       Scale to convert time variable units to seconds     !
!     Lcheck       Switch to indicate that the time range needs to be  !
!                    checked by the calling routine.                   !
!     foundit      The value of the result is TRUE/FALSE if the        !
!                    time variable is found or not.                    !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_parallel
      USE mod_iounits
      USE mod_ncparam
      USE mod_netcdf
#if defined PIO_LIB && defined DISTRIBUTE
      USE mod_pio_netcdf
#endif
      USE mod_scalars
!
      USE strings_mod, ONLY : founderror, lowercase
!
      implicit none
!
!  Imported variable declarations.
!
      logical, intent(out) :: lcheck
!
      integer, intent(in) :: ng, model, nfiles, iotype
!
      character (*), intent(in) :: ncname
!
      real(dp), intent(out) :: tmin, tmax, tscale
!
!  Local variable declarations.
!
      logical :: lcycle, lperpetual, lspectral, foundit
!
      integer :: nrec, tvarid, i, ncid, nvdim, nvatt
!
      character (len=40) :: tunits, tvarname
 
      character (len=*), parameter :: myfile =                          &
     &  __FILE__//", check_file"
 
#if defined PIO_LIB && defined DISTRIBUTE
!
      TYPE (file_desc_t) :: piofile
      TYPE (var_desc_t)  :: tvardesc
#endif
!
      sourcefile=myfile
!
!------------------------------------------------------------------------
!  Check if requested time is within the NetCDF file dataset.
!------------------------------------------------------------------------
!
!  Initialize.
!
      foundit=.false.
      lcheck=.true.
      lcycle=.false.
      lperpetual=.false.
      lspectral =.false.
      tscale=1.0_r8                        ! seconds
      tmin=0.0_r8
      tmax=0.0_r8
!
!  Open NetCDF file for reading.
!
      SELECT CASE (iotype)
        CASE (io_nf90)
          CALL netcdf_open (ng, model, ncname, 0, ncid)
#if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL pio_netcdf_open (ng, model, ncname, 0, piofile)
#endif
      END SELECT
      IF (founderror(exit_flag, noerror, __line__, myfile)) THEN
        IF (master) WRITE (stdout,10) trim(ncname)
        RETURN
      END IF
!
!  Inquire about all the variables
!
      SELECT CASE (iotype)
        CASE (io_nf90)
          CALL netcdf_inq_var (ng, model, ncname,                       &
     &                         ncid = ncid)
#if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL pio_netcdf_inq_var (ng, model, ncname,                   &
     &                             piofile = piofile)
#endif
      END SELECT
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Search for the time variable: any 1D array variable with the string
!  'time' in the variable name.
!
      DO i=1,n_var
        IF ((index(trim(lowercase(var_name(i))),'time').ne.0).and.      &
     &            (var_ndim(i).eq.1)) THEN
          tvarname=trim(var_name(i))
          foundit=.true.
          EXIT
        ELSE IF ((index(trim(var_name(i)),'tide_period').ne.0).and.     &
     &            (var_ndim(i).eq.1)) THEN
          tvarname=trim(var_name(i))
          foundit=.true.
          lspectral=.true.          ! we do not need to check tidal data
          EXIT
        END IF
      END DO
      IF (.not.foundit) THEN
        IF (master) THEN
          WRITE (stdout,20) trim(ncname)
        END IF
        exit_flag=4
        IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
      END IF
!
!  Inquire about requested variable.
!
      SELECT CASE (iotype)
        CASE (io_nf90)
          CALL netcdf_inq_var (ng, model, ncname,                       &
     &                         ncid = ncid,                             &
     &                         myvarname = trim(tvarname),              &
     &                         varid = tvarid,                          &
     &                         nvardim = nvdim,                         &
     &                         nvaratt = nvatt)
#if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL pio_netcdf_inq_var (ng, model, ncname,                   &
     &                             piofile = piofile,                   &
     &                             myvarname = trim(tvarname),          &
     &                             piovar = tvardesc,                   &
     &                             nvardim = nvdim,                     &
     &                             nvaratt = nvatt)
#endif
      END SELECT
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
!  Set number of records available and check the 'units' attribute.
!  Also, set output logical switch 'Lcheck' for the calling to check
!  the available data time range. For example, we need to check it
!  there is enough data to finish the simulation.  Notice that for
!  data with 'cycle_length', Lcheck = FALSE.  Also,  Lcheck = FALSE
!  for perpetual time axis: the 'calendar' attribute is 'none' or
!  the number of records in the time dimension is one (Nrec=1).
!
      nrec=var_dsize(1)              ! time is a 1D array
      DO i=1,nvatt
        IF (trim(var_aname(i)).eq.'units') THEN
          tunits=trim(var_achar(i))
          IF (index(trim(var_achar(i)),'day').ne.0) THEN
            tscale=86400.0_r8
          ELSE IF (index(trim(var_achar(i)),'hour').ne.0) THEN
            tscale=3600.0_r8
          ELSE IF (index(trim(var_achar(i)),'second').ne.0) THEN
            tscale=1.0_r8
          END IF
        ELSE IF (trim(var_aname(i)).eq.'calendar') THEN
          IF (((nrec.eq.1).and.(nfiles.eq.1)).or.                       &
     &        (index(trim(var_achar(i)),'none').ne.0)) THEN
            lperpetual=.true.
          END IF
        ELSE IF (trim(var_aname(i)).eq.'cycle_length') THEN
          lcycle=.true.
        END IF
      END DO
!
!  Turn off the checking of time range if cycling, perpectual, or
!  spectral time axis.
!
      IF (lcycle.or.lperpetual.or.lspectral.or.                         &
     &    ((nrec.eq.1).and.(nfiles.eq.1))) THEN
        lcheck=.false.
      END IF
!
!  Read in time variable minimum and maximun values (input time units).
!
      SELECT CASE (iotype)
        CASE (io_nf90)
          CALL netcdf_get_time (ng, model, ncname, tvarname,            &
     &                          rclock%DateNumber, tmin,                &
     &                          ncid = ncid,                            &
     &                          start = (/1/),                          &
     &                          total = (/1/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          CALL netcdf_get_time (ng, model, ncname, tvarname,            &
     &                          rclock%DateNumber, tmax,                &
     &                          ncid = ncid,                            &
     &                          start = (/nrec/),                       &
     &                          total = (/1/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
 
#if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL pio_netcdf_get_time (ng, model, ncname, tvarname,        &
     &                              rclock%DateNumber, tmin,            &
     &                              piofile = piofile,                  &
     &                              start = (/1/),                      &
     &                              total = (/1/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
          CALL pio_netcdf_get_time (ng, model, ncname, tvarname,        &
     &                              rclock%DateNumber, tmax,            &
     &                              piofile = piofile,                  &
     &                              start = (/nrec/),                   &
     &                              total = (/1/))
          IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
#endif
      END SELECT
 
!
!  Close NetCDF file.
!
      SELECT CASE (iotype)
        CASE (io_nf90)
          CALL netcdf_close (ng, model, ncid, ncname, .false.)
#if defined PIO_LIB && defined DISTRIBUTE
        CASE (io_pio)
          CALL pio_netcdf_close (ng, model, piofile, ncname, .false.)
#endif
      END SELECT
      IF (founderror(exit_flag, noerror, __line__, myfile)) RETURN
!
 10   FORMAT (/, ' CHECK_FILE - unable to open grid NetCDF file: ',a)
 20   FORMAT (/, ' CHECK_FILE - unable to find time variable in input', &
     &        ' NetCDF file:', /, 14x, a, /, 14x,                       &
     &        'variable name does not contains the "time" string.')
!
      RETURN
      END FUNCTION check_file