ana_nudgcoef.h

Go to the documentation of this file.

!!
      SUBROUTINE ana_nudgcoef (ng, tile, model)
!
!! git $Id$
!!================================================= Hernan G. Arango ===
!! Copyright (c) 2002-2025 The ROMS Group                              !
!!   Licensed under a MIT/X style license                              !
!!   See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine sets spatially varying nudging coefficients time-      !
!  scales (1/s). They are used for nuding to climatology in the        !
!  governing equations.                                                !
!                                                                      !
!  It is HIGHLY recommended to write these nudging coefficients into   !
!  input NetCDF NUDNAME instead of using analytical expressions        !
!  below.  It is very easy to introduce parallel bugs.  Also, Users    !
!  can plot their spatial distribution and fine tune their values      !
!  during the pre-proccessing stage for a particular application.      !
!                                                                      !
!  REMARK:  Nudging of free-surface in the vertically integrated       !
!  ======   continuity equation is NOT allowed because it VIOLATES     !
!  mass/volume conservation. If such nudging effects are required,     !
!  it needs to be specified on the momentum equations for (u,v)        !
!  and/or (ubar,vbar). If done on (u,v) only, its effects enter        !
!  the 2D momentum equations via the residual vertically integrated    !
!  forcing term.                                                       !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_ncparam
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
!
!  Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
#include "tile.h"
!
      CALL ana_nudgcoef_tile (ng, tile, model,                          &
     &                        lbi, ubi, lbj, ubj,                       &
     &                        imins, imaxs, jmins, jmaxs)
!
! Set analytical header file name used.
!
#ifdef DISTRIBUTE
      IF (lanafile) THEN
#else
      IF (lanafile.and.(tile.eq.0)) THEN
#endif
        ananame(16)=myfile
      END IF
!
      RETURN
      END SUBROUTINE ana_nudgcoef
!
!***********************************************************************
      SUBROUTINE ana_nudgcoef_tile (ng, tile, model,                    &
     &                              LBi, UBi, LBj, UBj,                 &
     &                              IminS, ImaxS, JminS, JmaxS)
!***********************************************************************
!
      USE mod_param
      USE mod_parallel
      USE mod_clima
      USE mod_grid
      USE mod_ncparam
      USE mod_scalars
#ifdef DISTRIBUTE
!
      USE distribute_mod, ONLY : mp_collect
      USE mp_exchange_mod, ONLY : mp_exchange2d
# ifdef SOLVE3D
      USE mp_exchange_mod, ONLY : mp_exchange3d
      USE mp_exchange_mod, ONLY : mp_exchange4d
# endif
#endif
!
      implicit none
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
!
!  Local variable declarations.
!
      integer :: Iwrk, i, itrc, j, k
!
      real(r8) :: cff1, cff2, cff3
!
      real(r8), parameter :: IniVal = 0.0_r8
!
      real(r8), dimension(IminS:ImaxS,JminS:JmaxS) :: wrk
 
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Set up nudging towards data time-scale coefficients (1/s).
!-----------------------------------------------------------------------
!
!  Initialize.
!
      DO j=jstrt,jendt
        DO i=istrt,iendt
          wrk(i,j)=0.0_r8
        END DO
      END DO
 
#if defined ADRIA02
!
!  Set tracer nudging coefficients in the southern edges from a three
!  days time scale at the boundary point to decrease linearly to 30 days
!  six grids points away from the boundary.
!
      cff1=1.0_r8/(3.0_r8*86400.0_r8)
      cff2=1.0_r8/(30.0_r8*86400.0_r8)
      DO j=jstrt,min(6,jendt)
        DO i=istrt,iendt
          wrk(i,j)=cff2+real(6-j,r8)*(cff1-cff2)/6.0_r8
        END DO
      END DO
 
      IF (any(lnudgetclm(:,ng))) THEN
        DO itrc=1,ntclm(ng)
          DO k=1,n(ng)
            DO j=jstrt,jendt
              DO i=istrt,iendt
                clima(ng)%Tnudgcof(i,j,k,itrc)=wrk(i,j)
              END DO
            END DO
          END DO
        END DO
      END IF
 
