ana_fsobc.h

Go to the documentation of this file.

!!
      SUBROUTINE ana_fsobc (ng, tile, model)
!
!! git $Id$
!!======================================================================
!! Copyright (c) 2002-2025 The ROMS Group                              !
!!   Licensed under a MIT/X style license                              !
!!   See License_ROMS.md                                               !
!=======================================================================
!                                                                      !
!  This routine sets free-surface open boundary conditions using       !
!  analytical expressions.                                             !
!                                                                      !
!=======================================================================
!
      USE mod_param
      USE mod_ncparam
!
! Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
!
! Local variable declarations.
!
      character (len=*), parameter :: MyFile =                          &
     &  __FILE__
!
#include "tile.h"
!
      CALL ana_fsobc_tile (ng, tile, model,                             &
     &                     lbi, ubi, lbj, ubj,                          &
     &                     imins, imaxs, jmins, jmaxs)
!
! Set analytical header file name used.
!
#ifdef DISTRIBUTE
      IF (lanafile) THEN
#else
      IF (lanafile.and.(tile.eq.0)) THEN
#endif
        ananame( 6)=myfile
      END IF
!
      RETURN
      END SUBROUTINE ana_fsobc
!
!***********************************************************************
      SUBROUTINE ana_fsobc_tile (ng, tile, model,                       &
     &                           LBi, UBi, LBj, UBj,                    &
     &                           IminS, ImaxS, JminS, JmaxS)
!***********************************************************************
!
      USE mod_param
      USE mod_boundary
      USE mod_grid
      USE mod_ncparam
      USE mod_scalars
!
!  Imported variable declarations.
!
      integer, intent(in) :: ng, tile, model
      integer, intent(in) :: LBi, UBi, LBj, UBj
      integer, intent(in) :: IminS, ImaxS, JminS, JmaxS
!
!  Local variable declarations.
!
      integer :: i, j
!
      real(r8) :: cff, fac, omega, phase, val
 
#include "set_bounds.h"
!
!-----------------------------------------------------------------------
!  Free-surface open boundary conditions.
!-----------------------------------------------------------------------
!
#if defined INLET_TEST
      IF (lbc(inorth,isfsur,ng)%acquire.and.                            &
     &    domain(ng)%Northern_Edge(tile)) THEN
        cff=-1.0_r8*sin(2.0_r8*pi*time(ng)/(12.0_r8*3600.0_r8))
        DO i=istrt,iendt
          boundary(ng)%zeta_north(i)=cff
        END DO
      END IF
#elif defined KELVIN
      fac=1.0_r8                                ! zeta0
      omega=2.0_r8*pi/(12.42_r8*3600.0_r8)      ! M2 Tide period
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
        DO j=jstrt,jendt
          val=fac*exp(-grid(ng)%f(istr-1,j)*grid(ng)%yp(istr-1,j)/      &
     &                sqrt(g*grid(ng)%h(istr-1,j)))
          boundary(ng)%zeta_west(j)=val*cos(omega*time(ng))
        END DO
      END IF
 
      IF (lbc(ieast,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Eastern_Edge(tile)) THEN
        DO j=jstrt,jendt
          cff=1.0_r8/sqrt(g*grid(ng)%h(istr-1,j))
          val=fac*exp(-grid(ng)%f(istr-1,j)*grid(ng)%yp(iend,j)*cff)
          boundary(ng)%zeta_east(j)=val*cos(omega*grid(ng)%xp(iend,j)*  &
     &                                      cff-omega*time(ng))
        END DO
      END IF
#elif defined ESTUARY_TEST
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
        cff=1.0_r8*sin(2.0_r8*pi*time(ng)/(12.0_r8*3600.0_r8))
        DO j=jstrt,jendt
          boundary(ng)%zeta_west(j)=cff
        END DO
      END IF
#elif defined SED_TEST1
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
        fac=100.0_r8
        DO j=jstrt,jendt
          boundary(ng)%zeta_west(j)=9.0e-06_r8*fac
        END DO
      END IF
 
      IF (lbc(ieast,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Eastern_Edge(tile)) THEN
        fac=100.0_r8
        DO j=jstrt,jendt
          boundary(ng)%zeta_east(j)=9.0e-06_r8*real(iend+1,r8)*fac
        END DO
      END IF
#elif defined SHOREFACE
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
!!      cff=-1.0_r8*SIN(2.0_r8*pi*time(ng)/(12.0_r8*3600.0_r8))
        cff=0.0_r8
        DO j=jstrt,jendt
          boundary(ng)%zeta_west(j)=cff
        END DO
      END IF
#elif defined TEST_CHAN
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
        cff=0.0_r8
        DO j=jstrt,jendt
          boundary(ng)%zeta_west(j)=cff
        END DO
      END IF
 
      IF (lbc(ieast,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Eastern_Edge(tile)) THEN
        cff=-0.4040_r8*min(time(ng)/150000.0_r8,1.0_r8)
        DO j=jstrt,jendt
          boundary(ng)%zeta_east(j)=cff
        END DO
      END IF
#elif defined WEDDELL
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
        fac=tanh((tdays(ng)-dstart)/1.0_r8)
        omega=2.0_r8*pi*time(ng)/(12.42_r8*3600.0_r8)  !  M2 Tide period
        val=0.53_r8+(0.53_r8-0.48_r8)/real(iend+1,r8)
        phase=(277.0_r8+(277.0_r8-240.0_r8)/real(iend+1,r8))*deg2rad
        DO j=jstrt,jendt
          boundary(ng)%zeta_west(j)=fac*val*cos(omega-phase)
        END DO
      END IF
 
      IF (lbc(ieast,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Eastern_Edge(tile)) THEN
        fac=tanh((tdays(ng)-dstart)/1.0_r8)
        omega=2.0_r8*pi*time(ng)/(12.42_r8*3600.0_r8)  !  M2 Tide period
        val=0.53_r8+(0.53_r8-0.48_r8)
        phase=(277.0_r8+(277.0_r8-240.0_r8))*deg2rad
        DO j=jstrt,jendt
          boundary(ng)%zeta_east(j)=fac*val*cos(omega-phase)
        END DO
      END IF
#else
      IF (lbc(ieast,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Eastern_Edge(tile)) THEN
        DO j=jstrt,jendt
          boundary(ng)%zeta_east(j)=0.0_r8
        END DO
      END IF
 
      IF (lbc(iwest,isfsur,ng)%acquire.and.                             &
     &    domain(ng)%Western_Edge(tile)) THEN
        DO j=jstrt,jendt
          boundary(ng)%zeta_west(j)=0.0_r8
        END DO
      END IF
 
      IF (lbc(isouth,isfsur,ng)%acquire.and.                            &
     &    domain(ng)%Southern_Edge(tile)) THEN
        DO i=istrt,iendt
          boundary(ng)%zeta_south(i)=0.0_r8
        END DO
      END IF
 
      IF (lbc(inorth,isfsur,ng)%acquire.and.                            &
     &    domain(ng)%Northern_Edge(tile)) THEN
        DO i=istrt,iendt
          boundary(ng)%zeta_north(i)=0.0_r8
        END DO
      END IF
#endif
!
      RETURN
      END SUBROUTINE ana_fsobc_tile