#elif defined DAMEE_4
!
!  Set tracer nudging coefficients in the southern and northern edges
!  from a five days time scale at the boundary point to decrease
!  linearly to 60 days seven grids points away from the boundary.
!
      cff1=1.0_r8/(5.0_r8*86400.0_r8)
      cff2=1.0_r8/(60.0_r8*86400.0_r8)
      cff3=(7.0_r8*cff1-cff2)/6.0_r8
      DO j=jstrt,min(8,jendt)
        DO i=istrt,iendt
          wrk(i,j)=cff2+real(8-j,r8)*(cff1-cff2)/7.0_r8
        END DO
      END DO
 
      DO j=max(jstrt,mm(ng)-7),jendt
        DO i=istrt,iendt
          wrk(i,j)=cff1+real(mm(ng)-j,r8)*(cff2-cff1)/7.0_r8
        END DO
      END DO
 
      DO j=max(jstrt,74),min(80,jendt)
        DO i=max(istrt,102),min(108,iendt)
          cff1=sqrt(real((i-109)*(i-109)+(j-77)*(j-77),r8))
          wrk(i,j)=max(0.0_r8,(cff3+cff1*(cff2-cff3)/6.0_r8))
        END DO
      END DO
 
      IF (any(lnudgetclm(:,ng))) THEN
        DO itrc=1,ntclm(ng)
          DO k=1,n(ng)
            DO j=jstrt,jendt
              DO i=istrt,iendt
                clima(ng)%Tnudgcof(i,j,k,itrc)=wrk(i,j)
              END DO
            END DO
          END DO
        END DO
      END IF
 
#else
!
!  Default nudging coefficients.  Set nudging coefficients uniformly to
!  the values specified in the standard input file.
!
      IF (lnudgem2clm(ng)) THEN
        DO j=jstrt,jendt
          DO i=istrt,iendt
            clima(ng)%M2nudgcof(i,j)=m2nudg(ng)
          END DO
        END DO
      END IF
 
# ifdef SOLVE3D
!
      IF (lnudgem3clm(ng)) THEN
        DO k=1,n(ng)
          DO j=jstrt,jendt
            DO i=istrt,iendt
              clima(ng)%M3nudgcof(i,j,k)=m3nudg(ng)
            END DO
          END DO
        END DO
      END IF
!
      IF (any(lnudgetclm(:,ng))) THEN
        DO itrc=1,ntclm(ng)
          DO k=1,n(ng)
            DO j=jstrt,jendt
              DO i=istrt,iendt
                clima(ng)%Tnudgcof(i,j,k,itrc)=tnudg(itrc,ng)
              END DO
            END DO
          END DO
        END DO
      END IF
# endif
#endif
#ifdef DISTRIBUTE
!
!-----------------------------------------------------------------------
!  Exchage nudging coefficients information.
!-----------------------------------------------------------------------
!
      IF (lnudgem2clm(ng)) THEN
        CALL mp_exchange2d (ng, tile, model, 1,                         &
     &                      lbi, ubi, lbj, ubj,                         &
     &                      nghostpoints, .false., .false.,             &
     &                      clima(ng)%M2nudgcof)
      END IF
 
# ifdef SOLVE3D
!
      IF (lnudgem3clm(ng)) THEN
        CALL mp_exchange3d (ng, tile, model, 1,                         &
     &                      lbi, ubi, lbj, ubj, 1, n(ng),               &
     &                      nghostpoints, .false., .false.,             &
     &                      clima(ng)%M3nudgcof)
      END IF
!
      IF (any(lnudgetclm(:,ng))) THEN
        CALL mp_exchange4d (ng, tile, model, 1,                         &
     &                      lbi, ubi, lbj, ubj, 1, n(ng), 1, ntclm(ng), &
     &                      nghostpoints, .false., .false.,             &
     &                      clima(ng)%Tnudgcof)
      END IF
# endif
#endif
!
      RETURN
      END SUBROUTINE ana_nudgcoef_tile